sujet Re : Automatisation Baie 19" dans AutoCAD – tous produits - Forum Français

Automatisation Baie 19"

Kevin_Megel — Mon, 15 Jun 2015 09:40:37 GMT

Hello la communauté, je vous solicite surtout pouyr avoir des informations,

dans le cadre de mon travail, je suis parfois amené a dessiner des baie 19" (ou rack 19") avec l'instalation du materiel dedans. et il y a plusieur taille possible qui se compte en nombre de U (42U 24 U ect...)

Mon objectifs est de pouvoir lorque j'ai mis tout mon materiel de selectionné et de posser directement la baie adequoite. et evité de compté le nombre de U pour choisir la baie.

bref j'aimerais faire

-Pose du materiel

-Selection de celui ci

-Calcule automatique du nombre de U

-Choix automatique de la baie.

Est ce que c'est possible de programme un tel truc ? Avec mes compétence actuel ?

Il y a bien sur des taille standard donc serait il possible de créer des fourchette, par exemple entre 37 et 42 U ça selectione automatiquement une baie 42U ?

Je ne sais pas si j'ai été claire, si il y a des question n'hesitez pas.

Re : Automatisation Baie 19"

patrick_35 — Mon, 15 Jun 2015 10:03:53 GMT

Salut

Tu peux dessiner ta baie sous Excel

Re : Automatisation Baie 19"

Kevin_Megel — Mon, 15 Jun 2015 10:14:47 GMT

et ensuite dessiné le materiel ? je suis pas assez bon en exel pour faire un tel prodige (surtout avec le detail de tout)

Re : Automatisation Baie 19"

Anonymous — Mon, 15 Jun 2015 12:14:24 GMT

Bonjour Megeon,

Si j'ai bien compris, tu as déjà des blocs correspondant à chaque éléments ?

Si tel es le cas, je ne connais pas la taille de ta bibliothèque, mais pour simplifier la programmation, insére un attribut invisible et constant dans chaque bloc bibliothèque avec le nombre de U.

Lors du dessin, une fois que tu as posé le matériel, les différentes étapes de la commande serais :

- Sélection des éléments avec éventuellement un filtre pour ne sélectionner que les blocs concernés.

- Vérification de la validité des blocs sélectionnés (si le filtre n'est pas suffisant).

- Pour chaque bloc, retrouver l'attribut, enregistrer la valeur dans une variable et l'additionner.

- Avec une fonction cond, insérer le bon bloc.

Tu devrais facilement trouver des exemples des différentes étapes sur les forums.

Olivier

Re : Automatisation Baie 19"

Kevin_Megel — Mon, 15 Jun 2015 12:24:18 GMT

oui j'ai deja mes bloc et pour le oment la bibilothes n'est pas tres importante. donc modifiable.

ensuite serait t'il possible de faire une selection a l'ecrans, car il m'arrive d'avoir sur le m^me dessin ( par chantier en faite) plusieur baie différente .

Re : Automatisation Baie 19"

Anonymous — Mon, 15 Jun 2015 12:39:08 GMT

Tu peux faire une sélection à l'écran.

Par exemple :

(ssget (list '(0 . "insert") (cons 2 "essai*")))

Lance une sélection classique filtrant uniquement les blocs commençant par essai.

Olivier

Re : Automatisation Baie 19"

Kevin_Megel — Mon, 15 Jun 2015 13:30:11 GMT

Merci Olivier, et merci Patrick, je vais essayer de commencer qqch avec ces éléments.

Re : Automatisation Baie 19"

Kevin_Megel — Wed, 17 Jun 2015 09:05:57 GMT

hello bon j'ai commencé mes recherches sur ce programme, et avant d'avoir trop avancer je vien voir si tout vous parrait ok

voici comment j'ai decomposé le programme

1 Selection des blocs commençant par 19pouces

(ssget (list '(0 . "insert")(cons 2 "19pouces)

2 Rechercher le nombre de "u" (via un attributqui sera en première place car j'en aurais plusieur)

(setq ent (car (entsel)))

3 Additionné le nombre de "U" (la je commence a coincer)

ici je suppose que je doit chercher a additioner la liste que j'ai créer dans le "2"

4 selection de la baie d'une taille supperieur ou egal au nombre de "u" calculer ( et j'ai même pas commencer a chercher)

Re : Automatisation Baie 19"

Anonymous — Wed, 17 Jun 2015 09:57:57 GMT

Bonjour Megeon,

1- Utilise tu réellement l'éditeur comme te la recommandé _Gile car tu devrais très repérer une erreur à la fin de ton filtre. Ormis cette erreur, tu sélectionne tous les blocs s'appellant 19pouces alors que tu veux sélectionner tout ceux commencant par 19pouces. Il te faut ajouter le signe * pour préciser.

Avec de poster, test ta ligne de code pour vérifier si elle fonctionne ou non.

2- Nous nous sommes mal compris. Avec ta ligne de code, tu demande à l'utilisateur de sélectionner un objet.

La sélection des blocs est déjà faite dans le numéro 1. Il te faut ensuite faire une boucle sur ta sélection pour trouver dans chaque bloc la valeur de U.

Voici un exemple similaire à ce que tu veux faire :

;;;Commande nmax indiquant la valeur maximum de l'attribut N°
;;;-Olivier- le 26/02/2013
(defun c:nmax (/ entbloc ent num n)
  (setq ss1 (ssget (list '(0 . "INSERT") '(66 . 1)))) ; filtre les blocs contenant un attribut
  (setq	n    0
	num -1e99
  )
  (repeat (sslength ss1) ; répète autant de fois qu'il y a d'éléments dans la sélection
    (progn (setq entbloc (ssname ss1 n)
		 ent	 (entnext entbloc)
	   )
	   (while (/= (cdr (assoc 0 (entget ent))) "SEQEND") ; répète qu'à l'objet SEQUEND (fin du bloc)
	     (if (and (= (cdr (assoc 0 (entget ent))) "ATTRIB")
		      (= (cdr (assoc 2 (entget ent))) "N°")
		      (/= (cdr (assoc 1 (entget ent))) "")
		 )
	       (setq num (max num (read (cdr (assoc 1 (entget ent))))))
	     )
	     (setq ent (entnext ent))
	   )
	   (setq n (1+ n))
    )
  )
  (if (= num -1e99)
    (alert "Pas de valeur valide")
    (alert (strcat "La valeur maximum est de : " (rtos num)))
    )
  (princ)
)

3- Oui une simple addition de la valeur du U de chaque bloc. (voir code précédent.

4- Un simple appel à la commande "insert" avec un chemin prédéfini et assortie d'une condition. Regarde la fonction COND.

Olivier

Re : Automatisation Baie 19"

Kevin_Megel — Wed, 17 Jun 2015 10:21:18 GMT

pour le 1 oui j'utilise l'editeur, j'ai recopier, mais j'ai oublié "*" je n'ai pas fait de copier coller 😕

sinon j'ai beau me concentré et faire les chose carré, j'ai du mal avec le code....

Re : Automatisation Baie 19"

patrick_35 — Wed, 17 Jun 2015 12:41:12 GMT

Salut

Tu as plusieurs possibilités pour dessiner la baie.

1) Elle peut-être dynamique (pour le nombre de U et pour la taille)
2) Elle peut-être dessinée depuis une nomenclature (Excel ou autre) avec insertion des éléments.
3) Elle peut-être dessinée sans recherche des attributs depuis des éléments connues (par exemple un passe-fil = 1U; panneau 24 ports = 1U; panneau 48ports = 2U) insérés dans le dessin.
4) Ne pas oublier une réserve

Le plus simple est d'avoir un exemple pour savoir comment la dessiner depuis quels éléments.

Re : Automatisation Baie 19"

Kevin_Megel — Wed, 17 Jun 2015 13:21:32 GMT

salut patrick

1) j'en ai déjà une de dynamique, mais ce que je voudrait c'est de ne pas compté ne nombre de U moi même apres pour passer a l'achat.

2) Excel c'est bien, pour travailler en interne le but de ça c'est pour les clients,

3) ça revien a faire le calcul moi même est c'est pas se que je recherche.

4) parfois on a des reserve, parfois non ça depend des chantier.

pour les exemples, disons que je sais se que j'insert :

1switch Admin 1U

1Switch 1U

1Passe fil 1U

1 Switch 1U

1 Patch RJ 1U

1Ventil 1U

1 amplis 2U

1 ventil 1U

1 amplis 3U

1 ventil 1U

1 amplis 3U

En selectionnant le tout la lisp me sort la bai de taille adequat ici 16U donc une baie 16U

ensuite on a des standart donc :

de 0 à 8 : 8U

de 9 à 10 : 10U

de 10 à 12 : 12U

de 13 à 16 : 16U

de 17 à 24 : 24U

de 25 à 32 : 32U

de 33 à 42 : 42U

Re : Automatisation Baie 19"

patrick_35 — Wed, 17 Jun 2015 13:56:49 GMT

Pour le 2, le but est justement de dessiner une baie pour le client à partir de données internes.

Sinon, un exemple

(defun c:nbu(/ doc sel tot)
  (setq doc (vla-get-activedocument (vlax-get-acad-object))
	tot 0
  )
  (vla-startundomark doc)
  (and (ssget (list (cons 0 "insert")))
    (progn
      (vlax-for ent (setq sel (vla-get-activeselectionset doc))
	(cond
	  ((vl-position (vla-get-effectivename ent) '("1switch Admin" "1Switch" "1Passe fil" "1Patch RJ")); Liste des équipements de 1U
	    (setq tot (1+ tot))
	  )
	  ((vl-position (vla-get-effectivename ent) '("1 amplis")); Liste des équipements de 2U
	    (setq tot (+ tot 2))
	  )
	  ((vl-position (vla-get-effectivename ent) '("1 amplis2" "1 amplis3")); Liste des équipements de 3U
	    (setq tot (+ tot 3))
	  )
	)
      )
      (vla-delete sel)
    )
  )
  (vla-endundomark doc)
  (princ (strcat "\nNombre de U trouvé : " (itoa tot)))
  (princ)
)

Re : Automatisation Baie 19"

patrick_35 — Wed, 17 Jun 2015 14:03:17 GMT

Pour le 2, le but est justement de dessiner une baie pour le client à partir de données internes.

Sinon, par exemple

(defun c:nbu(/ doc sel tot)
  (setq doc (vla-get-activedocument (vlax-get-acad-object))
	tot 0
  )
  (vla-startundomark doc)
  (and (ssget (list (cons 0 "insert")))
    (progn
      (vlax-for ent (setq sel (vla-get-activeselectionset doc))
	(cond
	  ((vl-position (vla-get-effectivename ent) '("1switch Admin" "1Switch" "1Passe fil" "1Patch RJ")); Liste des équipements de 1U
	    (setq tot (1+ tot))
	  )
	  ((vl-position (vla-get-effectivename ent) '("1 amplis")); Liste des équipements de 2U
	    (setq tot (+ tot 2))
	  )
	  ((vl-position (vla-get-effectivename ent) '("1 amplis2" "1 amplis3")); Liste des équipements de 3U
	    (setq tot (+ tot 3))
	  )
	)
      )
      (vla-delete sel)
    )
  )
  (vla-endundomark doc)
  (princ (strcat "\nNombre de U trouvé : " (itoa tot)))
  (princ)
)

Re : Automatisation Baie 19"

Kevin_Megel — Wed, 17 Jun 2015 14:10:47 GMT

je suis pas sur de comprendre ton code, il va falloire mettre toute les nom des bloc 1U/2U/3U/4U/.... ?

ça risque d'être colossale cette manneuvre surtout que j'ai regulièrement des nouveauté

Re : Automatisation Baie 19"

patrick_35 — Wed, 17 Jun 2015 14:20:39 GMT

C'était l'idée de départ, mais tu peux aussi ne pas mettre tous les 1U, mais uniquement ceux qui ont plus et à la fin du cond, comptabiliser les 1U (par contre, attention à la sélection ou au filtre)

Re : Automatisation Baie 19"

Kevin_Megel — Wed, 17 Jun 2015 14:40:15 GMT

j'y ai penssé de mettre que les plus courant le soucis c'est que ça depend que chaque chantier ce que l'on met dedant, et donc les passe fils, les u plein, et les u de ventil certe c'est regulier mais les switch ça depand deja de la marque que l'on met, plus le type de switch du coup on peut arrive pour les switchs ( juste les switchs ) a environ une 10 ene de regulier, tu fait ça pour les patch par la suite puis les amplis aussi ça devien colossale, d'ou l'interet de recupérer un attribut qui donne la taille et faire l'addition

car si il y a du nouveau materiel ou certain que j'ai pas encore referencé, il est plus simple de faire un bloc et de d'y mettre un attribut ( le bloc sera fait de toute façon) que d'aller modifier le code à chaque fois !

Ok pour simplifier le texte imbuvable du dessus, J'ai beaucoup d'element régulier, et souvant de la nouveauté, il ne faudrait pas modifier regulièrement le code

Re : Automatisation Baie 19"

patrick_35 — Wed, 17 Jun 2015 14:45:30 GMT

Alors en effet, il reste la solution de l'attribut, mais cela revient a se taper tous les blocs pour l'ajouter (et de préference avec une étiquette spécifique, si jamais on bouge pour une raison ou une autre abec battman par exemple) @+

Re : Automatisation Baie 19"

Kevin_Megel — Wed, 17 Jun 2015 15:04:22 GMT

je suis en faite en phase de création des bloc (j'en ai pas encore beaucoup, facile a reprendre) donc ça n'est pas un soucis. il faudra juste que j'arrive a sortir le code (et la c'est une autre histoire) et que je le comprenne si jamais par exemble on decide de se passer d'une tel taille de baie que je puisse la supprimer ect...

Re : Automatisation Baie 19"

patrick_35 — Wed, 17 Jun 2015 15:17:25 GMT

Par exemple

(defun c:nbu(/ att doc ent sel tot)
  (setq doc (vla-get-activedocument (vlax-get-acad-object))
	tot 0
  )
  (vla-startundomark doc)
  (and (ssget (list (cons 0 "insert") (cons 66 1)))
    (progn
      (vlax-for ent (setq sel (vla-get-activeselectionset doc))
	(foreach att (vlax-invoke ent 'getattributes)
	  (and (eq (vlax-get att 'tagstring) "MON_ETIQUETTE")
	    (setq tot (+ tot (atoi (vlax-get att 'textstring))))
	  )
	)
      )
      (vla-delete sel)
    )
  )
  (vla-endundomark doc)
  (princ (strcat "\nNombre de U trouvé : " (itoa tot)))
  (princ)
)