topic Re: lisp to extract insertion point of profile view in Civil 3D Customization Forum

lisp to extract insertion point of profile view

ssm-jt — Mon, 04 Mar 2019 18:02:36 GMT

would like some direction to write a lisp to extract the insertion point of a profile view

thanks

Re: lisp to extract insertion point of profile view

hippe013 — Mon, 04 Mar 2019 19:57:26 GMT

I don't believe that the location/position property is exposed.

Re: lisp to extract insertion point of profile view

ssm-jt — Mon, 04 Mar 2019 20:01:46 GMT

typical......hate to be able to make it simple

Re: lisp to extract insertion point of profile view

hippe013 — Mon, 04 Mar 2019 20:05:10 GMT

You could use .NET. I know that lisp has it's benefits, but .NET has quite a bit more power. It would also be fairly simple to do in .NET.

Re: lisp to extract insertion point of profile view

ssm-jt — Mon, 04 Mar 2019 20:08:43 GMT

yes....i have been told this from past questions i have asked.....dont know where to start with .net

took me long enough to scrape by in lisp...

Re: lisp to extract insertion point of profile view

hippe013 — Mon, 04 Mar 2019 20:16:02 GMT

Well, you've come to the right place if you'd like to learn.

I would start by downloading Visual Studio Community. I could help you from there.

Re: lisp to extract insertion point of profile view

Jeff_M — Tue, 05 Mar 2019 01:10:13 GMT

This can be done with lisp. The following function requires a valid ProfileView vla-object to be passed to it and returns the 2d point of insertion.

(defun pvinspt (pv / x y)
  (vlax-invoke-method pv 'findxyatstationandelevation (vlax-get pv 'stationstart) (vlax-get pv 'elevationmin) 'x 'y)
  (list x y)
  )
''example:
(setq ent (car (entsel "\nSelect ProfileView"))
      pview (vlax-ename->vla-object ent)
      )
(pvinspt pview)

Re: lisp to extract insertion point of profile view

Jeff_M — Tue, 05 Mar 2019 01:23:04 GMT

Note that this does not work with styles having an Axis Offset other than 0. Stay tuned for an updated function to address that.

Re: lisp to extract insertion point of profile view

Jeff_M — Tue, 05 Mar 2019 01:43:40 GMT

This one works with Axis offsets and detects the direction of the profileview to get the correct insertion point.

(defun pvinspt (pv / x y)
  (vlax-invoke-method pv 'getboundingbox 'll 'ur)
  (setq style (vlax-get pv 'style))
  (setq direction (vlax-get (vlax-get style 'graphstyle) 'direction))
  (if (= direction 0)
    (vlax-safearray->list ll)
    (list (car (vlax-safearray->list ll)) (cadr (vlax-safearray->list ur)) 0.0)
    )
  )

Re: lisp to extract insertion point of profile view

Jeff_M — Tue, 05 Mar 2019 15:53:06 GMT

Ack, I reversed the order of the (list...) in that last post. It should be this:
(list (car (vlax-safearray->list ur)) (cadr (vlax-safearray->list ll)) 0.0)

Re: lisp to extract insertion point of profile view

hippe013 — Wed, 06 Mar 2019 20:47:02 GMT

@Jeff_M Nice work. I didn't think to use the bounding box. I looked for the location / position property and when I didn't find it I just ended it there. I believe that you had intended to declare your local variables and you edited your last line so I took the liberty of making those changes and posting your revised code.

(defun pvinspt (pv / ll ur style direction)
  (vlax-invoke-method pv 'getboundingbox 'll 'ur)
  (setq style (vlax-get pv 'style))
  (setq direction (vlax-get (vlax-get style 'graphstyle) 'direction))
  (if (= direction 0)
    (vlax-safearray->list ll)
    (list (car (vlax-safearray->list ur)) (cadr (vlax-safearray->list ll)) 0.0)
    )
  )

Re: lisp to extract insertion point of profile view

Jeff_M — Wed, 06 Mar 2019 21:00:17 GMT

@hippe013 , thanks for posting the corrected code. Just shows how one should not try to post code when one is in a hurry to get a project done, but still want to help here. Just take the extra few minutes to make sure all is good before posting it.