topic Station and offset of 105 COGO points in relation to 291 alignments in Civil 3D Customization Forum

Station and offset of 105 COGO points in relation to 291 alignments

K_Aboumosalam — Fri, 27 Sep 2024 17:08:19 GMT

I am working with Civil 3D and need to calculate the station and offset of 105 COGO points in relation to 291 alignments. Is there is a way to do all of this at once.

Re: Station and offset of 105 COGO points in relation to 291 alignments

hippe013 — Fri, 27 Sep 2024 19:02:09 GMT

It can be written in LISP using the COM API or it can be written in C# or VB using the .NET API. Using either API you can get the necessary information from the Cogo Point to use in the calculation of the station and offset from the alignment. What do you imagine for the output?

Re: Station and offset of 105 COGO points in relation to 291 alignments

hosneyalaa — Fri, 27 Sep 2024 22:46:01 GMT

Can you attached example drawing

Re: Station and offset of 105 COGO points in relation to 291 alignments

K_Aboumosalam — Sat, 28 Sep 2024 04:29:41 GMT

Thanks for your help, I just need the information to be like this:

Point Number

Easting

Northing

Elevation

Raw Description

Compare to Alignment

Compared Station

Compared Easting

Compared Northing

Compared Elevation

Compared Offset (XY)

Re: Station and offset of 105 COGO points in relation to 291 alignments

K_Aboumosalam — Sat, 28 Sep 2024 04:30:42 GMT

I have attached a screenshot as a ref.

Re: Station and offset of 105 COGO points in relation to 291 alignments

hippe013 — Mon, 30 Sep 2024 13:35:28 GMT

Most of your export values are self-explanatory, however, some of them could use further clarification.

Compare Alignment = Name of Alignment, simple enough

Compared Station = Station Value of the Cogo, but what happens when there is no station solution? Use the closest point?

Compared Easting = I assume that this is the easting of the point on Alignment, but what value should be used when no solution exists? Use the closest point?

Compared Northing = same as above compared Easting, what value when no solution exists? Use the closest point?

Compared Elevation = not sure what you want here, the elevation of the input cogo point?

It would be helpful to clarify the above values.

Re: Station and offset of 105 COGO points in relation to 291 alignments

K_Aboumosalam — Tue, 01 Oct 2024 04:53:21 GMT

Compare Alignment = Name of Alignment, simple enough Correct

Compared Station = Station Value of the Cogo, but what happens when there is no station solution? Use the closest point? No, please keep it blank. if no intersection between the point and an aligment the value shall be blank.

Compared Easting = I assume that this is the easting of the point on Alignment, but what value should be used when no solution exists? Use the closest point? please keep it blank. if no intersection between the point and an aligment the value shall be blank.

Compared Northing = same as above compared Easting, what value when no solution exists? Use the closest point?

please keep it blank. if no intersection between the point and an aligment the value shall be blank.

Compared Elevation = not sure what you want here, the elevation of the input cogo point?

Need the elevation of the new point on alignment.

Compared Offset (XY) = not sure what you want for this, the (XY) is throwing me off, typically the offset value is the distance from the point directly to the alignment, and if that is the case, what value for when there is no station solution? Use the closest point? Yes, I mean the direct value from point to alignment, if no intersection between the point and an aligment the value shall be blank.

Re: Station and offset of 105 COGO points in relation to 291 alignments

hippe013 — Tue, 01 Oct 2024 14:59:42 GMT

We can ignore the fact that you will end up with 30,555 results by comparing 105 cogo points with 291 alignments.

Let us consider an example and work out the details using LISP and the COM API.

In the figure above point 'A' lies in an area where there is not a solution for the station & offset.

Using Point 'A' Coordinates (X Y) and the following method:

(vlax-invoke-method align 'StationOffset x y 'Station 'Offset)

Station = 0.0

Offset = 0.0

We can get the closest point ("point on line" pol) on the alignment using the following method:

(setq pol (vlax-curve-getClosestPointTo align (list x y)))

then using that point 'pol' we can get the station & offset again using this point.

(vlax-invoke-method align 'StationOffset (car pol) (cadr pol) 'Station2 'Offset2)

Station2 = 50.11

Offset2 = 0.00

Now, we could say that since station & station2 are not equal that point 'A' lands in an area where there is no solution, however if using the method I describe above on point 'B' we will see that station and station2 will be both 0.0. So, what I am getting at, is it will be difficult to determine when the values should be blank. For point 'A' we can determine that it lies in a bad area as Station and Station2 will not be equal, however, for point 'B' it is not as clear.

Utilizing LISP and the COM API it will be difficult to determine which points have valid station & offset values for a given alignment. We could just run the with the first method and just insert whatever values we get from the StationOffset method. You will have zeros for your station & offset for points that don't have a solution. If you are okay with this, we can write this in LISP using the COM API.

It might be advantageous to use .NET API for a multitude of reasons. One being that using the station offset method in the .NET API will throw an exception will for both points 'A' & 'B'. We can catch this exception and therefor leave them blank. Are you familiar with coding in the .NET API?

Lastly, your compared elevation, I still don't understand what you want for this value.

"Need the elevation of the new point on alignment."

The alignment is two-dimensional, I am not understanding what elevation, other than the source elevation, you are looking to achieve. Could you clarify further?

Re: Station and offset of 105 COGO points in relation to 291 alignments

hippe013 — Tue, 01 Oct 2024 19:16:17 GMT

Here is an example code for you to test. I've made an attempt to include error traps, but I am sure someone will find something.

(defun c:CogoToAlignmentReport ( / pntSS alignSS fileName file i cnt cogo j align line) (princ "\nSelect Cogo Points: ") (setq pntSS (ssget '(( 0 . "AECC_COGO_POINT")))) (if pntSS (progn (princ "\nSelect Alignments: ") (setq alignSS (ssget '(( 0 . "AECC_ALIGNMENT")))) (if alignSS (progn (setq fileName (getfiled "Export Cogo / Alignment Report" "" "csv" 1)) (if fileName (progn (setq file (open fileName "w")) (if file (progn (setq i 0) (setq cnt 0) (repeat (sslength pntSS) (setq cogo (vlax-ename->vla-object (ssname pntSS i))) (setq j 0) (repeat (sslength alignSS) (setq align (vlax-ename->vla-object (ssname alignSS j))) (setq line (cogo:PrintCogoStationOffset cogo align 3)) (write-line line file) (setq j (+ j 1)) (setq cnt (+ cnt 1)) );repeat alignSS (setq i (+ i 1)) );repeat pntSS (close file) (princ (strcat "\nSuccessfully exported " (itoa cnt) " lines to file.")) ) (princ "\nError: Could not open File.") );If File ) (princ "\nError: Could not obtain File Name.") );If filename ) (princ "\nError: Must have an Alignment Selection.") );If alignSS ) (princ "\nError: Must have a Cogo Point Selection.") );If pntSS (princ) );defun ;Arguments: ;cogo - CogoPoint as a VLA-OBJECT ;align - Alignment as a VLA-OBJECT ;prec - Desrired precision as an Integer ;Returns: a String of comma separated values (defun cogo:PrintCogoStationOffset (cogo align prec) (setq pn (vlax-get-property cogo 'Number)) (setq x (vlax-get-property cogo 'Easting)) (setq y (vlax-get-property cogo 'Northing)) (setq z (vlax-get-property cogo 'Elevation)) (setq desc (vlax-get-property cogo 'RawDescription)) (vlax-invoke-method align 'StationOffset x y 'Station 'Offset) (vlax-invoke-method align 'PointLocation station 0.0 'polX 'polY) (setq name (vlax-get-property align 'Name)) (setq str (strcat (itoa pn) "," (rtos x 2 prec) "," (rtos y 2 prec) "," (rtos z 2 prec) "," desc "," name "," (rtos station 2 prec) "," (rtos polX 2 prec) "," (rtos polY 2 prec) "," (rtos z 2 prec) "," (rtos offset 2 prec))) )

Re: Station and offset of 105 COGO points in relation to 291 alignments

K_Aboumosalam — Wed, 02 Oct 2024 07:43:04 GMT

Thank you so much for your help! Most of my alignments are straightforward without complex curves, so I felt that Method One would be a perfect fit for my needs.

"Need the elevation of the new point on alignment."

As for the elevation of the new point on the alignment, I can easily address that later. My main objective was to determine the elevation of the COGO point from the surface, which I can retrieve directly from the surface data when necessary.

I tested the code, and it works flawlessly! I genuinely appreciate your assistance—you’ve saved me a tremendous amount of time. Even though I completed the task using a different method, I know this code will be incredibly valuable for my future projects. I can't thank you enough!

Re: Station and offset of 105 COGO points in relation to 291 alignments

hippe013 — Wed, 02 Oct 2024 13:26:27 GMT

I am happy that it worked for you.