Thema "Betreff: Inventor (VBA/iLogic): Unterscheidung Modelmaß und Benutzermaß" in Inventor - Deutsches Forum

Inventor (VBA/iLogic): Unterscheidung Modelmaß und Benutzermaß

j_weber — Mon, 26 Feb 2018 11:49:39 GMT

Hallo liebe Prgrammierprofies unter uns,

guck zu Jürgen und Dennis,

in meinen Zeichnungsableitungen hab ich zwei Bemaßungstile. Einen DIN-Benutzer und einen DIN-Modell. Die Unterscheiden sich einzig durch die Farbe der Maß.

DIN-Benutzer ist für die normale benutzerdefinierte Bemaßung in einer Zeichnung, die DIN-Modell verwende ich für die Maße, die ich aus einem Modell abgreife. So kann ich Farblich gleich sehen, was ein Modellmaß ist und was ein Benutzermaß ist. Für die etwas älteren unter uns, so war es auch im Mechanical Desktop so.

Ich muß aber immer den Modellmaßen manuell den Bemaßungsstil zuweise, automatisch geht das nicht.

Jetzt wieder meine Idee über VBA oder über iLogic.

Ich habe aber kein Unterscheidungsmerkmal gefunden. Ich sehe immer nur LinearDimension oder ähnlich.

Gibt es da keine Unterscheidung.

Ich dachte nämlich, das ich vielleicht alle Maße in einer Zeichnung nach dem Merkmal prüfen lassen kann, und da wo es zutrifft, da ändere ich dann den Bemaßungsstil.

Ich würde es vielleicht sogar selbst versuchen zu lösen, Anhand von Beispielen oder anhand der Programmieranleitungen von Jürgen W.

also dann

schönen Sonntag noch.

@j_weber,

Die Themenüberschrift wurde zum besseren Auffindbarkeit editiert von Dennis.Ossadnik
Original: Frage an die Programmierprofies: Unterscheidung Modelmaß und Benutzermaß

Betreff: Inventor (VBA/iLogic): Unterscheidung Modelmaß und Benutzermaß

Juergen_Wagner — Mon, 26 Feb 2018 11:50:17 GMT

markiere ein abgerufene Bemaßung und führe das "Objekt Infoprogramm" aus ==> VBA Programmierung: Eigenschaften von Objekte anschauen

Vergleiche die Eigenschaften zwischen manuell erstelltem und abgerufenem Maß.

Das wird dir auffallen (nicht anderes habe ich gerade gemacht, weil ich es auch nicht "einfach so" wusste).

Andere Möglichkeit: Da du weißt, wie das API Objekt heißt, einfach nach in der API Hilfe suchen, wie hier beschrieben. Da findest du dann das:

Betreff: Inventor (VBA/iLogic): Unterscheidung Modelmaß und Benutzermaß

j_weber — Mon, 26 Feb 2018 11:50:45 GMT

Hallo Jürgen,

da war ich ja schon auf dem richtigen Weg.

Ich hatte auch schon die beiden Bemaßungen mit der Objektprüfung mir angeguckt. Ich bin nur nicht hinter den retrieved gekommen. Ich dacte da steht dann vielleicht was von model oder so.

Aber gut, ich lerne.

Kann man sich eigentlich auch so eine Art Liste ausdrucken lassen wie den die aktuellen Werte eines Objektes gerade sind. Das würde das vergleichen vereinfachen.

Vielen Dank bis hier hin. Ich versuche dann mal meine Idee umzusetzen.

Mal sehen wie weit ich komme.

bis dann

Betreff: Inventor (VBA/iLogic): Unterscheidung Modelmaß und Benutzermaß

Dennis.Ossadnik — Mon, 26 Feb 2018 12:15:36 GMT

j.weber schrieb:

guck zu Jürgen und Dennis,

Hallo Jörg,

falls Du mich gemeint haben solltest, bleibt da leider für mich mal wieder nichts zu tun... @Juergen_Wagner hat das wohl bereits abgeräumt.

Bei den meisten Sachen mache ich das übrigens genau wie Jürgen auch. Ich schaue mir mit der gleichen Funktion einfach das Objekt an und suche, ob es eine Eigenschaft oder Methode hat, die ich schon verwenden kann.

Was die Liste angeht, so schaue in normalerweise nur nach, um welches Objekt es sich genau handelt.

Dann suche ich dieses Objekt in der Programmierhilfe. So habe ich gleich alle Infos zur Verfügung - also was die Eigenschaft eigentlich meldet, ob man diese auch setzen oder nur abrufen kann und so weiter...

Hier mal ein Beispiel zum Volumenkörper:

Mit etwas Glück findet man so in der Hilfe auch schon die ersten Beispiele, wie man den Code anwenden kann oder muss.

Betreff: Inventor (VBA/iLogic): Unterscheidung Modelmaß und Benutzermaß

j_weber — Mon, 26 Feb 2018 12:15:37 GMT

Ich gebs auf.

Ich weiss nicht so recht wie ich was wann ermittel und was ich wie wann definiere.

Ich hab also schon rausgekommen, auf den Hinweis von Jürgen hin, das ich nach dem Wert retrieved gucken muss. Und das dieser Wert für Modellmaße tue ist.

Wenn ich das nun in eine Logic packen will, dann könnte das so aussehen.

If GeneralDimension.retireved = true then

GeneralDimension.Style = "Bemaßung-Modell"

end if

An den Wert komme ich über die Teilnehmer, ITEM, einer General Dimension, glaub ich jedenfalls. Sicher ist das Wechseln des Styles an dieser Stelle auch noch falsch.

Ich hab nach Beispielen gesucht wo man vielleicht einfach nur mal den Bemaßungsstil ändert, aber leider da nicht so viel gefunden.

Ich will aber nicht aufgeben, weil ich das alles ganz spannend finde

Vielleicht kann mir doch jemand eine Hilfe geben, wie ich da rangehen muss. Das wäre toll.

Und ist überhaupt das ganze ohne ein Prgrammierstudium möglich zu erlernen?

bis dann, ich hol jetzt erst mal ein Kaffee

Betreff: Inventor (VBA/iLogic): Unterscheidung Modelmaß und Benutzermaß

Juergen_Wagner — Mon, 26 Feb 2018 12:52:17 GMT

Du musst zwischen dem Objekt und der Klasse unterscheiden.

Beispiel: Die Klasse ist "Mensch" und das konkrete Objekt ist "Jörg", "Jürgen", "Dennis", ... ,d.h. alle einzelnen Menschen gehört zur Klasse "Mensch"

Alle einzelnen Menschen erben die Eigenschaften (Haarfarbe, Größe,....) und Methoden (Funktionen, die das Objekt ausführen kann, z.B. laufen, sprechen, trinken, essen) der Klasse "Mensch".

Soll ich ein Bier trinken, so lautet der Aufruf:

dim oMensch as Mensch

set oMensch = DieserRaum.Jürgen 'Wir stellen uns vor, wir wären gerade im gleichen Zimmer

Call oMensch.trinken("Bier")

du willst auf die Klasse "GeneralDimension" zugreifen, muss aber auf das konkrete Bemaßungsobjekt zugreifen.

Aus den API-Samples: "DrawingDimension" ist die Klasse während "oDrawingDim" das konkrete Objekt darstellt. Wenn man mittels einer Schleife durch alle Bemaßungen geht, bei jedem Durchlaufen eben ein anderes Maß.

Public Sub DeleteUnattachedDimensions()
    ' Set a reference to the active drawing document
    Dim oDoc As DrawingDocument
    Set oDoc = ThisApplication.ActiveDocument
    
    ' Set a reference to the active sheet
    Dim oSheet As Sheet
    Set oSheet = oDoc.ActiveSheet
    
    Dim oDrawingDim As DrawingDimension
    
    ' Iterate over all dimensions in the drawing
    ' and delete unattached (sick) dimensions.
    
    For Each oDrawingDim In oSheet.DrawingDimensions
        If oDrawingDim.Attached = False Then
            Call oDrawingDim.Delete
        End If
    Next
End Sub

Du musst das Call oDrawingDim.Delete durch die Funktion zum ändern des Stils ersetzen. Siehe dazu auch https://forums.autodesk.com/t5/inventor-customization/ilogic-to-change-dimension-style-of-certain-dimensions/td-p/5523708

Betreff: Inventor (VBA/iLogic): Unterscheidung Modelmaß und Benutzermaß

fullevent — Mon, 26 Feb 2018 13:03:50 GMT

Hallo @j_weber,

du hast bei dir einen kleinen Tippfehler im Code.. "Retrieved" statt "Retireved"

Mit dieser Regel kannst du alle DrawingDimensions durchlaufen und die Eigenschaft .Retrieved = True abfragen:

Dim oDrawDoc As DrawingDocument
oDrawDoc = ThisApplication.ActiveDocument

Dim oSheet As Sheet
oSheet = oDrawDoc.ActiveSheet

Dim oDrawDim As DrawingDimension

For Each oDrawDim In oSheet.DrawingDimensions
	If  oDrawDim.Retrieved = True Then
		'Hier muss dann noch der Style gesetzt werden
	End If
Next

Allerdings bin ich mir grad nicht sicher wie der Code ist um den .Style zu ändern.
Hättest du da eine idw zum Testen mit den benötigten Stilen?

Edit:
Das ist sooo gut und leicht nachvollziehbar erklärt vom Jürgen.. echt richtig gut!
Solange man das Gerüst und den Aufbau von Codebeispielen so gut erklärt bekommt, benötigt man meiner Meinung nach wirklich kein Informatikstudium für solche Geschichten

Betreff: Inventor (VBA/iLogic): Unterscheidung Modelmaß und Benutzermaß

Dennis.Ossadnik — Mon, 26 Feb 2018 13:10:17 GMT

Hallo Jörg,

ich hatte mal einen Code geschrieben, der die Splines markiert in der Zeichnung. Den habe ich mal umgeändert auf Deine Bedürfnisse...

Hier VBA-Code zum Testen:

Sub IDW_MarkRetrievedDimension()

Dim oApp As Application
Set oApp = ThisApplication

' // Zeichnung holen
Dim oDoc As DrawingDocument
Set oDoc = ThisApplication.ActiveDocument

Dim oLayers As LayersEnumerator
Set oLayers = oDoc.StylesManager.Layers

'Layer für die Medellbemaßung
Dim RetrievedLayer As Layer

'Nach dem Layer suchen...
Dim tmpLayer As Layer
For Each tmpLayer In oLayers

    If tmpLayer.Name = "Retrieved_Dimension" Then
        Set RetrievedLayer = tmpLayer
        Exit For
    End If
Next

'Wenn nichts zugeweisen ist, dann ist der Layer wohl nicht vorhanden
' --> also anlegen
If RetrievedLayer Is Nothing Then
        
    Set RetrievedLayer = oLayers.Item("1:Dimension (ISO)").Copy("Retrieved_Dimension")
                
        Dim myGreen As Inventor.Color
        Set myGreen = oApp.TransientObjects.CreateColor(50, 255, 100)
        
        RetrievedLayer.Color = myGreen
        
        'MsgBox ("Neuer Layer wurde angelegt.")
    
End If

' // nur für das aktive Blatt
' // vielleicht später für alle oder bestimmte Blätter...
Dim tmpSheet As Sheet
Set tmpSheet = oDoc.ActiveSheet

'Bei jedem Modellmaß den Layer ändern
Dim tmpDim As GeneralDimension
For Each tmpDim In tmpSheet.DrawingDimensions

    If tmpDim.Retrieved = True Then
    
        tmpDim.Layer = RetrievedLayer
    
    End If

Next

End Sub

Ich ändere in diesem Code allerdings nicht den gesamten Bemaßungsstil, sondern nur den Layer. Warum?

Wenn man hinterher wieder zurück möchte, finde ich es so einfacher. Sowohl im Code als auch für den Anwender von Hand.

Ich gehe mal davon aus, dass man mit Deinem Code "während der Arbeit" die farblichen Abgrenzungen sehen will, aber wenn man fertig st und nun die Datei freigeben oder drucken muss, dann sollen die Farben für den Vorgang ja auch ganz normal aussehen.

Du kannst den Stil allerdings auf die gleiche Weise anpassen, wie ich das hier mit den Layern getan habe. @Juergen_Wagner hatte ja schön erklärt worauf es ankommt.... Äh, wer trinkt noch mal das Bier?

Hier ein kleines Video, wie der Code in Aktion aussieht und wie man die Änderungen wieder leicht zurückstellen kann:

Hilft Dir das ein Stückchen weiter?

Bitte nutzt den "Als Lösung akzeptieren"-Button, wenn ein Beitrag euer Problem oder eure Frage löst. Für hilfreiche Posts könnt ihr auch gerne Kudos vergeben.

Betreff: Inventor (VBA/iLogic): Unterscheidung Modelmaß und Benutzermaß

j_weber — Mon, 26 Feb 2018 13:13:33 GMT

Danke euch, ich versuche es weiter.

Ja, die Erklärungen von Jürgen sind echt gut, so verstehe ich auch was.

vielen Dank an euch

Betreff: Inventor (VBA/iLogic): Unterscheidung Modelmaß und Benutzermaß

j_weber — Mon, 26 Feb 2018 15:36:03 GMT

Yippi, yibbi, yibbi, yippi.

Ich habs.

Public Sub Modellmaße()
 
Dim oDoc As DrawingDocument
Set oDoc = ThisApplication.ActiveDocument

Dim oSheet As Sheet
Set oSheet = oDoc.ActiveSheet

Dim oStylesManager As DrawingStylesManager
Set oStylesManager = oDoc.StylesManager

Dim oDimensionsStyle As DimensionStylesEnumerator
Set oDimensionsStyle = oStylesManager.DimensionStyles

Dim oModellDimStyle As DimensionStyle
Set oModellDimStyle = oDimensionsStyle.Item("Bemaßung - Modell")

Dim tmpDim As GeneralDimension
    For Each tmpDim In oSheet.DrawingDimensions
        If tmpDim.Retrieved = True Then
        tmpDim.Style = oModellDimStyle
    End If
Next

MsgBox ("Modellmaße wurden auf Stil " & oModellDimStyle.Name & " geändert")

Anhand der Erklärungen, Hilfen und langsames herantasten funktioniert es.

Hier der Beweiss

http://autode.sk/2F4AINQ

Es ist vielleicht nicht so ausgefeilt wie die anderen Lösungen, aber ich bin zufrieden damit. Es muss allerdings der Stil bekannt sein.

Vielleicht kann es der eine oder andere gebrauchen.