Thema "Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung" in Inventor - Deutsches Forum

Abwicklung auf Zeichnung mit definierter Bezeichnung

ThomasCassan — Tue, 23 Jul 2019 08:20:59 GMT

-----------------------------------------------ÜBERSETZUNG-----------------------------------------------

Hallo Freunde !!

Ich suche nach einer Möglichkeit, eine flache Projektion über iLogic einzufügen und den Ansichtstext anzuzeigen. Es sollte "ABWICKLUNG / FLAT PROJECTION" und die Skala stehen.

Gibt es jemanden, der mir bitte helfen kann?

vielen Dank!!

Thomas C.

---------------------------------------------------ORIGINAL--------------------------------------------------

Hi Buddies!!

I am looking for a way to insert a flat projection via iLogic and display the view text. It should say "ABWICKLUNG/FLAT PROJECTION" and the scale.

is there someone who can help me please??

thx a lot!!

Thomas C.

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

michele.mk — Tue, 23 Jul 2019 08:31:47 GMT

Hallo @ThomasCassan,

du befindest dich im deutschsprachigen Forum, ich habe daher deinen Beitrag übersetzt. Da ich kein Produktexperte bin würde ich dich bitten, mir zu sagen, falls etwas falsch übersetzt sein sollte.

Viele Grüße,

Michèle

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

ThomasCassan — Tue, 23 Jul 2019 08:43:15 GMT

HI
Es ist OK soweit

Danke!!
Thomas C.

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

S_May — Sat, 27 Jul 2019 12:28:50 GMT

Hallo @ThomasCassan

hast Du Dir das so vorgestellt?

    'Actives Dokument holen
    Dim oDrawDoc As DrawingDocument
    oDrawDoc = ThisDrawing.Document

    'Aktives Blatt holen
    Dim oSheet As Sheet
    oSheet = oDrawDoc.ActiveSheet
      
    'Kurze Fehlerprüfung (einfach gehlaten zum Nachvollziehen)
    If oSheet.DrawingViews.Count = 0 Then
        'Keine Ansicht auf dem Blatt.
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor Is Nothing Then
        'Erstansicht nicht gültig für diesen Code (eventuell eine Entwurfsansicht)
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocumentType <> Inventor.DocumentTypeEnum.kPartDocumentObject Then
        'Auf der ersten Ansicht ist kein Einzeteil abgeleitet
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument.ComponentDefinition.Type <> Inventor.ObjectTypeEnum.kSheetMetalComponentDefinitionObject Then
        'Das Einzelteil ist kein Blech und kann hier nicht verarbeitet werden
        'Code wird nicht ausgeführt.
        Exit Sub
    End If
    'Fehlerprüfung ENDE
	
    'Mal eben schauen, ob es bereits eine Ansicht LASER auf dem Blatt gibt
    Dim tmpView As DrawingView
    For Each tmpView In oSheet.DrawingViews
        If tmpView.Name = "LASER" Then
            'Code wird verlassen, wenn es bereits eine Ansicht namens "LASER" auf dem Blatt gibt
            'MsgBox ("Ansicht LASER existiert bereits. Code wird verlassen.")
            Exit Sub
        End If
    Next

    'Referenziertes Modell holen aus der ersten Ansicht
    Dim oModel As PartDocument
    oModel = oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument

    'Wenn noch keine Abwicklung im Part ist, wird sie jetzt erstellt
    Dim tmpSheetCompDef As SheetMetalComponentDefinition
    tmpSheetCompDef = oModel.ComponentDefinition

    If tmpSheetCompDef.HasFlatPattern = False Then
        Call tmpSheetCompDef.Unfold
        'Sollte es hier zu einem Fehler kommen, muss die Ansicht zunächst manuell erstellt werden im Blechteil
    End If
    'Abwicklung im Blech jetzt vorhanden


    'Optionen zusammenstellen für die Ansicht der Abwicklung
    Dim oBaseViewOptions As NameValueMap
    oBaseViewOptions = ThisApplication.TransientObjects.CreateNameValueMap
    Call oBaseViewOptions.Add("SheetMetalFoldedModel", False)

    ' Punkt erstelen, an dem die Ansicht platziert werden soll.
    Dim oPoint As Point2d
    oPoint = ThisApplication.TransientGeometry.CreatePoint2d(oSheet.Width + 10, oSheet.Height / 2)
    ' Ansicht erstellen im Maßstab 1:1
	
    Dim oBaseView As DrawingView
    oBaseView = oSheet.DrawingViews.AddBaseView(oModel, _
												oPoint, _
												1, _
												Inventor.ViewOrientationTypeEnum.kDefaultViewOrientation, _
												Inventor.DrawingViewStyleEnum.kHiddenLineRemovedDrawingViewStyle, _
												, _
												, _
												oBaseViewOptions)

    'Ansicht den einen Namen zur Identifizierung geben
    oBaseView.Name = "ABWICKLUNG / FLAT PROJEKTION"

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

michele.mk — Thu, 01 Aug 2019 13:26:57 GMT

Hallo @ThomasCassan,

und? War @S_Mays Antwort schon gleich ein richtiger Treffer? Falls ja, wärst du so lieb und markierst seine Antwort als Lösung? Einfach auf den Button "Als Lösung akzeptieren" klicken, dann profitieren auch andere Anwender von der Information.
Oder hast du in der Zwischenzeit weiter probiert und bist vielleicht selbst auf eine Lösung für dein Problem gekommen, die du mit uns teilen könntest? Falls ja, kann man deine Antwort als Lösung markieren. Nicht nur dass dadurch auch andere Anwender von der Information profitieren, die Lösung wird deinem Konto gutgeschrieben.

Falls nicht, dann lass uns doch wissen wie der Stand der Dinge ist.

Gruß,
Michèle

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

ThomasCassan — Mon, 19 Aug 2019 05:43:16 GMT

Hi !!

danke für dieses tolle Programm.

Leider ists nicht so ganz das was ich benötige.

1. Maßstab sollte 1:5 sein - das ist so der Durchschnitt der Blechteilgrösse, wenns anders ist kann ichs ja ohne weiters über Ansicht ändern entsprechend anpassen.

2. Die Ansichtsbezeichnung sollte in der Zeichnung stehen, nicht nur im Browser.Also einfach nur "sLicht" einschalten... 🙂

Anonsten funktionierts tadellos!!!

nochmals danke!!

Thomas C.

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

S_May — Mon, 19 Aug 2019 05:47:46 GMT

Hi @ThomasCassan

@ThomasCassan schrieb:

Hi !!

danke für dieses tolle Programm.

Leider ists nicht so ganz das was ich benötige.

1. Maßstab sollte 1:5 sein - das ist so der Durchschnitt der Blechteilgrösse, wenns anders ist kann ichs ja ohne weiters über Ansicht ändern entsprechend anpassen.

2. Die Ansichtsbezeichnung sollte in der Zeichnung stehen, nicht nur im Browser.Also einfach nur "sLicht" einschalten... 🙂

Anonsten funktionierts tadellos!!!

nochmals danke!!

lg

Thomas C.

Von 1:25 haste nix geschrieben
Der Text steht doch auf der Zeichnung über der Abwicklung somit auch später in der DXF

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

ThomasCassan — Mon, 19 Aug 2019 05:52:25 GMT

Von 1:25 haste nix geschrieben => stimmt - sorry - deshalb hab ichs jetzt ja nachgetragen
Der Text steht doch auf der Zeichnung über der Abwicklung somit auch später in der DXF => ne, nur im Browsertext und auch im Ansichststext (Bezeichnung) stehts drin - aber eben - die Lampe ist nicht aktiviert. Zumindest nicht bei mir!

danke für deinen Support!

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

S_May — Mon, 19 Aug 2019 08:12:26 GMT

Hi @ThomasCassan

kommst Du denn jetzt so zurecht?

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

ThomasCassan — Tue, 20 Aug 2019 06:18:34 GMT

wie gesagt - bei mir stehts nicht auf der Zeichnung - was muss ich da ändern??

und der Maßstab sollte 1:5 sein

kannst du das noch anpassen??

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

ThomasCassan — Fri, 23 Aug 2019 07:16:01 GMT

so jetzt ists gelöst

Ansichtsmaßstab auf 1:5 geändert

=> in der CodeZeile 72 den Wert 0.2 ändern, wers anders haben will

Ansichtsbezeichnung wird angezeigt

=> letzte Zeile steht auf "TRUE"

    'Actives Dokument holen
    Dim oDrawDoc As DrawingDocument
    oDrawDoc = ThisDrawing.Document

    'Aktives Blatt holen
    Dim oSheet As Sheet
    oSheet = oDrawDoc.ActiveSheet
      
    'Kurze Fehlerprüfung (einfach gehlaten zum Nachvollziehen)
    If oSheet.DrawingViews.Count = 0 Then
        'Keine Ansicht auf dem Blatt.
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor Is Nothing Then
        'Erstansicht nicht gültig für diesen Code (eventuell eine Entwurfsansicht)
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocumentType <> Inventor.DocumentTypeEnum.kPartDocumentObject Then
        'Auf der ersten Ansicht ist kein Einzeteil abgeleitet
        'Code wird nicht ausgeführt.
        Exit Sub
    ElseIf oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument.ComponentDefinition.Type <> Inventor.ObjectTypeEnum.kSheetMetalComponentDefinitionObject Then
        'Das Einzelteil ist kein Blech und kann hier nicht verarbeitet werden
        'Code wird nicht ausgeführt.
        Exit Sub
    End If
    'Fehlerprüfung ENDE
	
    'Mal eben schauen, ob es bereits eine Ansicht LASER auf dem Blatt gibt
    Dim tmpView As DrawingView
    For Each tmpView In oSheet.DrawingViews
        If tmpView.Name = "LASER" Then
            'Code wird verlassen, wenn es bereits eine Ansicht namens "LASER" auf dem Blatt gibt
            'MsgBox ("Ansicht LASER existiert bereits. Code wird verlassen.")
            Exit Sub
        End If
    Next

    'Referenziertes Modell holen aus der ersten Ansicht
    Dim oModel As PartDocument
    oModel = oSheet.DrawingViews.Item(1).ReferencedDocumentDescriptor.ReferencedDocument

    'Wenn noch keine Abwicklung im Part ist, wird sie jetzt erstellt
    Dim tmpSheetCompDef As SheetMetalComponentDefinition
    tmpSheetCompDef = oModel.ComponentDefinition

    If tmpSheetCompDef.HasFlatPattern = False Then
        Call tmpSheetCompDef.Unfold
        'Sollte es hier zu einem Fehler kommen, muss die Ansicht zunächst manuell erstellt werden im Blechteil
    End If
    'Abwicklung im Blech jetzt vorhanden


    'Optionen zusammenstellen für die Ansicht der Abwicklung
    Dim oBaseViewOptions As NameValueMap
    oBaseViewOptions = ThisApplication.TransientObjects.CreateNameValueMap
    Call oBaseViewOptions.Add("SheetMetalFoldedModel", False)

    ' Punkt erstelen, an dem die Ansicht platziert werden soll.
    Dim oPoint As Point2d
    oPoint = ThisApplication.TransientGeometry.CreatePoint2d(oSheet.Width + 10, oSheet.Height / 2)
    ' Ansicht erstellen im Maßstab 1:1
	
    Dim oBaseView As DrawingView
    oBaseView = oSheet.DrawingViews.AddBaseView(oModel, _
												oPoint, _
												0.2, _
												Inventor.ViewOrientationTypeEnum.kDefaultViewOrientation, _
												Inventor.DrawingViewStyleEnum.kHiddenLineRemovedDrawingViewStyle, _
												, _
												, _
												oBaseViewOptions)

    'Ansicht den einen Namen zur Identifizierung geben
    oBaseView.Name = "ABWICKLUNG / FLAT PROJEKTION"
	oBaseView.ShowLabel = True

vielen Dank für euren Support!!!

Thomas

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

ThomasCassan — Thu, 29 Aug 2019 11:34:56 GMT

Hi!!

ich hab noch ein Problem detektiert - wenn das Programm die Abwicklung erstellt, dann bleibt die Abwicklung in der ipt- Datei geöffnet. Kannst du mir noch den Befehl senden, diese Ansicht zu schliessen??

das wäre super!!

vielen Dank!

Thomas C.

Betreff: Abwicklung auf Zeichnung mit definierter Bezeichnung

alessandro.brandestini — Tue, 30 Aug 2022 14:56:04 GMT

Das ist der Code, aus dem direkt aus dem ipt die Zeichnung erstellt wird.

Allerdings ohne Prüfung und ohne automatische Abwicklungserstellung.

-> $Templates <- muss noch mit dem Pfad der Templates ersetzt werden (mit "" vorne und hinten).

-> $Norm.idw <- muss noch mit dem Gewünschten Template für die Zeichnung ersetzt werden.

Sub Main
	Dim oTargetDoc As Document = Nothing
	If RuleArguments.Exists("TargetDocument") Then
		oTargetDoc = RuleArguments.Value("TargetDocument")
	Else
		oTargetDoc = ThisDoc.Document
	End If
	If IsNothing(oTargetDoc) Then Exit Sub
	If oTargetDoc.DocumentType <> DocumentTypeEnum.kAssemblyDocumentObject And _
		oTargetDoc.DocumentType <> DocumentTypeEnum.kPartDocumentObject Then
		Exit Sub
	End If
	'if oTargetDoc has not been saved yet, then accessing its FullFileName will throw Error
	Dim oTargetDocFFN As String = ""
	Try
		oTargetDocFFN = oTargetDoc.FullFileName
	Catch
		Exit Sub
	End Try
	If oTargetDocFFN = "" Then Exit Sub 'making sure it was filled in
	Dim oDrawingFullFileName As String = System.IO.Path.ChangeExtension(oTargetDocFFN, ".idw")
	If System.IO.File.Exists(oDrawingFullFileName) Then
		oOverWrite = MsgBox("A Drawing for this model already exists." & vbCrLf &
		"Do you want to over-write it?", vbYesNo + vbQuestion, "DRAWING EXISTS!")
		If oOverWrite = vbNo Then Exit Sub
	End If
	
	Dim oTPath As String = "$Templates"
	Dim oTName As String = "$Norm.idw"
	Dim oTFullFileName As String = System.IO.Path.Combine(oTPath, oTName)
	Dim oDDoc As DrawingDocument = Nothing
	If System.IO.File.Exists(oTFullFileName) Then
		oDDoc = ThisApplication.Documents.Add(DocumentTypeEnum.kDrawingDocumentObject, oTFullFileName, True)
	Else
		MsgBox("Template Drawing could not be found!", vbCritical, "")
		Exit Sub
	End If

	'Using RangeBox to get model size
	Dim oRangeBox As Box = oTargetDoc.ComponentDefinition.RangeBox
	Dim oXDim As Long = (oRangeBox.MaxPoint.X - oRangeBox.MinPoint.X)
	Dim oYDim As Long = (oRangeBox.MaxPoint.Y - oRangeBox.MinPoint.Y)
	Dim oZDim As Long = (oRangeBox.MaxPoint.Z - oRangeBox.MinPoint.Z)
	
	Dim oModelWidth As Long = MaxOfMany(oXDim, oYDim, oZDim)
	Dim oModelHeight As Long = MinOfMany(oXDim, oYDim, oZDim)
	
	Dim oViewRotation As Double = 0.0
	Dim oViewOrientation As ViewOrientationTypeEnum = Nothing
	If oModelWidth = oXDim And oModelHeight = oYDim Then
		oViewOrientation = ViewOrientationTypeEnum.kFrontViewOrientation
		oViewRotation = 0
	ElseIf oModelWidth = oXDim And oModelHeight = oZDim Then
		oViewOrientation = ViewOrientationTypeEnum.kTopViewOrientation
		oViewRotation = 0
	ElseIf oModelWidth = oYDim And oModelHeight = oXDim Then
		oViewOrientation = ViewOrientationTypeEnum.kFrontViewOrientation
		oViewRotation = (PI / 2)
	ElseIf oModelWidth = oYDim And oModelHeight = oZDim Then
		oViewOrientation = ViewOrientationTypeEnum.kRightViewOrientation
		oViewRotation = (PI / 2)
	ElseIf oModelWidth = oZDim And oModelHeight = oXDim Then
		oViewOrientation = ViewOrientationTypeEnum.kTopViewOrientation
		oViewRotation = (PI / 2)
	ElseIf oModelWidth = oZDim And oModelHeight = oYDim Then
		oViewOrientation = ViewOrientationTypeEnum.kRightViewOrientation
		oViewRotation = 0
	End If

	'Get the size of the Active Sheet
	Dim oSheetWidth As Double = oDDoc.ActiveSheet.Width
	Dim oSheetHeight As Double = oDDoc.ActiveSheet.Height
	
	'Get size of area within border available for views (used for scaling views)
	Dim oSideBorderOffset As Double = 5
	Dim oTopBottomBorderOffset As Double = 0.5
	Dim oTitleBlockHeight As Double = 2.5
	Dim oBorderWidth As Double = oSheetWidth-(oSideBorderOffset * 2)
	Dim oBorderHeight As Double = oSheetHeight - (oTopBottomBorderOffset * 2)
	Dim oAreaAboveTitleBlock As Double = (oBorderHeight - oTopBottomBorderOffset) - oTitleBlockHeight

	'Set view scale, based on model width
	Dim oBViewScale As Double = 0.0
	If oModelWidth > (oBorderWidth / 2) Then
		oBViewScale = ((oBorderWidth / 2) / oModelWidth)
	ElseIf oModelWidth < (oBorderWidth / 2) Then
		oBViewScale = (oModelWidth / (oBorderWidth / 2))
	End If

	inc = 1/32
	oBViewScale = Round(Round(oBViewScale, 5) / inc) * inc
	'oBViewScale = 1/2

	'Try creating & placing each view at 1:1 scale, then scale to needed factor.
	Dim oTG As TransientGeometry = ThisApplication.TransientGeometry
	Dim oViews As DrawingViews = oDDoc.ActiveSheet.DrawingViews
	
	Dim oFullScale As Double = 1
	Dim oOriginPoint As Point2d = oTG.CreatePoint2d(0, 0)
	Dim oBaseView As DrawingView = oViews.AddBaseView(oTargetDoc, oOriginPoint, oFullScale, _
	oViewOrientation, DrawingViewStyleEnum.kHiddenLineDrawingViewStyle)

	'Locations of view centerpoint columns & rows
	Dim o1stColumn As Double = oSideBorderOffset + (oBorderWidth / 4)
	Dim o2ndColumn As Double = oSideBorderOffset + ((oBorderWidth / 4) * 3)
	Dim o1stRow As Double = oTopBottomBorderOffset + oTitleBlockHeight + (oAreaAboveTitleBlock / 4)
	Dim o2ndRow As Double = oTopBottomBorderOffset + oTitleBlockHeight + ((oAreaAboveTitleBlock / 4) * 3)

	'Base View center point location
	'Dim oBaseViewLocation As Point2d = oTG.CreatePoint2d(o1stColumn, o1stRow)

	'Dim oBaseView As DrawingView = oViews.AddBaseView(oTargetDoc, oBaseViewLocation, oBViewScale, _
	'oViewOrientation, DrawingViewStyleEnum.kHiddenLineDrawingViewStyle)
	'oBaseView.Rotation = oViewRotation
	'oBaseView.Position = oBaseViewLocation
	oBaseView.Scale = oBViewScale
	'oBaseView.ScaleString = RoundToFraction(oBViewScale, 1 / 32, RoundingMethod.Round)
	'oBaseView.Center = oBaseViewLocation
	'oBaseView.RotateByAngle = 
	'oBaseView.IncludeMeshBodies = True
	'oBaseView.IncludeSurfaceBodies = True
	'oBaseView.Top
	'oBaseView.Height
	'oBaseView.Left
	'oBaseView.Width
	'oBaseView.Name = "BASE VIEW"
	'oDDoc.Update
	'MsgBox("Center Of View Is At:  " & oBaseView.Center.X & " , " & oBaseView.Center.Y)
	'MsgBox("oBViewScale = " & oBaseView.ScaleString)

	'Dim oUpperViewInsPoint As Point2d = oTG.CreatePoint2d(o1stColumn, o2ndRow)
	'Dim oUpperView As DrawingView = oViews.AddProjectedView(oBaseView, oUpperViewInsPoint, _
	'DrawingViewStyleEnum.kFromBaseDrawingViewStyle)
	'oUpperView.Name = "UPPER VIEW"
	'oUpperView.IncludeMeshBodies = True
	'oUpperView.IncludeSurfaceBodies = True
	
	'Dim oRightViewInsPoint As Point2d = oTG.CreatePoint2d(o2ndColumn, o1stRow)
	'Dim oRightView As DrawingView = oViews.AddProjectedView(oBaseView, oRightViewInsPoint, _
	'DrawingViewStyleEnum.kFromBaseDrawingViewStyle)
	'oRightView.Name = "RIGHT VIEW"
	'oRightView.IncludeMeshBodies = True
	'oRightView.IncludeSurfaceBodies = True
	
	
	Dim oISOViewInsPoint As Point2d = oTG.CreatePoint2d(o2ndColumn, o2ndRow)
	Dim oISOView As DrawingView = oViews.AddProjectedView(oBaseView, oISOViewInsPoint, _
	DrawingViewStyleEnum.kShadedDrawingViewStyle)
	oISOView.Name = "ISO VIEW"
	oISOView.IncludeMeshBodies = True
	oISOView.IncludeSurfaceBodies = True
	
	'Optionen zusammenstellen für die Ansicht der Abwicklung
	Dim oBaseViewOptions As NameValueMap
    oBaseViewOptions = ThisApplication.TransientObjects.CreateNameValueMap
	Call oBaseViewOptions.Add("SheetMetalFoldedModel", False)
	
	Dim oABWInsPoint As Point2d = oTG.CreatePoint2d(o1stColumn, o2ndRow)
	Dim oABW As DrawingView = oViews.AddBaseView(oTargetDoc, _
	 oABWInsPoint, _
	 1.0, _
	 Inventor.ViewOrientationTypeEnum.kDefaultViewOrientation, _
	 Inventor.DrawingViewStyleEnum.kHiddenLineRemovedDrawingViewStyle, _
	 , _
	 , _
	 oBaseViewOptions)

	oABW.Name = "Abwicklung"
	oABW.IncludeMeshBodies = True
	oABW.IncludeSurfaceBodies = True
	oDDoc.SaveAs(oDrawingFullFileName, False)


End Sub