topic Re: How to deploy Inventor 2020 Read Only viewer in Inventor Forum

How to deploy Inventor 2020 Read Only viewer

steinar_sorem — Mon, 08 Apr 2019 11:06:27 GMT

Hi,

How do we create deployment of Inventor 2020 Read Only mode (viewer)? As we can see we have to deploy a full version of the product? In our large multi site environment it will be to easy to R O users to start the full version of the product..

Steinar Sørem

Kongsberg Maritime

CAD Administrator

Re: How to deploy Inventor 2020 Read Only viewer

Mark.Lancaster — Mon, 08 Apr 2019 11:41:42 GMT

@steinar_sorem

The exe is located here C:\Program Files\Autodesk\Inventor 2020\Bin and is called Invro.exe. Now this read-only mode its part of the overall installation of Inventor so I don't believe you can just create a deployment for the read only aspect.

You could try and copy the exe from the installation file location (C:\Autodesk\Inventor_Pro_2020_English_Win_64bit_dlm\x64\INV\PF\ADSK\INV\Bin) to a person machine and see if it works without installing all of Inventor 2020. I just don't have a machine to test it on.

Re: How to deploy Inventor 2020 Read Only viewer

steinar_sorem — Mon, 08 Apr 2019 11:53:14 GMT

Hi,
Thanks for your attention. You will need the full installation anyway. This file is is what you start from windows program menu while you choose to start the program in read Only mode.

BR
S\

Re: How to deploy Inventor 2020 Read Only viewer

pball — Mon, 08 Apr 2019 13:07:48 GMT

If you want to disable full Inventor you could create a script to run after the deployment. You can have a deployment run something after it finishes and I've had some success using that for installing my custom addin. You could have a script that renames or deletes the Inventor.exe from the program files folder and the shortcuts. Then it shouldn't be possible to run normal Inventor at all. I might actually try doing that but we only have 10 or so people that need a viewer so doing it manually isn't a problem for me.

Re: How to deploy Inventor 2020 Read Only viewer

GunnarNilsson — Mon, 08 Apr 2019 13:27:03 GMT

I would deploy Inventor the normal way and afterwards just rename Inventor.exe to Inventor.exe.donotuse. That way the users cannot start full Inventor unless they are admin on the computer and able to rename the exe back. Also remove the shortcuts pointing to the full version of the product.

Re: How to deploy Inventor 2020 Read Only viewer

steinar_sorem — Mon, 08 Apr 2019 13:43:55 GMT

Hi all, thanks for your attention to this post.

All this manual file manipulation is how we see it only a way around. Anyway, we deploy hundreds of computers in a lot of office sites round the globe and none of our users is allowed to manipulate files in Program File folders.

What we still asking is how we can deploy Inventor Read Only mode as default to all our project staff round the globe.

Finally we can view large assemblies in Inventor, but we we do not want to install a full Inventor license to be able to run Read Only..

As it is by now it looks like we have to build a deployment with a script at the end that modify shortcuts on the computer. Software Center accept that kind of solutions. Hopefully Autodesk add this behavior to Deployment Wizard next year..

Re: How to deploy Inventor 2020 Read Only viewer

pball — Mon, 08 Apr 2019 20:24:47 GMT

Well I went ahead and made a custom deployment installer for 2020 Read-only mode. My initial testing seems to work as intended.

I created an Inventor 2020 deployment and barely changed any settings, none of the settings should affect this setup process. The main install batch script creates a secondary batch script in the the temp directory on the local pc and then runs that script as administrator, since renaming program files and start menu items seems to require that. I have the deployment and the main script saved on a network drive, which is the reason it creates the local temp script to do the installing.

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

REM Everything between the parentheses is written to the secondary temporary install script
(
echo @echo off
REM  This is copied from the original deployment shortcut link file
REM  I found using the server IP worked while the mapped network drive letter failed
echo   start /wait "" "\\Sever\Software\Autodesk\Inventor 2020 Read-Only Mode\Img\Setup.exe" /qb /I \\Server\Software\Autodesk\Inventor 2020 Read-Only Mode\Img\Inventor 2020 Read-Only Mode.ini /Trial /language en-us

REM  Copy original start menu shortcut for Read-only mode to desktop
echo   copy "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Inventor Read-only Mode 2020 - English.lnk" "C:\Users\Public\Desktop\Inventor Read-only Mode 2020 - English.lnk"  

REM  Rename Inventor exe so it can't be run by accident
echo   ren "C:\Program Files\Autodesk\Inventor 2020\Bin\Inventor.exe" Inventor.exe.bak

REM  Delete all start menu shortcuts except for Read-only mode
echo   del "C:\Users\Public\Desktop\Autodesk Inventor Professional 2020.lnk"
echo   del "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Autodesk Inventor Professional 2020 - English.lnk"
echo   del "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Autodesk Multi-Sheet Plot 2020.lnk"
echo   del "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Design Assistant 2020.lnk"
echo   del "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\License Transfer Utility - Inventor 2020.lnk"

echo   rmdir /S /Q "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Tools"

REM  Optionally start Inventor Read-only mode and load an application options file
echo   start "" "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Inventor Read-only Mode 2020 - English.lnk" /IMPORTOPTIONS="\\Server\Software\Autodesk\Inventor 2020 Read-Only Mode\Tools\Inv2020 RO app options.xml"

REM  Delete install batch script
echo   del "%temp%\Inventor2020ROInstall.bat"
)>"%temp%\Inventor2020ROInstall.bat"

REM Start the temporary install script with administrator rights
set vbs=%temp%\getadmin.vbs
echo Set UAC = CreateObject^("Shell.Application"^)                >> "%vbs%"
echo UAC.ShellExecute "%temp%\Inventor2020ROInstall.bat", "", "", "runas", 1 >> "%vbs%"
"%temp%\getadmin.vbs"
del "%temp%\getadmin.vbs"

The path for the deployment and the application options if you import them should be the only parts you need to change.

If you have any questions let me know.

Re: How to deploy Inventor 2020 Read Only viewer

tfrazziniA449G — Sat, 13 Apr 2019 22:54:06 GMT

pball,

I gave your script a try after editing the path for our installation file locations. It started the installation but before completion attempted to delete the shortcuts. Naturally they weren't made yet and it gave me errors. I'm no cmd guru so can you explain if I did something wrong if it worked for you, or if there is something I can add to assure the installation task finishes prior to executing the lines below?

Re: How to deploy Inventor 2020 Read Only viewer

pball — Mon, 15 Apr 2019 12:12:44 GMT

Here is an update I've made that seems more reliable. For some reason the "start /wait" command for starting the install doesn't seem to work always. So I added a check to ensure that setup.exe isn't running before the script continues. Hopefully this update works better for you.

@echo off

(
echo @echo off
echo   echo Starting Inventor 2020 Read-only Install
echo   "\\Software\Autodesk\Inventor 2020 Read-Only Mode\Img\Setup.exe" /qb /I \\Software\Autodesk\Inventor 2020 Read-Only Mode\Img\Inventor 2020 Read-Only Mode.ini /Trial /language en-us

echo   echo Starting Cleanup

echo   :wait
echo   timeout /t 2 /nobreak ^>nul
echo   tasklist /fi "imagename eq Setup.exe" ^|find ":" ^> nul
echo   if errorlevel 1 goto :wait

echo   copy "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Inventor Read-only Mode 2020 - English.lnk" "C:\Users\Public\Desktop\Inventor Read-only Mode 2020 - English.lnk"  

echo   ren "C:\Program Files\Autodesk\Inventor 2020\Bin\Inventor.exe" Inventor.exe.bak

echo   del "C:\Users\Public\Desktop\Autodesk Inventor Professional 2020.lnk"
echo   del "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Autodesk Inventor Professional 2020 - English.lnk"
echo   del "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Autodesk Multi-Sheet Plot 2020.lnk"
echo   del "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Design Assistant 2020.lnk"
echo   del "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\License Transfer Utility - Inventor 2020.lnk"

echo   rmdir /S /Q "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Tools"

echo   start "" "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Autodesk Inventor 2020\Inventor Read-only Mode 2020 - English.lnk" /IMPORTOPTIONS="\\Software\Autodesk\Inventor 2020 Read-Only Mode\Tools\Inv2020 RO app options.xml"

echo   echo Done

echo   del "%temp%\Inventor2020ROInstall.bat"
)>"%temp%\Inventor2020ROInstall.bat"


set vbs=%temp%\getadmin.vbs
echo Set UAC = CreateObject^("Shell.Application"^)                >> "%vbs%"
echo UAC.ShellExecute "%temp%\Inventor2020ROInstall.bat", "", "", "runas", 1 >> "%vbs%"
"%temp%\getadmin.vbs"
del "%temp%\getadmin.vbs"

Re: How to deploy Inventor 2020 Read Only viewer

tfrazziniA449G — Mon, 15 Apr 2019 18:26:39 GMT

Thank you, it worked as it should for the first three machines. I appreciate the help.

Re: How to deploy Inventor 2020 Read Only viewer

steinar_sorem — Tue, 16 Apr 2019 06:12:29 GMT

Just to be clear, in a huge environment we do not accept to manipulate our deployments with some manually created scripts that do this and that. Autodesk has to think twice here and understand the behavior to be able to could install Inventor as Read Only mode right out of the box. Without any user manipulations.

Ass mentioned before, finally Inventor can read large assemblies. Let us be able to distribute this possibility out to our product advisers and sales management in a easy way.

Re: How to deploy Inventor 2020 Read Only viewer

Anonymous — Wed, 05 Jun 2019 05:42:47 GMT

Thank you for the script.

If I downlaod Inventor 2020, I only get the

Inventor_Pro_2020_English_Win_64bit_wi_en-us_Setup.exe

Inventor_Pro_2020_English_Win_64bit_wi_en-us_Setup_webinstall

How can I download the full extrated directory to put on the "software server"?

Many Thanks

Re: How to deploy Inventor 2020 Read Only viewer

jzarczynski — Wed, 11 Dec 2019 14:58:46 GMT

You must create your own deployment package and place it on your server.

Then you refer to .Ink shortut which usually starts an deployment.

Re: How to deploy Inventor 2020 Read Only viewer

steinar_sorem — Thu, 12 Dec 2019 07:02:08 GMT

Hi
There is no solution in the Deployment wizard to create a real Read Only deployment.
If users just have to use another shortcut to be able to start a full version of Inventor we are not able to use this "Read Only" solution delivered by Autodesk.
In large user environment as we have, we need a real Read Only version not able to change to full version. Only way has to be uninstall, and then install a full version.

BR
Steinar Sorem
Kongsberg Maritime