sujet Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite dans AutoCAD – tous produits - Forum Français

droite tagente à un cercle parallele ou perpendiculaire à une autre droite

Anonymous — Mon, 20 Jun 2016 15:23:11 GMT

Bonjour,

Je vous écris car je suis coincée avec mes droites! Voila aujourd'hui, pour faire une droite tangente à un cercle parallèle ou perpendiculaire à une autre droite, je commence par faire ma droite parallele ou perpendiculaire et je passe en paramétrique pour mettre la tangence entre la nouvelle droite et le cercle. J'ai pu lire des lisp qui permettent de faire des tangentes en un point précis sur un cercle ou une polyligne est ce qu'il serait possible de faire la même chose avec des parallèles et perpendiculaires, voire sans dire que la droite soit parallele ou perpendiculaire, rentrer un angle au clavier?

J'espère que vous pourrez m'aider.

Re : droite tagente à un cercle parallele ou perpendiculaire à une autre droite

_gile — Mon, 20 Jun 2016 16:04:58 GMT

Salut,

Petit rappel de géométrie :

la tangente à un cercle est perpendiculaire au rayon passant par le point de tangence.

- pour dessiner la tangente parallèle à une droite, en utilisant les accrochages aux objets, commencer par dessiner une ligne depuis le centre du cercle jusqu'à la perpendiculaire à la droite, puis depuis l'intersection entre cette ligne et le cercle, dessiner la droite parallèle à la première

- pour dessiner la tangente perpendiculaire à une droite, toujours en utilisant les accrochages aux objets, commencer par dessiner une ligne depuis le centre du cercle parallèlement à la droite, puis depuis l'intersection entre cette ligne et le cercle, dessiner la droite perpendiculaire à la première

Un petit screencast.

Si tu as vraiment besoin d'un LISP, ça devrait être faisable.

Re : droite tagente à un cercle parallele ou perpendiculaire à une autre droite

Anonymous — Mon, 20 Jun 2016 18:30:36 GMT

Merci pour votre réponse rapide,Avant de passer par le paramétrique tangente c est ce que je faisais mais je trouvais que la construction était quand même lourde car dans mon travail je ne fais que ça. Alors je voulais savoir si faire un Lisp finalement de la méthode pouvait me faire gagner du temps?De plus, il y a une autre chose qui me fait perdre pas mal de temps, lorsque que je veux faire une tangente entre 2 arcs, il me faut prolonger les arcs sinon pour autocad la tangente n'existe pas.Je reste à disposition si vous avez des questions je ne sais pas si je suis assez claire.Dory
Envoyé depuis mon appareil mobile Samsung.

Re : droite tagente à un cercle parallele ou perpendiculaire à une autre droite

tramber — Mon, 20 Jun 2016 19:13:19 GMT

Pour faire une tangeante sur deux arcs, il suffit de forcer l'accrochage à chaque fois et avant :

Lancer ligne, taper TAN et valider, cliquer le mode différé sur le premier côté désiré.

Pour le second point, taper et valider TAN encore une fois et cliquer.

C'est ce qu'on appelle l'accrochage différé, il suffit de la faire agir deux fois.

Ainsi, je n'arrive pas à le faire pour le premier exemple vidéo car il s'agit d'un parallèle, mais en revanche je n'utilise pas d'objet à effacer pour le second exemple.

Il suffit de lancer LIGNE, demander une TANgeante différée sur le cercle et forcer enfin l'accrochage perpendiculaire.

(toutes ces manipulations peuvent se faire avec MAJ ou CTRL + Clic-droit)

Re : droite tagente à un cercle parallele ou perpendiculaire à une autre droite

_gile — Mon, 20 Jun 2016 20:51:47 GMT

@tramber

tramber a écrit :
[...], mais en revanche je n'utilise pas d'objet à effacer pour le second exemple.
Il suffit de lancer LIGNE, demander une TANgeante différée sur le cercle et forcer enfin l'accrochage perpendiculaire.

Ça marche avec LIGNE, mais pas avec DROITE.

@Anonymous

Si tu veux qu'on t'aide pour un LISP; il faudrait préciser ce que tu veux faire exactement, à partir de quelles données et comment tu pensais les acquérir.

Re : droite tagente à un cercle parallele ou perpendiculaire à une autre droite

tramber — Tue, 21 Jun 2016 06:48:40 GMT

Satanées droites ! Tu as raison @_gile je ne pensais pas à la droite mais à une ligne.

Il n'y a rien qui marche en direct. J'ai essayé plein d'options de la droite....

Moralité si on voulait faire court : je tournerais un petit lisp qui transformerait toute ligne en droite. De quoi développer de petites méthodologies basées sur la ligne, voire des macros dans un bouton avec l'appel à cette fonction à la fin.

(defun c:d2d(/ dern *osmode*)
  (setq dern(entlast))
  (cond((=(cdr(assoc 0(entget dern)))"LINE")
	(setq *osmode*(getvar "osmode"))
	(setvar "osmode"0)
	(command "_xline"
		 (cdr(assoc 10 (entget dern)))
		 (cdr(assoc 11 (entget dern)))
		 "")
	(entdel dern)
	
	(setvar "osmode" *osmode*)
	)
       (princ"\nLe dernier objet créé n'est pas une ligne")
       )
  )

Lancer D2D crée une droite à la place du dernier objet si et seulement si ce dernier est une ligne.

Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite

Anonymous — Tue, 21 Jun 2016 08:29:22 GMT

Bonjour,

Je me demandais si on pouvait partir du lisp sur les lignes tangentes en un point precis et par exemple proposer une variante où au lieu de rentrer le point de tangence on rentrerait un angle par rapport à l'absolu ou par rapport à une référence (soit un segment) et à ce compte là on pourrait balayer presque tous les cas de lignes tangentes.

Je dis cela car nous avons migré il y a pas longtemps sur autocad, on travaillait avant sous visionael (unix) et le logiciel proposé tous les cas de construction de tangente et pour nous c'était un vrai gain de temps. Je sais que par la construction géométrique on peut y arriver mais c'est plus long.

J'aurais besoin d'un coup de main car je suis plus que novice sur lisp, j'arrive à mes fins en créant des boutons mais je suis limitée en l'occurrence pour ce type de demande.

Je vous remercie.

dory

Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite

_gile — Tue, 21 Jun 2016 09:46:20 GMT

Salut,

Si je demandais de "préciser ce que tu veux faire exactement, à partir de quelles données et comment tu pensais les acquérir" c'est justement parce qu'il est très rare qu'il soit intéressant de partir d'un code existant dont on pense qu'il fait "à peu près" ce que l'on cherche à faire.

Si, quand tu parles d'un LISP qui dessine la tangente au point, tu parles bien de celui que j'ai écrit (dans bsc_med_per_tan.lsp sur cette page par exemple), il est vraiment préférable de repartir de zéro s'il s'agit des tangentes à un cercle (beaucoup plus simple).

Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite

_gile — Tue, 21 Jun 2016 12:28:26 GMT

@Anonymous

Un petit LISP pour dessiner une tangente à un cercle suivant un angle.

L'utilisateur est invité à sélectionner un cercle puis à spécifier un angle en entrant la valeur en ligne de commande ou par deux points.

La tangente sera celle dont le point de tangence est le plus proche du point cliqué lors de la sélection du cercle.

Comme il semble qu'il y ait un doute sur le type d'entité à dessiner pour figurer la tangente (ligne, droite ou demi droite) j'ai mis les 3 possibilités (dont deux en commentaire). Pour une ligne ou une demi droite l'utilisateur reprend la main pour spécifier le points suivant (ligne) ou la direction (demi droite).

(defun c:TanCircle (/ ent elst ang cen rad pt)
  ;; sélection du cercle
  (while
    (not
      (and
	(setq ent (entsel "\nSélectionnez un cercle: "))
	(= (cdr (assoc 0 (setq elst (entget (car ent))))) "CIRCLE")
      )
    )
     (prompt "\nL'objet sélectionné doit être un cercle.")
  )
  ;; spécification de l'angle
  (while
    (not
      (setq ang (getangle "\nSpécifiez l'angle de la tangente: "))
    )
  )
  ;; calcul du point de tangence le plus proche du point cliqué
  (setq	cen (cdr (assoc 10 elst))
	rad (cdr (assoc 40 elst))
	pt  (trans (cadr ent) 1 0)
	p1  (polar cen (+ ang (* PI 0.5)) rad)
	p2  (polar cen (+ ang (* PI 1.5)) rad)
	pt  (if	(< (distance pt p1) (distance pt p2))
	      p1
	      p2
	    )
  )
  ;; dessin de la tangente
  ;; (dé)commenter suivant le type d'entité souhaité
  
  ;; ligne
  (vl-cmdf "_line" "_non" pt (strcat "<" (angtos ang (getvar 'aunits) 16)) "_non" pause "")
  
  ;; droite
  ;;(vl-cmdf "_xline" "_non" pt "_non" (polar pt ang 1.0) "")
  
  ;; demi droite
  ;;(vl-cmdf "_ray" "_non" pt (strcat "<" (angtos ang (getvar 'aunits) 16)) "_non" pause "")
  
  (princ)
)

Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite

CADaSchtroumpf — Tue, 21 Jun 2016 13:24:14 GMT

Je propose aussi ma variante (pas complétement paufiner...)

(defun c:xline2tg ( / ss1 obj_straight AcDoc Space dir_vec deriv alpha ss2 obj_curv pt_cen nw_obj)
	(princ "\nSélectionnez une Droite ou Demi-droite: ")
	(while (not (setq ss1 (ssget "_+.:E:S" '((0 . "XLINE,RAY"))))))
	(setq
		obj_straight (vlax-ename->vla-object (ssname ss1 0))
		AcDoc (vla-get-ActiveDocument (vlax-get-acad-object))
		Space
		(if (eq (getvar "CVPORT") 1)
			(vla-get-PaperSpace AcDoc)
			(vla-get-ModelSpace AcDoc)
		)
		dir_vec (vlax-get-property obj_straight 'DirectionVector)
		deriv (vlax-safearray->list (vlax-variant-value dir_vec))
		alpha (atan (cadr deriv) (car deriv))
	)
	(princ "\nSélectionnez une Cercle ou un Arc à tangenter: ")
	(while (not (setq ss2 (ssget "_+.:E:S" '((0 . "ARC,CIRCLE"))))))
	(setq
		obj_curv (vlax-ename->vla-object (ssname ss2 0))
		pt_cen (vlax-get obj_curv 'Center)
		nw_obj (vla-addXLine Space (vlax-3d-point (getvar "UCSORG")) dir_vec)
	)
	(vlax-invoke-method
		nw_obj
		'move
		(vlax-3d-point (getvar "UCSORG"))
		(vlax-3d-point (polar pt_cen (+ (* 0.5 pi) alpha) (vlax-get obj_curv 'Radius)))
	)
	(prin1)
)

Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite

Anonymous — Tue, 21 Jun 2016 18:00:58 GMT

Merci beaucoup

Je vais m empresser de tester!

Concernant la droite parallèle à une droite tangente à un cercle, j ai essayé de faire une macro. J y arrive je pense qu il faut que j essaie de la finaliser un peu plus car elle demande à l opérateur de venir cliquer en plus du cercle et de la droite, le point d intersection de la droite de construction avec le cercle. Peut être que vous avec un Lisp ça pourrait être complétément transparent.

En tout cas merci d essayer de solutionner mon problème c est sympa!

Je vous tiens au courant.

Merci

Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite

Anonymous — Wed, 22 Jun 2016 11:36:24 GMT

Bonjour,

Je viens de tester le lisp, je ne sais pas si c'est moi mais je n'arrive pas à faire une ligne tangente au cercle à 20°. (video jointe)

Dory

Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite

_gile — Wed, 22 Jun 2016 12:01:47 GMT

Salut,

Ça marche chez moi:

Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite

Anonymous — Wed, 22 Jun 2016 15:12:00 GMT

Salut,

Je suis verte ca a l'air de super bien marcher chez vous mais moi non!

Est ce que ca peut venir d'une config d'accrochage, un mode en particulier. J'ai l'impression que lorsque je rentre la valeur de l'angle cela correspond à la position du point sur le cercle et après il attend un deuxième point.

si vous avez une idée je prends, merci.

Dory

Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite

Anonymous — Wed, 22 Jun 2016 15:48:43 GMT

Bonjour,

Sur quelle version es-tu ?

J'ai essayé sur 2014 ça marche sans problème, sur 2017 par contre il ne prends pas en compte le "_non" après la définition de l'angle pour la ligne et la demi-droite.

Cependant en écrivant manuellement _non, ça fonctionne à merveille.

Cordialement,

Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite

_gile — Wed, 22 Jun 2016 16:57:26 GMT

Effectivement, je n'avais pas suffisamment testé, il semble que la routine ne fonctionne plus avec les versions 2015 et ultérieures (du moins pour les lignes et demi-droites).

Pour dessiner une droite, on peut utiliser la routine en dé-commentant dans le code la commande qui crée une droite et en supprimant les autres.

Pour une ligne, la routine ci-dessous devrait fonctionner avec toutes les versions tant qu'on reste en vue de dessus et dans un plan parallèle au plan XY du SCG.

Je pensais pouvoir m'en sortir avec les commandes et éviter de devoir sortir l'artillerie lourde...

(defun c:TanCircle (/ grDrawLine ent elst ang cen rad pt)
  ;; grDrawline
  ;; Dessine une ligne depuis un point suivant une direction
  (defun grDrawLine (startPt direction / dist pt line elst loop)
  (setq pt    (trans startPt 0 1)
	line  (entmakex
		(list
		  '(0 . "LINE")
		  (cons 10 startPt)
		  (cons 11 startPt)
		)
	      )
	elst  (entget line)
	loop  T
      )
      (princ "\nSpécifiez la longueur ou [annUler]: ")

      (if
	(vl-catch-all-error-p
	  (vl-catch-all-apply
	    '(lambda (/ gr len end str)
	       (while
		 (and (setq gr (grread T 12 0)) (/= (car gr) 3) loop)
		  (cond
		    ;; modification de la ligne en fonction de la position du pointeur
		    ((= 5 (car gr))
		     (if (minusp
			   (apply '+ (mapcar '* direction (mapcar '- (cadr gr) pt)))
			 )
		       (setq direction (mapcar '- direction))
		     )
		     (setq len (distance pt (cadr gr))
			   end (mapcar
				 (function
				   (lambda (x1 x2)
				     (+ x1 (* len x2))
				   )
				 )
				 startPt
				 direction
			       )
		     )
		     (entmod (subst (cons 11 end)
				    (assoc 11 elst)
				    elst
			     )
		     )
		     ;; affichage dynamique de la longueur dans la barre d'état
		     (grtext -1 (strcat "Longueur: " (rtos len)))
		    )
		    ;; clic droit
		    ((member (car gr) '(11 25))
		     (entdel line)
		     (setq loop	nil
			   line	nil
		     )
		    )
		    ;; Entrée ou Espace
		    ((member (cadr gr) '(13 32))
		     (cond
		       ;; longueur valide
		       ((and str (numberp (distof str)))
			(setq end  (mapcar
				     (function
				       (lambda (x1 x2)
					 (+ x1 (* (distof str) x2))
				       )
				     )
				     startPt
				     direction
				   )
			      loop nil
			)
			(entmod	(subst (cons 11 end)
				       (assoc 11 elst)
				       elst
				)
			)
		       )
		       ;; annUler
		       ((= (strcase str) "U")
			(entdel line)
			(setq loop nil
			      line nil
			)
		       )
		       ;; entrée non valide
		       (T
			(princ
			  "\nNécessite un nombre valide ou une saisie au pointeur.
				     \nSpécifiez la longueur ou [annUler]: "
			)
			(setq str "")
		       )
		     )
		    )
		    ;; Récupération des entrée au clavier
		    (T
		     ;; retour/effacer
		     (if (= (cadr gr) 8)
		       (or
			 (and
			   str
			   (/= str "")
			   (setq str (substr str 1 (1- (strlen str))))
			   (princ (chr 8))
			   (princ (chr 32))
			 )
			 (setq str nil)
		       )
		       (or
			 (and str
			      (setq str (strcat str (chr (cadr gr))))
			 )
			 (setq str (chr (cadr gr)))
		       )
		     )
		     ;; affichage sur la ligne commande
		     (and str (princ (chr (cadr gr))))
		    )
		  )
	       )
	     )
	  )
	)
	 (and (entdel line) (setq line nil))
      )
  (grtext)
  line
)
  
  ;; sélection du cercle
  (while
    (not
      (and
	(setq ent (entsel "\nSélectionnez un cercle: "))
	(= (cdr (assoc 0 (setq elst (entget (car ent))))) "CIRCLE")
      )
    )
     (prompt "\nL'objet sélectionné doit être un cercle.")
  )
  ;; spécification de l'angle
  (while
    (not
      (setq ang (getangle "\nSpécifiez l'angle de la tangente: "))
    )
  )
  ;; calcul du point de tangence le plus proche du point cliqué
  (setq	cen (cdr (assoc 10 elst))
	rad (cdr (assoc 40 elst))
	ang (+ ang (angle '(0. 0. 0.) (getvar "ucsxdir")))
	pt  (trans (cadr ent) 1 0)
	p1  (polar cen (+ ang (* PI 0.5)) rad)
	p2  (polar cen (+ ang (* PI 1.5)) rad)
	pt  (if	(< (distance pt p1) (distance pt p2))
	      p1
	      p2
	    )
  )
  ;; dessin de la tangente
  (grDrawLine pt (polar '(0. 0. 0.) ang 1.))
  
  (princ)
)

Re : droite tangente à un cercle parallele ou perpendiculaire à une autre droite

Anonymous — Wed, 22 Jun 2016 18:07:55 GMT

Merci beaucoup je vais testé et je vous tiens au courant si la grosse cavalerie marche. ...
En tout cas c est assez impressionnant vous devez manger des lignes de codes au goûter
Encore merci et je vous tiens au courant Dory

Envoyé depuis mon appareil mobile Samsung.