topic Re: Voltage Controlled Current Source not simulatable in EAGLE Forum

Voltage Controlled Current Source not simulatable

tedj1 — Wed, 14 Feb 2018 21:32:22 GMT

Hi. I've run into a perplexing problem. I get the message "The part cannot be simulated, check value and connections" when I try to include in a model a spice 'Gxxx' part (a voltage controlled current source) that is of the form:

Syntax: Gxxx n+ n- value={<expression>}

although the form:

Syntax: Gxxx n+ n- nc+ nc- <gain>

is simulatable at least. I haven't checked its results, but have no reason to suspect it either.

In my case, the expression is:

{I(V4)-I(V5)+I(V6)+I(V7)-I(V8)-I(V9)}

But how to transform a summed current into a voltage between two pins? Or does Autodesk have any plan to implement that non-working form of a VCCS?

Thanks, Ted

Re: Voltage Controlled Current Source not simulatable

tedj1 — Thu, 15 Feb 2018 00:07:10 GMT

Oops. Guess it's simple enough:

*** set Vnode

VA NA 0 Value={I(V4)-I(V5)+I(V6)+I(V7)-I(V8)-I(V9)}

*** Iout = Vnode * Gain

GA 1 2 NA 0 1

instead of:

GA 1 2 Value={I(V4)-I(V5)+I(V6)+I(V7)-I(V8)-I(V9)}

But now it's failing on this line:

EB6 33 0 Value={0.25*V(15)*V(6)*V(8)}

and not failing on this one prior to it:

EB4 10 0 Value={IF(V(7)>1 & V(3)>(0.3+V(2)), 2, 0)}

I can't fathom what the difference might be that one would produce an error and the other not do so. And maybe my earlier assumptions about the original problem weren't quite as expected. ??

Re: Voltage Controlled Current Source not simulatable

jorge_garcia — Thu, 15 Feb 2018 17:35:19 GMT

Hi Ted,

I hope you're doing well. By the nature of your two posts I'm getting the impression that you are copying a netlist into the simulator and trying to run that, without creating an EAGLE schematic. Is that the case?

I know that there are certain things that we currently don't support even if you run them through the netlist mechanism. I'll pin the SPICE developer on this issue and he will most likely respond here, if not I will..

In the mean time I encourage you to attach your file so that it can be reviewed in it's entirety. Sometimes the issue can lie beyond the lines we post.

Let me know if there's anything else I can do for you.

Best Regards,

Re: Voltage Controlled Current Source not simulatable

ed.pataky — Thu, 15 Feb 2018 17:49:58 GMT

Re: Voltage Controlled Current Source not simulatable

edpataky — Thu, 15 Feb 2018 17:54:29 GMT

Hi Ted, please post a picture of the schematic, or the schematic itself ... i need to know for example, what are the actual names of the sources .. the format you used V(7) for example mean that there is a node named "7" in the circuit ... maybe in reality you have a source named "V7"? in that case it should be V(V7,0) for example .. as Jorge said, it seems like you may have done this manually and if so i think the format is incorrect .. please post at least the full netlist and i can figure out what you need to do

Re: Voltage Controlled Current Source not simulatable

edpataky — Thu, 15 Feb 2018 21:52:43 GMT

Ted,

reading your post again, you said:

"But how to transform a summed current into a voltage between two pins? Or does Autodesk have any plan to implement that non-working form of a VCCS?"

First, the syntax from the ngspice manual is:

GXXXXXXX N+ N- NC+ NC- VALUE <m=va l >

Secondly, you can only use current in expressions like this: I(Vxx), where you have I and inside is the name of an independent voltage source .. so in fact your second form is correct where you noted: {I(V4)-I(V5)+I(V6)+I(V7)-I(V8)-I(V9)}

Based on that question, you want a current controlled voltage source CCVS not VCCS correct? First, I want to point you to the example under examples/ngspice/Sources . open the one called sources.sch and you will see examples of how to use these sources.

For a basic CCVS you have a gain setting called h and a ref value which needs to point to voltage source ... this will take the current through the ref source and multiply by h for the final output voltage. However, this may be too simple for what you want ...

IF what you want is to sum currents and turn that into a voltage, then i would recommend just use the arbitrary source Bxxx:

This works perfectly and is what you need I think. Notice the 1mA and 3mA from the sources V1 and V2 are translated into voltage of 4mV coming ou of source B1. The netlist is below.

* --------- devices ---------
B_B1 N_1 0 v=I(V_V1)+I(V_V2) 
R_R1 0 V1 1k 
R_R2 0 V2 1k 
R_R3 0 N_1 1k 
V_V1 V1 0 1V 
V_V2 V2 0 3V

You will notice there is an extra V_ or B_ or R_ prefixed to the part names after netlisting, this is done by EAGLE, and if you are using expressions that you manually enter, then you need to include this prefix. Otherwise let me know if this works for you, and thank you for the post. 🙂

Re: Voltage Controlled Current Source not simulatable

tedj1 — Fri, 16 Feb 2018 23:14:20 GMT

Thank you so much, jorge. Pleased to hear from you.

>By the nature of your two posts I'm getting the impression that you are copying a netlist into the simulator and trying to run that, without creating an EAGLE schematic. Is that the case?

I put it into a device. I know how to create a new device and populate a package and symbol and add a model in Eagle, although you're right. It's from On Semiconductor's large library of PSPICE, ISSPICE and other models at:

http://www.onsemi.com/PowerSolutions/supportDoc.do?type=models&rpn=NCP511

I'm working with NCP511P.LIB file attached (PSPICE LDO voltage regulator).

I've ultimately gotten stuck at the functions I(node pair) and V(node) which work fine in the latest LTSpice, but throw errors in Eagle. Maybe I'm missing a library? The simulator reports:

Error: Part GP5 cannot be simulated, check value and connections!

and there are I() and V() errors in the log. The short doc file is the .mdl (the uploader didn't like the .MDL part). The long doc is my .LBR file (the uploader didn't like the .LBR part).

Best regards,
Ted

Re: Voltage Controlled Current Source not simulatable

edpataky — Sat, 17 Feb 2018 16:42:06 GMT

i see it is pspice model not a pure spice model .. i can probably convert it for you .. i will work on it .. hopefully there are not too many pspice-specific lines in the model so it wont be too difficult .. i will post once i analyze it

Re: Voltage Controlled Current Source not simulatable

tedj1 — Sat, 17 Feb 2018 17:49:48 GMT

>i see it is pspice model not a pure spice model .. i can probably convert it for you .. i will work on it .. hopefully there are not too many pspice-specific lines in the model so it wont be too difficult .. i will post once i analyze it

Hi Ed. My but Autodesk is first rate in their support gurus. 🙂 So helpful. I looked for an automated translater but didn't get far. Are there any good references describing the difference? Thanks for those circuits. I'd like to see LTSpice's netlist export of them. My symbol looks like the standard circle and arrow. Do your pictured voltage controlled current sources come with LTSpice? I wish On Semiconductor would do the job but the two listed are apparently all they offer for that model.

Thanks and regards, Ted

Re: Voltage Controlled Current Source not simulatable

edpataky — Sat, 17 Feb 2018 20:06:44 GMT

I do not know of any automatic translator, but the difference is usually in the special functions used ..

OK, first issue, in the model, there is a line "V1 11 5", this is invalid, the voltage has no value and i have no idea what it should be .. let's just put 0V for now ... my guess is that it is used just to get a current, as in the expression used later "I(V1)", in which case 0V is correct ... There are several others, so set them all to 0V if there is no value.

Then we have several lines that we need to look at for ngspice:

EB3 14 0 Value={IF(V(10)>1 & V(3)>(1.3+V(2)), 0, 2)}
EB4 10 0 Value={IF(V(7)>1 & V(3)>(0.3+V(2)), 2, 0)}
GB5 1 2 Value={I(V4)-I(V5)+I(V6)+I(V7)-I(V8)-I(V9)}
EB6 33 0 Value={0.25*V(15)*V(6)*V(8)}
EB7 29 0 Value={1.521+10.557*I(V1)}

The formats possible in ngspice are:

EXXXXXXX n+ n- vol=’expr’
EXXXXXXX n+ n- value ={ expr }
GXXXXXXX n+ n- cur=’expr’ <m=val>
GXXXXXXX n+ n- value=’expr’ <m=val>
GXXXXXXX N+ N- NC+ NC- VALUE <m=val>

These actually look fine except for the IF function used .. you can get equivalent functionality using the unit step function "u" and some basic math .. see ngspice manual

However, this line: "V2 7 0 PULSE 0 2" is not a correct format .. format is: "PULSE(V1 V2 TD TR TF PW PER)", unfortunately i am not sure what is meant by that line ..

Another issue: this line "X1 14 10 8 30 RS1500" points to a subcircuit model called RS1500 which is not supplied and similarly for "X3 9 15 NC511LIM", so you would need those models for this to work

This can certainly be converted, but there are several issues here, and missing models. The pulse statement is the only one that i am a bit perplexed by, since how can you define a pulse source without a period or pulse width? i suppose pspice must have a spec that has those parameters optional, but still it seems odd .. .i would try to find the spec for that function in pspice, and then you can convert it to a more pure spice implementation: "PULSE(V1 V2 TD TR TF PW PER)"

According to this page: http://www.stuffle.net/references/PSpice_help/sources.html, there are in fact some default values for the pulse function that seem to indicate it is a one time pulse, where period is set to TSTOP and PW is set to TSTEP .. this makes sense as defaults ... so, a bit of digging around, and some conversion, you can get this to work! Hope this helps.

Re: Voltage Controlled Current Source not simulatable

edpataky — Sat, 17 Feb 2018 20:21:26 GMT

the ispice version of the models seem closer, although they also have the issue of voltages without values, and the pulse function undefined .. but those use the ternary operator for IF, which will work ( ? : ) in ngspice .. i would remove the DC=value version and just use value for voltage sources as well ... i will see what else i can find .. i think i am almost there

Re: Voltage Controlled Current Source not simulatable

edpataky — Sat, 17 Feb 2018 20:28:19 GMT

ok got it to work .. the ternary operators were a bit odd as well, with 2 question marks but only one colon ... not sure i converted correctly, you may want to check that:

.SUBCKT NCP511SN33 1 2 3 5
*3.3Volt 150mA CMOS Low IQ Low-Dropout Voltage Regulator
*Terminal identifications:
*VIN=1 GND=2 ENABLE=3 VOUT=5
.MODEL IQDIODE1 D CJO=2P N=0.93
.MODEL IQDIODE2 D CJO=2P
.MODEL IQDIODE3 D CJO=2P N=0.2
.MODEL IQDIODE4 D CJO=2P N=0.17
.MODEL PMSERIES PMOS Level=1 CBD=2.05E-11 CBS=2.46E-11
+ CGBO=8.40E-08 CGDO=3.00E-08 CGSO=3.60E-08 CJ=0
+ GAMMA=1.59E-06 IS=3.01E-14 KP=61.6E-02 LAMBDA=10E-03 MJ=.46
+ PB=0.80 PHI=0.75 RD=0 RS=0.3 VTO=-0.75
.SUBCKT RS1500 2 3 4 5
C1 11 0 10P
R3 10 8 144.269
C3 8 0 10P
B1 10 0 V=V(2)>1 ? V(5)>1 ? 0 : 2 : 2
B2 16 0 V=V(3)>1 ? V(4)>1 ? 0 : 2 : 2
B5 4 0 V=V(8)>1 ? 2 : 0
B6 5 0 V=V(11)>1 ? 2 : 0
R1 16 11 144.269
.ENDS
.SUBCKT NC511LIM 1  2
RIN 1 0 1E12
E1 3 0 0 1 1
RC1 2 4 1MEG
C1 2 4 1F IC=0
R1 3 4 1MEG
E2 2 0 0 4 1E6
VN 5 2 1.9403
DN 4 5 DN
.MODEL DN D(IS=1E-12 N=.14319)
VP 2 6 1.9403
DP 6 4 DN
.ENDS
R1 12 16 10
X1 14 10 8 30 RS1500
E3 16 2 9 33 1
B3 14 0 V=V(10)>1 ? V(3)>(1.3+V(2)) ? 0 : 2 : 2
B4 10 0 V=V(7)>1 ? V(3)>(0.3+V(2)) ? 2 : 0 : 0
V1 11 5 0
E2 9 0 1 2 1
R2 11 28 42K
R3 28 31 35K
V2 7 0 PULSE(0 2 0 10n 10n 1n 100)      
B5 1 2 I=I(V4)-I(V5)+I(V6)+I(V7)-I(V8)-I(V9)
E1 4 0 13 28 1k
V3 13 2 1.5V
X2 4 17 NC511LIM
B6 33 0 V=0.25*V(15)*V(6)*V(8)
R4 17 6 10k
C2 6 0 10p
R5 9 18 50K
D3 18 19 IQDIODE1
V4 19 0 0V
R6 9 20 50K
D4 20 21 IQDIODE2
V5 21 0 1.1V
R7 9 22 97K
D5 22 23 IQDIODE2 
V6 23 29 0
R8 9 24 23K
D6 24 25 IQDIODE3 
V7 25 29 1.25V
R9 9 26 19.3K
D7 26 27 IQDIODE4 
V8 27 29 1.4V
B7 29 0 V=1.521+10.557*I(V1)
R10 1 3 1MEG
V9 31 2 0V
R11 2 1 10MEG
D8 2 5 IQDIODE2 
M1 11 12 1 1 PMSERIES 
X3 9 15 NC511LIM
R14 32 5 20
C3 1 32 70n
*Designed by Kehinde Omolayo 3-17-04
.ENDS

Re: Voltage Controlled Current Source not simulatable

edpataky — Sat, 17 Feb 2018 20:44:50 GMT

actually i think it still needs some work, but that should help you get started ... when adding an offset to the output voltage something is still wrong, but it simulates .. i think the issue must be in the conversions ... just check one by one and make sure the mapping makes sense.

Re: Voltage Controlled Current Source not simulatable

edpataky — Sun, 18 Feb 2018 04:59:50 GMT

Ted, i have found more information on this operator with two question marks: https://www.electronicspoint.com/threads/weird-spice-conditional-expression-syntax-a-b-c-d-what-does-itmean.68236/

From this page i see that the two question marks act like an AND function before the condition is completely defined .. that means you need to convert the a?b?c:d into a?b?c:d:d, in fact that is what i did so if that information is correct then that part is right ..

since this is a 3.3V LDO maybe if you simulate this with VIN=4V see how it works

Re: Voltage Controlled Current Source not simulatable

edpataky — Sun, 18 Feb 2018 05:35:58 GMT

OK, Ted, figured it out .. it was my PULSE function that was wrong in the end .. here is the correct model for ngspice

* model file: /Users/patakye/Documents/eagle/test/test/NCP511SN33.mdl
* |=======================================================
* |                    NCP511SN33        REV - 03/17/04
* |                (IsSPICE VERSION)
* |                ON SEMICONDUCTOR
* |  3.3Volt 150mA CMOS Low Iq Low-Dropout Voltage Regulator
* |
* | This model was developed for ON Semiconductor bY:
* | OK Power Systems
* | 
* | 
* |
* | Copyright 2004 OK Power Systems
* | All Rights Reserved
* |
* | The content of this model is subject to change
* | without notice and may not be modified or altered
* | without permission from ON Semiconductor. This model
* | has been carefully checked and is believed to be
* | accurate, however neither OK Power Systems nor
* | ON Semiconductor assume liability for the use of
* | this model or the results obtained from using it.
* |
* | For more information regarding modeling services,
* | model libraries or simulation productors, please
* | call at (631) 654-0253 ext 116 or 106.
* |
* |=======================================================
*Designed by Kehinde Omolayo 3-17-04
.SUBCKT NCP511SN33 1 2 3 5
*3.3Volt 150mA CMOS Low IQ Low-Dropout Voltage Regulator
*Terminal identifications:
*VIN=1 GND=2 ENABLE=3 VOUT=5
.MODEL IQDIODE1 D CJO=2P N=0.93
.MODEL IQDIODE2 D CJO=2P
.MODEL IQDIODE3 D CJO=2P N=0.2
.MODEL IQDIODE4 D CJO=2P N=0.17
.MODEL PMSERIES PMOS Level=1 CBD=2.05E-11 CBS=2.46E-11
+ CGBO=8.40E-08 CGDO=3.00E-08 CGSO=3.60E-08 CJ=0
+ GAMMA=1.59E-06 IS=3.01E-14 KP=61.6E-02 LAMBDA=10E-03 MJ=.46
+ PB=0.80 PHI=0.75 RD=0 RS=0.3 VTO=-0.75
.SUBCKT RS1500 2 3 4 5
C1 11 0 10P
R3 10 8 144.269
C3 8 0 10P
B1 10 0 V=V(2)>1 ? V(5)>1 ? 0 : 2 : 2
B2 16 0 V=V(3)>1 ? V(4)>1 ? 0 : 2 : 2
B5 4 0 V=V(8)>1 ? 2 : 0
B6 5 0 V=V(11)>1 ? 2 : 0
R1 16 11 144.269
.ENDS
.SUBCKT NC511LIM 1  2
RIN 1 0 1E12
E1 3 0 0 1 1
RC1 2 4 1MEG
C1 2 4 1F IC=0
R1 3 4 1MEG
E2 2 0 0 4 1E6
VN 5 2 1.9403
DN 4 5 DN
.MODEL DN D(IS=1E-12 N=.14319)
VP 2 6 1.9403
DP 6 4 DN
.ENDS
R1 12 16 10
X1 14 10 8 30 RS1500
E3 16 2 9 33 1
B3 14 0 V=V(10)>1 ? V(3)>(1.3+V(2)) ? 0 : 2 : 2
B4 10 0 V=V(7)>1 ? V(3)>(0.3+V(2)) ? 2 : 0 : 0
V1 11 5 0
E2 9 0 1 2 1
R2 11 28 42K
R3 28 31 35K
V2 7 0 PULSE(0 2 0 1u 1u 500m 500m)      
B5 1 2 I=I(V4)-I(V5)+I(V6)+I(V7)-I(V8)-I(V9)
E1 4 0 13 28 1k
V3 13 2 1.5
X2 4 17 NC511LIM
B6 33 0 V=0.25*V(15)*V(6)*V(8)
R4 17 6 10k
C2 6 0 10p
R5 9 18 50K
D3 18 19 IQDIODE1
V4 19 0 0
R6 9 20 50K
D4 20 21 IQDIODE2
V5 21 0 1.1
R7 9 22 97K
D5 22 23 IQDIODE2 
V6 23 29 0
R8 9 24 23K
D6 24 25 IQDIODE3 
V7 25 29 1.25
R9 9 26 19.3K
D7 26 27 IQDIODE4 
V8 27 29 1.4
B7 29 0 V=1.521+10.557*I(V1)
R10 1 3 1MEG
V9 31 2 0
R11 2 1 10MEG
D8 2 5 IQDIODE2 
M1 11 12 1 1 PMSERIES 
X3 9 15 NC511LIM
R14 32 5 20
C3 1 32 70n
*Designed by Kehinde Omolayo 3-17-04
.ENDS

I setup the sim as transient from 0 to 100ms, and the source VIN as 4.3V (as in the app note in your zip file) but with some jitter on the line, 10mV worth .. you can see the output voltage is a nice clean 3.3V.

Re: Voltage Controlled Current Source not simulatable

edpataky — Sun, 18 Feb 2018 05:46:32 GMT

my guess is that the pulse statement models an internal 2V reference in the IC, but they used a pulse so that it could "turn on" and work as a catalyst for other conmected circuits

Re: Voltage Controlled Current Source not simulatable

tedj1 — Thu, 22 Feb 2018 15:17:03 GMT

Ed,

I'm not impressed. I'm awed by your effort. Thank you so much. It is very helpful.