topic Re: flatten feature line elevations by single command in Civil 3D Customization Forum

flatten feature line elevations by single command

robert06 — Thu, 31 Aug 2017 14:44:41 GMT

How could I flatten feature line elevations by single command?

Natively it can be achieved:

a) setting a point of a feature line to the elevation and running 'set feature grade'

b) changing 0+00 point in 'grading elevation editor' plus running 'flatten grade or elevations' from the button after selecting all the points in the list.

The options available are rough for a simple operation like that, is there a lisp available?

Re: flatten feature line elevations by single command

hippe013 — Thu, 31 Aug 2017 21:33:14 GMT

This should get you started.

(defun c:flatfl ()
  (setq sel (entsel "\nSelect Featureline: "))
  (setq elev (getreal "\nEnter Elevation: "))
  (if (and sel elev)
    (progn
      (setq obj (vlax-ename->vla-object (car sel)))
      (setq pnts (vlax-safearray->list (vlax-variant-value (vlax-invoke-method obj 'GetPoints  3))))
      (setq i 0)
      (repeat (/ (length pnts) 3)
	(setq x (nth i pnts))
	(setq y (nth (+ i 1) pnts))
	(vlax-invoke-method obj 'SetPointElevation (vlax-3d-point x y elev))
	(setq i (+ i 3))
	)
      )
    )
  (princ)
  )

Re: flatten feature line elevations by single command

robert06 — Fri, 01 Sep 2017 07:17:12 GMT

Excellent!

Thank you!

Re: flatten feature line elevations by single command

hippe013 — Fri, 01 Sep 2017 14:33:12 GMT

You bet. Happy I could help.

Re: flatten feature line elevations by single command

robert06 — Mon, 08 Oct 2018 06:59:04 GMT

Can you also flatten the grade between feature line endpoints?

Re: flatten feature line elevations by single command

hippe013 — Mon, 08 Oct 2018 15:01:38 GMT

StraightGrade - Hold Start and End Elevations - Create a Straight Grade In-between

(defun c:StraightGrade ()
  ;Prompt for Featureline
  (princ "\nSelect Featureline: ")
  (setq ss (ssget ":s" '((0 . "AECC_FEATURE_LINE"))))

  ;If we have a Selection Set then proceed
  (if ss
    (progn
      ;Get Object from SelectionSet
      (setq obj (vlax-ename->vla-object (ssname ss 0)))
      
      ;Get All Points (3)   |  (1)=PI Points (2)=Elevation Points
      (setq pnts (vlax-safearray->list (vlax-variant-value (vlax-invoke-method obj 'GetPoints  3))))
      
      ;Get the Point Count - ;(setq pCount (vlax-get-property obj 'PointsCount))
      (setq pCount (/ (length pnts) 3))

      ;Compute
      (setq sp (list (nth 0 pnts)(nth 1 pnts)(nth 2 pnts)))
      (setq ep (list (nth (- (length pnts) 3) pnts)(nth (- (length pnts) 2) pnts)(nth (- (length pnts) 1) pnts)))
      (setq zDiff (- (caddr ep) (caddr sp) ))
      (setq len (vlax-get-property obj 'Length2D))
      (setq slope (/ zDiff len))

      ;Report
      (princ (strcat "\nStart Point Elev: " (rtos (caddr sp) 2 2)))
      (princ (strcat "\nEnd Point Elev: " (rtos (caddr ep) 2 2)))
      (princ (strcat "\nElevation Difference: " (rtos zDiff 2 2)))
      (princ (strcat "\nTotal 2D Length: " (rtos len 2 2)))
      (princ (strcat "\nUsing Slope of: " (rtos (* slope 100.00) 2 2) "%"))

      ;Set increment to Beginning of Second Point
      (setq i 3)

      ;Repeat for each point except the first and last
      (repeat (- pCount 2)
	
	;Get Current Point
	(setq p (list (nth i pnts) (nth (+ i 1) pnts) (nth (+ i 2) pnts)))
	
	;Get its 2D Distance along the Featureline
	(setq dist (vlax-curve-getDistAtPoint obj p))
	
	;Compute
	(setq newZ (+ (* dist slope) (caddr sp)))
	(setq newP (list (car p)(cadr p) newZ))

	;Set the Elevation
	(vlax-invoke-method obj 'SetPointElevation (vlax-3d-point newp))

	;Increment
	(setq i (+ i 3))
	)
      )
    )
  (princ)
  )

Re: flatten feature line elevations by single command

robert06 — Mon, 08 Oct 2018 15:44:30 GMT

Greatly appreciated, thank you!

A closed feature line is flattened to the starting station elevation just like it mathematically logical is.

Only thing comparing your lisps to Civil's native feature line editing commands is that the grading surface is not automatically updated, automatic surface rebuilding is not "awakened".

What's the command in Civil to rebuild a surface? Rebuild is accessed through Toolspace + right click on the surface name, but command name is hidden.

Re: flatten feature line elevations by single command

hippe013 — Mon, 08 Oct 2018 17:02:08 GMT

I added '(Command "REGENALL")' to the code to trigger the rebuild of the surface. I believe that the surface still needs to be set to Automatic Re-Build.

(defun c:StraightGrade ()
  ;Prompt for Featureline
  (princ "\nSelect Featureline: ")
  (setq ss (ssget ":s" '((0 . "AECC_FEATURE_LINE"))))

  ;If we have a Selection Set then proceed
  (if ss
    (progn
      ;Get Object from SelectionSet
      (setq obj (vlax-ename->vla-object (ssname ss 0)))
      
      ;Get All Points (3)   |  (1)=PI Points (2)=Elevation Points
      (setq pnts (vlax-safearray->list (vlax-variant-value (vlax-invoke-method obj 'GetPoints  3))))
      
      ;Get the Point Count - ;(setq pCount (vlax-get-property obj 'PointsCount))
      (setq pCount (/ (length pnts) 3))

      ;Compute
      (setq sp (list (nth 0 pnts)(nth 1 pnts)(nth 2 pnts)))
      (setq ep (list (nth (- (length pnts) 3) pnts)(nth (- (length pnts) 2) pnts)(nth (- (length pnts) 1) pnts)))
      (setq zDiff (- (caddr ep) (caddr sp) ))
      (setq len (vlax-get-property obj 'Length2D))
      (setq slope (/ zDiff len))

      ;Report
      (princ (strcat "\nStart Point Elev: " (rtos (caddr sp) 2 2)))
      (princ (strcat "\nEnd Point Elev: " (rtos (caddr ep) 2 2)))
      (princ (strcat "\nElevation Difference: " (rtos zDiff 2 2)))
      (princ (strcat "\nTotal 2D Length: " (rtos len 2 2)))
      (princ (strcat "\nUsing Slope of: " (rtos (* slope 100.00) 2 2) "%"))

      ;Set increment to Beginning of Second Point
      (setq i 3)

      ;Repeat for each point except the first and last
      (repeat (- pCount 2)
	
	;Get Current Point
	(setq p (list (nth i pnts) (nth (+ i 1) pnts) (nth (+ i 2) pnts)))
	
	;Get its 2D Distance along the Featureline
	(setq dist (vlax-curve-getDistAtPoint obj p))
	
	;Compute
	(setq newZ (+ (* dist slope) (caddr sp)))
	(setq newP (list (car p)(cadr p) newZ))

	;Set the Elevation
	(vlax-invoke-method obj 'SetPointElevation (vlax-3d-point newp))

	;Increment
	(setq i (+ i 3))
	)
      )
    )
  (command "REGENALL")
  (princ)
  )

Re: flatten feature line elevations by single command

robert06 — Mon, 08 Oct 2018 18:48:31 GMT

Regen doesn't rebuild surfaces even if they are set to rebuild automatically.

With referral to Jeff_M https://forums.autodesk.com/t5/civil-3d-forum/rebuild-all/td-p/3361321

I added:

(initget "Yes No")
(setq yorn (cond ((getkword "\n Rebuild surface(s)? [Yes/No] <Yes>: ")) ("Yes")))
(cond ((and (= yorn "Yes") (ssget '((0 . "AECC_*SURFACE")))) ;;rebuild selected surfaces
(vlax-for ent (vla-get-activeselectionset
(vla-get-activedocument
(vlax-get-acad-object)))
(vlax-invoke ent 'rebuild)
)
))

Thank you!

Re: flatten feature line elevations by single command

robert06 — Mon, 15 Oct 2018 08:06:10 GMT

Still, maybe there is a way to trigger Civil to notice that a feature line part of a grading or surface has changed to rebuild the surface automatically? There probably is a call for that as native Civil feature line elevation editing commands do this. It would give @hippe013 's excellent lisps the full functionality.

Re: flatten feature line elevations by single command

hippe013 — Mon, 15 Oct 2018 14:41:40 GMT

I do realize that I misspoke when I stated "'(Command "REGENALL")' to the code to trigger the rebuild of the surface".

I urge you to do the following test. Create a simple surface that contains a featureline as a breakline in the surface. Set the surface rebuild to automatic. Now using a the above command that DOES NOT contain regenall and see if you get the the surface react to the command. Now with the same surface use the above command that does contain regenall. I am certain you will see why I added the simple (Command "REGENALL") to the end of the code.

Re: flatten feature line elevations by single command

robert06 — Wed, 17 Oct 2018 05:59:38 GMT

Ok, I did not test 'regenall' through the lisp as I did not expect that it works differently if featured in the lisp.

The affected surfaces are rebuilt then indeed, thank you.