Thema "Betreff: Inventor (VBA/iLogic): Abwicklung neben das Blatt" in Inventor - Deutsches Forum

Inventor (VBA/iLogic): Abwicklung neben das Blatt

S_May — Fri, 29 Dec 2017 13:49:25 GMT

Hallo zusammen,

gibt es eine Möglichkeit über iLogic, das beim Speichern der Zeichnung neben das Blatt nochmal eine Abwicklung abgelichtet wird, wir würden das für die Laserfertigung benötigen, da auf den Ansichten auf dem Blatt und an der Abwicklung auf dem Blatt bemaßt wird.

Die Abwicklung neben dem Blatt soll eine schnellere Bearbeitung der Laserarbeiten ermöglichen.

@S_May,

Die Themenüberschrift wurde zum besseren Auffindbarkeit editiert von Dennis.Ossadnik
Original: Abwicklung neben das Blatt über ilogic oder Makro

Betreff: Inventor (VBA/iLogic): Abwicklung neben das Blatt

Dennis.Ossadnik — Fri, 29 Dec 2017 13:49:39 GMT

Hallo @S_May,

hier mal ein kleiner Entwurf in VBA:

Sub CreateFlatPatternView()

    ' Set a reference to the drawing document.
    ' This assumes a drawing document is active.
    Dim oDrawDoc As DrawingDocument
    Set oDrawDoc = ThisApplication.ActiveDocument

    'Set a reference to the active sheet.
    Dim oSheet As Sheet
    Set oSheet = oDrawDoc.ActiveSheet

    ' Create a new NameValueMap object
    Dim oBaseViewOptions As NameValueMap
    Set oBaseViewOptions = ThisApplication.TransientObjects.CreateNameValueMap

    ' Set the options to use when creating the base view.
    Call oBaseViewOptions.Add("SheetMetalFoldedModel", False)

    ' Open the sheet metal document invisibly
    Dim oModel As Document
    
    Set oModel = oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument 'ThisApplication.Documents.Open("C:\temp\SheetMetal.ipt", False)

    ' Create the placement point object.
    Dim oPoint As Point2d
    Set oPoint = ThisApplication.TransientGeometry.CreatePoint2d(oSheet.Width + 10, oSheet.Height / 2)

    ' Create a base view.
    Dim oBaseView As DrawingView
    Set oBaseView = oSheet.DrawingViews.AddBaseView(oModel, oPoint, 1, _
    kDefaultViewOrientation, kHiddenLineRemovedDrawingViewStyle, _
    , , oBaseViewOptions)


End Sub

(Es gibt noch keine Fehlerbehandlung im Code.)

Diese Code setzt Dir die Abwicklung von dem Modell der ersten Ansicht auf dem Blatt neben die Blattgrenze im Maßstab 1:1.

Kannst Du damit schon was anfangen?

Bitte nutzt den "Als Lösung akzeptieren"-Button, wenn ein Beitrag euer Problem oder eure Frage löst. Für hilfreiche Posts könnt ihr auch gerne Kudos vergeben.

Betreff: Inventor (VBA/iLogic): Abwicklung neben das Blatt

S_May — Fri, 29 Dec 2017 14:39:16 GMT

Hi Dennis,

ich bin noch bis nächste Woche im Urlaub, aber ohne zu testen würde ich sagen ja, was ist denn der Auslöser für die Aktion?

Wir haben in der Firma leider nur 2016

Betreff: Inventor (VBA/iLogic): Abwicklung neben das Blatt

Dennis.Ossadnik — Fri, 29 Dec 2017 14:46:12 GMT

Hallo @S_May,

also momentan ist der Auslöser ganz einfach: Der User muss das Makro manuell ausführen, wenn er die Ansicht braucht

Aber Du kannst ja auch jedes Makro aus einer iLogic-Regel heraus starten. Dann hättest Du eine Regel, die Du triggern kannst.

Bei mir würde das so aussehen:

InventorVb.RunMacro("MasterIVB", "Drawing", "CreateFlatPatternView")

"MasterIVB": Meine IVB

"Drawing": Mein Modul für die Zeichnungsmakros

Oder eben gleich alles als iLogic-Regel...

Aber mit dem Trigger ist das natürlich so eine Sache. Du müsstest den Code noch etwas anpassen, da er im Moment einfach eine Ansicht erstellt. Du müsstest also ein Prüfkriterium einbauen, damit der Code auch weiß, ob es diese Ansicht eventuell schon gibt oder nicht.

Betreff: Inventor (VBA/iLogic): Abwicklung neben das Blatt

Dennis.Ossadnik — Fri, 29 Dec 2017 14:52:54 GMT

Man könnte bspw. den Namen der Ansicht nehmen, um zu prüfen, ob die Ansicht für das Laserbrennen schon da ist. Hier ein Beispiel:

Sub CreateFlatPatternView()

        ' Set a reference to the drawing document.
    ' This assumes a drawing document is active.
    Dim oDrawDoc As DrawingDocument
    Set oDrawDoc = ThisApplication.ActiveDocument

    'Set a reference to the active sheet.
    Dim oSheet As Sheet
    Set oSheet = oDrawDoc.ActiveSheet
    
    Dim tmpView As DrawingView
    For Each tmpView In oSheet.DrawingViews
    
        If tmpView.Name = "LASER" Then
               
        MsgBox ("Ansicht LASER existiert bereits. Code wird verlassen.")
        Exit Sub
        
        End If
    
    Next

    ' Create a new NameValueMap object
    Dim oBaseViewOptions As NameValueMap
    Set oBaseViewOptions = ThisApplication.TransientObjects.CreateNameValueMap

    ' Set the options to use when creating the base view.
    Call oBaseViewOptions.Add("SheetMetalFoldedModel", False)

    ' Open the sheet metal document invisibly
    Dim oModel As Document
    
    Set oModel = oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument 'ThisApplication.Documents.Open("C:\temp\SheetMetal.ipt", False)

    ' Create the placement point object.
    Dim oPoint As Point2d
    Set oPoint = ThisApplication.TransientGeometry.CreatePoint2d(oSheet.Width + 10, oSheet.Height / 2)

    ' Create a base view.
    Dim oBaseView As DrawingView
    Set oBaseView = oSheet.DrawingViews.AddBaseView(oModel, oPoint, 1, _
    kDefaultViewOrientation, kHiddenLineRemovedDrawingViewStyle, _
    , , oBaseViewOptions)

    oBaseView.Name = "LASER"

End Sub

Betreff: Inventor (VBA/iLogic): Abwicklung neben das Blatt

S_May — Fri, 29 Dec 2017 15:15:16 GMT

Hallo Dennis,

das ist eine gute Idee, ich melde mich nächste Woche zurück deswegen.

Betreff: Inventor (VBA/iLogic): Abwicklung neben das Blatt

S_May — Wed, 03 Jan 2018 07:03:52 GMT

Hallo Dennis,

Die ilogic Lösung wurde gestoppt (schade, hätte mir gut gefallen), aber ich bin nicht die Legislative.

Evtl. kannst Du ja eine ilogic machen für die Allgemeinheit (wenn´s einer brauchen kann).

Das Bier geht dann auf mich...

Betreff: Inventor (VBA/iLogic): Abwicklung neben das Blatt

Dennis.Ossadnik — Tue, 09 Jan 2018 12:04:43 GMT

Hallo @S_May,

habe den VBA-Code noch etwas erweitert und eine kleine Fehlerprüfung eingebaut.

Sub CreateFlatPatternView()
    
    'Actives Dokument holen
    Dim oDrawDoc As DrawingDocument
    Set oDrawDoc = ThisApplication.ActiveDocument

    'Aktives Blatt holen
    Dim oSheet As Sheet
    Set oSheet = oDrawDoc.ActiveSheet
    
    'Kurze Fehlerprüfung (einfach gehlaten zum Nachvollziehen)
    If oSheet.DrawingViews.Count = 0 Then
        'Keine Ansicht auf dem Blatt.
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor Is Nothing Then
        'Erstansicht nicht gültig für diesen Code (eventuell eine Entwurfsansicht)
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocumentType <> kPartDocumentObject Then
        'Auf der ersten Ansicht ist kein Einzeteil abgeleitet
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument.ComponentDefinition.Type <> kSheetMetalComponentDefinitionObject Then
        'Das Einzelteil ist kein Blech und kann hier nicht verarbeitet werden
        'Code wird nicht ausgeführt.
        Exit Sub
    End If
    'Fehlerprüfung ENDE
        
        
    'Mal eben schauen, ob es bereits eine Ansicht LASER auf dem Blatt gibt
    Dim tmpView As DrawingView
    For Each tmpView In oSheet.DrawingViews
        If tmpView.Name = "LASER" Then
            'Code wird verlassen, wenn es bereits eine Ansicht namens "LASER" auf dem Blatt gibt
            'MsgBox ("Ansicht LASER existiert bereits. Code wird verlassen.")
            Exit Sub
        End If
    Next

    'Referenziertes Modell holen aus der ersten Ansicht
    Dim oModel As PartDocument
    Set oModel = oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument 'ThisApplication.Documents.Open("C:\temp\SheetMetal.ipt", False)

    'Wenn noch keine Abwicklung im Part ist, wird sie jetzt erstellt
    Dim tmpSheetCompDef As SheetMetalComponentDefinition
    Set tmpSheetCompDef = oModel.ComponentDefinition

    If tmpSheetCompDef.HasFlatPattern = False Then
        Call tmpSheetCompDef.Unfold
        'Sollte es hier zu einem Fehler kommen, muss die Ansicht zunächst manuell erstellt werden im Blechteil
    End If
    'Abwicklung im Blech jetzt vorhanden


    'Optionen zusammenstellen für die Ansicht der Abwicklung
    Dim oBaseViewOptions As NameValueMap
    Set oBaseViewOptions = ThisApplication.TransientObjects.CreateNameValueMap
    Call oBaseViewOptions.Add("SheetMetalFoldedModel", False)

    ' Punkt erstelen, an dem die Ansicht platziert werden soll.
    Dim oPoint As Point2d
    Set oPoint = ThisApplication.TransientGeometry.CreatePoint2d(oSheet.Width + 10, oSheet.Height / 2)

    ' Ansicht erstellen im Maßstab 1:1
    Dim oBaseView As DrawingView
    Set oBaseView = oSheet.DrawingViews.AddBaseView(oModel, _
                                                    oPoint, _
                                                    1, _
                                                    kDefaultViewOrientation, _
                                                    kHiddenLineRemovedDrawingViewStyle, _
                                                    , _
                                                    , _
                                                    oBaseViewOptions)

    'Ansicht den einen Namen zur Identifizierung geben
    oBaseView.Name = "LASER"

End Sub

Wie gewünscht habe ich das dann umgeschrieben für die Verwendung in einer iLogic-Regel:

   
    'Actives Dokument holen
    Dim oDrawDoc As DrawingDocument
    oDrawDoc = ThisDrawing.Document

    'Aktives Blatt holen
    Dim oSheet As Sheet
    oSheet = oDrawDoc.ActiveSheet
      
    'Kurze Fehlerprüfung (einfach gehlaten zum Nachvollziehen)
    If oSheet.DrawingViews.Count = 0 Then
        'Keine Ansicht auf dem Blatt.
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor Is Nothing Then
        'Erstansicht nicht gültig für diesen Code (eventuell eine Entwurfsansicht)
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocumentType <> Inventor.DocumentTypeEnum.kPartDocumentObject Then
        'Auf der ersten Ansicht ist kein Einzeteil abgeleitet
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument.ComponentDefinition.Type <> Inventor.ObjectTypeEnum.kSheetMetalComponentDefinitionObject Then
        'Das Einzelteil ist kein Blech und kann hier nicht verarbeitet werden
        'Code wird nicht ausgeführt.
        Exit Sub
    End If
    'Fehlerprüfung ENDE
	
    'Mal eben schauen, ob es bereits eine Ansicht LASER auf dem Blatt gibt
    Dim tmpView As DrawingView
    For Each tmpView In oSheet.DrawingViews
        If tmpView.Name = "LASER" Then
            'Code wird verlassen, wenn es bereits eine Ansicht namens "LASER" auf dem Blatt gibt
            'MsgBox ("Ansicht LASER existiert bereits. Code wird verlassen.")
            Exit Sub
        End If
    Next

    'Referenziertes Modell holen aus der ersten Ansicht
    Dim oModel As PartDocument
    oModel = oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument

    'Wenn noch keine Abwicklung im Part ist, wird sie jetzt erstellt
    Dim tmpSheetCompDef As SheetMetalComponentDefinition
    tmpSheetCompDef = oModel.ComponentDefinition

    If tmpSheetCompDef.HasFlatPattern = False Then
        Call tmpSheetCompDef.Unfold
        'Sollte es hier zu einem Fehler kommen, muss die Ansicht zunächst manuell erstellt werden im Blechteil
    End If
    'Abwicklung im Blech jetzt vorhanden


    'Optionen zusammenstellen für die Ansicht der Abwicklung
    Dim oBaseViewOptions As NameValueMap
    oBaseViewOptions = ThisApplication.TransientObjects.CreateNameValueMap
    Call oBaseViewOptions.Add("SheetMetalFoldedModel", False)

    ' Punkt erstelen, an dem die Ansicht platziert werden soll.
    Dim oPoint As Point2d
    oPoint = ThisApplication.TransientGeometry.CreatePoint2d(oSheet.Width + 10, oSheet.Height / 2)
    ' Ansicht erstellen im Maßstab 1:1
	
    Dim oBaseView As DrawingView
    oBaseView = oSheet.DrawingViews.AddBaseView(oModel, _
												oPoint, _
												1, _
												Inventor.ViewOrientationTypeEnum.kDefaultViewOrientation, _
												Inventor.DrawingViewStyleEnum.kHiddenLineRemovedDrawingViewStyle, _
												, _
												, _
												oBaseViewOptions)

    'Ansicht den einen Namen zur Identifizierung geben
    oBaseView.Name = "LASER"

Verwendung des Code ist wie immer auf eigene Gefahr!

Auf das versprochene Bier freue ich mich schon

Betreff: Inventor (VBA/iLogic): Abwicklung neben das Blatt

S_May — Tue, 09 Jan 2018 12:13:10 GMT

Sehr cool Dennis, das gibt eine Kiste, wohin soll ich versenden lassen?

Betreff: Inventor (VBA/iLogic): Abwicklung neben das Blatt

j_weber — Wed, 10 Jan 2018 12:00:26 GMT

Coole Sache ,

da ich kein Alkohol trinke nützt ne Kiste nichts.

Obwohl, du bekommst ja schon eine