sujet Re : Lisp Epaisseur de trait dans AutoCAD – tous produits - Forum Français

Lisp Epaisseur de trait

Kevin_Megel — Fri, 13 Mar 2015 10:16:56 GMT

Hello la communauté,

j'ai besoin de pouvoir tout selectionner les objets de l'espace objet ( juste de l'espace objet) pour leur mettre à tous la même epaisseur de trait.

il faut bien entendu la même chose pour les bloc donc je me suis dit que je pourrais passer par une lisp, et j'ai tenté l'aventure.

Pour le pas faire trop compliqué avant de pourvoir entré dans les bloc sans les exploser, je me suis dit que je vais déjà trouver comment tout selectionné sur l'espace objet et lancer la variable, et la je coince déjà, ça doit déjà faire sourir les pro du lisp, et je vais balancer le code que j'ai tenté de faire, et la ils vons exploser de rire....

(defun c: EPT
  (ssget "_X" ' ((0 . "ModelSpace"))
	 (command "_EPAISSLIGN")
	 )
  )

Bon avant tout j'aimerais avant que l'un d'entre vous me sorte la lisp toute faite, comprendre comment on fait et ou sont mes erreurs

J'ai peut être vue trop ambitieux pour une première ?

Re : Lisp Epaisseur de trait

_gile — Fri, 13 Mar 2015 15:09:07 GMT

Salut,

C'est bien de se lancer dans l'aventure de la programmation, mais ça ne peut pas se faire sans un minimum de compréhension de ce qu'on fait et une grande rigueur en ce qui concerne la syntaxe (si l'être humain est plus ou moins capable d'interpréter un texte malgré les fautes d'othographes, l'interpréteur AutoLISP en est incapable).

L'apprentissage d'AutoLISP est grandement facilité par le fait que l'interpréteur est intégré à AutoCAD et qu'on peut donc exécuter des expressions LISP directement en ligne de commande ou dans la console Visual LISP.

Ceci permet, pour débuter, de faire des tests en quantité, ce qui devrait permettre de comprendre comment fonctionne ce langage avant d'essayer de faire un programme.

Par exemple, tu peux entrer directement en ligne de commande l'expression :

(command "_EPAISSLIGN")

et tu verras que tu n'auras pas résultat escompté parceque "_EPAISSLIGN" n'est pas une commande AutoCAD.

Et si tu orthographies correctement le nom de la commande (EPAISSLIGNE ou _LWEIGHT), tu t'apercevras que ce n'est pas la commande qui permet de changer l'épaisseur de lignes d'entités existantes...

Donc, avant d'essayer de créer une commande LISP, il faut, non seulement, connaître les bases du langage, mais aussi (très) bien connaître AutoCAD...

Je te recommande la lecture de Introduction à AutoLISP ainsi que les "officiels" AutoLISP Developper's Guide et AutoLISP Reference Guide (en anglais mais néanmoins incontournables).

Re : Lisp Epaisseur de trait

Kevin_Megel — Fri, 13 Mar 2015 15:18:42 GMT

ok je viens de me prendre un bonne paire de claques....

j'ai déjà sous le coude l'introduction a Autolisp,

bon je reviendrais dans une 10ène d'années pour voir si j'ai compris un truc ou deux ! car en plus les guides son en anglais, faut apprendre l'anglais en plus :s

donc à la prochaine...

Re : Lisp Epaisseur de trait

Anonymous — Fri, 13 Mar 2015 15:43:09 GMT

Bonjour Megeon,

Je ne sais pas si tu as déjà fais des macros en langage diesel sous Autocad.

Si c'est le cas, le plus simple avant de commencer un programme complet est de traduire quelques unes de ces macro en langage lisp. C'est comme cela que j'ai commencé (comme beaucoup qui comme moi sont des autodidactes en programmation).

Voici un lien qui je l'espère t'aideras.

Comme la dit Gilles, avant de programmer un ensemble de tâches, il faut savoir les faire manuellement. Evites les commandes avec des boites de dialogues, elles vont stopper tes programmes.

Bon courage

Olivier

Re : Lisp Epaisseur de trait

Kevin_Megel — Fri, 13 Mar 2015 16:09:03 GMT

Salut Olivier,

non j'ai jamais fait je suis vièrge de toute programation de pres ou de loin !

je vais voir ça de plus pres, cela n'empeche que j'ai un besoin urgent de ce programme... seul au BE on me demande de faire des truc de plus en plus fous, et c'est comme ça que je me retrouve à touché au lisp pour mieux me prendre une baffe de Gilles

Re : Lisp Epaisseur de trait

_gile — Fri, 13 Mar 2015 17:19:59 GMT

Si je t'ai blessé, je m'en excuse. Ce n'était pas du tout mon intention. On a tous commencé par là.

Dans tous les cas, tu ne pourras pas apprendre dans l'urgence, ce genre d'apprentissage demande de la rigueur, de la concentration donc d'être un minimum posé.

Quelques exemples pour ce que tu veux faire (chaque ligne -ou fin de ligne- débutant pas un point virgule (;) est un commentaire et ne sera pas interprétée.

1_ utilisation de la commande CHPROP pour modifier l'épaisseur de ligne (ici 0.7 mm) de toutes les entités contenues dans l'espace objet.

;; Utilisation de la commande CHPROP
;; Modifie l'épaisseur de ligne de toutes les entités de l'espace objet
;; Options de la commande
;; - DuBloc : "DuBloc" ou "ByBlock"
;; - DuCalque : "DuCalque" ou "ByLayer"
;; - l'épaisseur en millimètres (0.05, 0.35, 0.7, ...)

(defun c:EPT (/ ss)
  ;; on sélectionne toutes les entités de l'espace objet
  (setq ss (ssget "_X" '((410 . "model"))))

  ;; si le jeu de sélection n'est pas vide...
  (if ss

    ...on lance la commande CHPROP sur jeu de sélection
    (command "_.chprop" ss "" "_lweight" 0.7 "") ; <- remplacer 0.7 par la valeur désirée
  )
  (princ)
)

2_ Utilisation de la fonction SetPropertyValue (compatible Mac / Windows) pour modifier l'épaisseur de ligne (ici 0.35 mm) de toutes les entités contenues dans l'espace objet.

;; Utilisation de la fonction SetPropertyValue
;; Modifier l'épaisseur de ligne de toutes les entités de l'espace objet
;; Options
;; - Dubloc : -2
;; - DuCalque : -1
;; - l'épaisseur en centièmes de millimètres (5, 35, 70, ...)

(defun c:EPT (/ ss i)
  ;; on initialise un indice
  (setq 1 0)

  ;; on sélectionne toutes les entité de l'espace objet
  (if (setq ss (ssget "_X" '((410 . "Model"))))

    ;; tant qu'il existe une entité dans le jeu de sélection à l'indice...
    (while (setq ent (ssname ss i))

      ;; ...on change la propriété "LineWeight" de l'entité
      (SetPropertyValue ent "LineWeight" 35) ; <- remplacer 35 par la valeur désirée

      ;; et on incrémente l'indice
      (setq i (1+ i))
    )
  )
  (princ)
)

3_ Utilisation de la fonction SetPropertyValue (compatible Mac / Windows) pour modifier l'épaisseur de ligne de toutes les entités contenues dans l'espace objet (en Ducalque) et toutes les entités contenues dans les blocs (en DuBloc).

;; Utilisation de la fonction SetPropertyValue
;; Modifie l'épaisseur de ligne de toutes les entités de l'espace objet
;; et de toutes les entités dans tous les blocs
;; Options
;; - Dubloc : -2
;; - DuCalque : -1
;; - l'épaisseur en centièmes de millimètres (5, 35, 70, ...)
(defun c:EPT (/ ss i bloc ent)
  ;; on initialise un indice
  (setq 1 0)
  
  ;; on sélectionne toutes les entité de l'espace objet
  (if (setq ss (ssget "_X" '((410 . "Model"))))
    
    ;; tant qu'il existe une entité dans le jeu de sélection à l'indice...
    (while (setq ent (ssname ss i))
      
      ;; ...on change la propriété "LineWeight" de l'entité
      (SetPropertyValue ent "LineWeight" -1) ; <- remplacer -1 par la valeur désirée

      ; on incrémente l'indice
      (setq i (1+ i))
    )
  )

  ;; tant qu'il y a des définitions de bloc dans la table des blocs...
  (while (setq bloc (tblnext "block" (not bloc)))

    ;; ...on parcourt toutes les entités de chaque définition de bloc
    (setq ent (cdr (assoc -2 bloc))) ; <- première entité dans le bloc

    ;; tant qu'il y a des entités...
    (while ent
      
      ;; ...on change la propriété "LineWeight" de l'entité
      (setpropertyvalue ent "LineWeight" -2) ; <- remplacer -1 par la valeur désirée

      ;; et on passe à l'entité suivante
      (setq ent (entnext ent))
    )
  )
  (princ)
)

Re : Lisp Epaisseur de trait

Anonymous — Fri, 13 Mar 2015 18:32:18 GMT

Bonjour (gile),

Si je peux me permettre, il manque un ; au début de la ligne ci-dessous pour la passer en commentaire.

...on lance la commande CHPROP sur jeu de sélection

J'écris surtout pour Megeon, afin qu'il ne se retrouve pas avec une erreur. Au début, il suffit de peut de chose pour être perturber.

Amicalement,

Olivier

Re : Lisp Epaisseur de trait

_gile — Fri, 13 Mar 2015 18:49:13 GMT

Olivier,

Bien sûr que tu peux te permettre.

Au temps pour moi, j'ai rajouté ces commentaires "à la volée" dans mon message. Ça ne serait probablement pas arrivé si j'avais mis ces commentaires dans l'éditeur Visual LISP...

Megeon,

Comme le dis Olivier, ajout deux points-virgules (;) au début de la ligne :

...on lance la commande CHPROP sur jeu de sélection

et, d'une manière générale, colle toujours les codes que tu copies dans une nouvelle fenêtre de l'éditeur Visual LISP, la coloration syntaxique et l'indentation (formatage du code) rendent vraiment les choses plus compréhensibles.

Re : Lisp Epaisseur de trait

Kevin_Megel — Mon, 16 Mar 2015 08:10:31 GMT

Merci, pour ces reponse, je vais tester cela dans la journée

@_gile, sans l'avoir mal pris, j'ai surtout resentie ta première reponse comme "laisse tomber t'y arrivera pas", mais si c'etait pas le but recherché alors aucun probleme 😉

Re : Lisp Epaisseur de trait

Kevin_Megel — Mon, 16 Mar 2015 08:18:25 GMT

donc si je comprend bien le premier lisp me permet de changer tout les trait pour mettre l''eppaisseur que j'ai donnée dans la lisp (ici 0.7), mais si je voulais choisir une epaisseur différente, il faut retourner dans la lisp, modifier l'eppaisseur, ne serai t'il pas possible d'ouvrir une boite de dialogue pour choisir a chaque fois l'epaisseur en fonction des dessins ?

Re : Lisp Epaisseur de trait

Kevin_Megel — Mon, 16 Mar 2015 09:08:19 GMT

hello c'est toujours moi, j'ai regardé ton lien Olivier, et j'ai donc essayer par moi même de transformé sa marco en lisp sans regarder la reponse, le me suis permis d'ajouté une sauvegarde aussi

voici la ligne

;;Purge zoom sauvegarde alias "PZ"
(defun c:PZ () (command "_-purge" "_zoom" "_qsave" "_close") (princ))

les commandes apres le purge ne se font pas, pourquoi ?

Re : Lisp Epaisseur de trait

Anonymous — Mon, 16 Mar 2015 09:39:38 GMT

Bonjour Megeon,

Il te faut une fonction command par commande Autocad.

On obtient donc :

(command "_-purge")

(command "_zoom")

(command "_qsave")

(command "_close")

De plus tu n'as entré aucune option dans tes commandes. Sans option, la commande _-purge ne sert à rien.

Olivier

Re : Lisp Epaisseur de trait

Kevin_Megel — Mon, 16 Mar 2015 09:42:45 GMT

ok donc une option te permet de choisir par exemple se que tu veux purger, et si je veux tout, je met "tout" ou bien les racourcit "TO" ?

Re : Lisp Epaisseur de trait

Kevin_Megel — Mon, 16 Mar 2015 09:46:45 GMT

ok je pense avoir réussi, et voici ma première Lisp 😄

;;Purge zoom sauvegarde alias "PZ"
(defun c:PZ()
  (command "_-purge" "TO" "" "n")
  (command "_zoom" "t")
  (command "_qsave")
  (command "_close")
  (princ)
)

Re : Lisp Epaisseur de trait

Kevin_Megel — Mon, 16 Mar 2015 10:20:00 GMT

si certain la veullent la voici dans un .txt ( j'ai voulu donnée le .lsp mais ça fonctionne pas ...)

Re : Lisp Epaisseur de trait

Anonymous — Mon, 16 Mar 2015 10:23:47 GMT

Concernt le lisp de modification d'épaisseur, les boite de dialogue sont beaucoup plus compliquée à mettre en place. En revanche, voici la commande de (gile) avec l'ajout d'une question en ligne de commande.

;; Utilisation de la commande CHPROP
;; Modifie l'épaisseur de ligne de toutes les entités de l'espace objet
;; Options de la commande
;; - DuBloc : "DuBloc" ou "ByBlock"
;; - DuCalque : "DuCalque" ou "ByLayer"
;; - l'épaisseur en millimètres (0.05, 0.35, 0.7, ...)

(defun c:EPT (/ ss ep)
  ;; on sélectionne toutes les entités de l'espace objet
  (setq ss (ssget "_X" '((410 . "model"))))

  ;; si le jeu de sélection n'est pas vide...
  (if ss
    ;; chargement des valeurs correctes
    (progn
      (initget "duCalque duBloc 0 0.05 0.09 0.13 0.15 0.18 0.20 0.25 0.30 0.35 0.40 0.50 0.53 0.60 0.70 0.80 0.90 1.00 1.06 1.20 1.40 1.58 2.00 2.11")
      ;; enregistrement de la valeur de l'épaisseur voulue
      (setq ep (getkword "indiquez l'épaisseur, [duCalque/duBloc/0/0.05/0.09/0.13/0.15/0.18/0.20/0.25/0.30/0.35/0.40/0.50/0.53/0.60/0.70/0.80/0.90/1.00/1.06/1.20/1.40/1.58/2.00/2.11] <duCalque>"))
      ;; ...on lance la commande CHPROP sur jeu de sélection
      (command "_.chprop" ss "" "_lweight" ep "") ; <- 0.7 remplacé par la vairble ep
      )
    )
  (princ)
  )

Olivier

Re : Lisp Epaisseur de trait

Kevin_Megel — Mon, 16 Mar 2015 10:46:12 GMT

Merci Olivier de cette ajout,

Merci a tout le monde de m'avoir aidée et a me lancer dans les bases de la lisp, et je comprend un peu plus comment ça fonctionne !!

Mille mercis

J'ai l'impression de moins voler mon lvl 9 ^^ Bien que je pense que je la vole tjr !!!

Re : Lisp Epaisseur de trait

braudpat — Tue, 17 Mar 2015 08:14:06 GMT

Hello

1) Merci pour cette routine !

2) J'ai fais une Micro-Modif dans le code :

dubloc ---> ByBlock & ducalque ---> ByLayer

3) J'ai donc teste et valide cette routine EPT sur MAP 2010 et sur MAP 2016

Donc on suppose qu'elle fonctionne sur TOUS les AutoCADs !?

Bonne Journee, Patrice (I am not an Autodesk Advisor)

Re : Lisp Epaisseur de trait

Kevin_Megel — Tue, 17 Mar 2015 09:02:50 GMT

salut Pat, merci pour la micro modif.

Si ça fonctionne sur 2010 et sur 2016 ça devrais fonctionné sur celle entre non ?

ça fonctionne sur 2013, jais pas testé sur mac

Re : Lisp Epaisseur de trait

Kevin_Megel — Tue, 17 Mar 2015 14:03:00 GMT

peut on me dire a quoi correspond ceci ?

(/ ss ep)