sujet Re: Modificatiion couleur attribut texte dans un bloc dans AutoCAD – tous produits - Forum Français

Modification couleur attribut texte dans un bloc

Anonymous — Fri, 18 Jan 2019 22:44:06 GMT

Bonjour, dans mon folio j'ai un bloc cartouche "AUTO4DE" qui contient plusieurs attributs textes, dont 'Titre1' et 'Plan' qui ont respectivement la couleur 'ducalque=jaune'. je souhaiterai modifier uniquement la couleur en vert de ces 2 attributs. Problème : j'ai des 10aines voir une centaine de folio à modifier, comment puis je faire un script pour modifier l'ensemble des folios ?

pour info:

j'ai réussi a créer un script pour modifier les textes, exemple :

-attedit
n
n

Titre1

67
74

-attedit
n
n

Plan

01
02

****

j'ai un trouver un fichier excell pour générer les scripts,. je sélectionne le script et les folios a modifier: résultat, il me créé un fichier avec le script contenant tous les folios. je fais un déplacé de l'explorateur vers autocad et le script lance l'ouverture 1 par 1 des folios en apportant la modification du titre 1 et plan . ca fonctionne très bien.

merci d'avance

Re: Modificatiion couleur attribut texte dans un bloc

patrick_35 — Tue, 08 Jan 2019 13:17:00 GMT

Salut

Quelle est la question ?

Sinon, tu as aussi SuperAutoScript

Re: Modificatiion couleur attribut texte dans un bloc

Anonymous — Tue, 08 Jan 2019 13:26:18 GMT

dans le bloc cartouche, nommé "AUTO4DE" qui contient plusieurs attributs textes, je souhaiterai modifier uniquement la couleur de 2 attributs 'Titre1' et 'Plan' en vert qui sont de la couleur 'ducalque=jaune'.

ayant beaucoup de folio a modifier j'aurai aimé savoir en plus si l'on pouvait faire un petit script pour pouvoir modifier l'ensemble de mes folios.

j'ai réussi à modifier le texte mais pas pour la couleur.

Re: Modificatiion couleur attribut texte dans un bloc

_Steven_ — Tue, 08 Jan 2019 14:02:14 GMT

Salut,

Est-ce que tous tes folios sont dans le même dessin?

Si oui, il n'y a pas besoin de faire de script.

Tu sélectionnes ton cartouche > Clic droit > Editeur de bloc > Tu sélectionnes les attributs Titre 1 et Plan et tu forces la couleur en vert puis tu fermes l'éditeur de bloc en enregistrant les modifications.

Tu lances, ensuite la commande ATTSYNQ, tu valides, tu sélectionnes ton cartouche puis tu valides.

De ce fait, la modification sera faite sur tous tes folios.

A moins que je n'ai pas bien compris la question.

Re: Modificatiion couleur attribut texte dans un bloc

Anonymous — Tue, 08 Jan 2019 14:20:47 GMT

bonjour j'ai 1 folio =1fichier,

et le cartouche est le même pour tous.

j'arrive a apporter les modification manuellement mais peut-on faire un script pour

passer la couleur jaune en vert pour les 2 attributs dans le bloc cartouche.

cartouche bloc : AUTO4DE

étiquette/attribut : titre1

étiquette/attribut : plan

****

au moins un script pour un folio, comme je l'indique plus haut j'ai trouvé un programme excell qui me créé le script pour tous les folios.

Re: Modificatiion couleur attribut texte dans un bloc

patrick_35 — Tue, 08 Jan 2019 14:37:19 GMT

Pas avec la commande -attedit.

La solution est d'insérer et de redéfinir le bloc avec les bonnes couleurs (inserer;toto=toto;...)

Puis d'effacer le dernier objet (en l'occurrence, le bloc que l'on vient d'insérer)

Puis de faire une synchro (attsync)

Re: Modificatiion couleur attribut texte dans un bloc

Anonymous — Tue, 08 Jan 2019 14:53:10 GMT

faire ca pour chaque fichier/folio !!

actuellement je rentre dans "éditeur d'attribut étendu" et onglet 'propriété" puis je modifie la couleur.

j'ai pris la main je continu comme ça 🙂

****

on ne peut pas faire un script ? par exemple la fonction "attedit" avec édition des attributs un par un pour modifier la couleur.....

Re: Modificatiion couleur attribut texte dans un bloc

patrick_35 — Tue, 08 Jan 2019 15:11:25 GMT

On peut avec -attedit changer la couleur des attributs, mais il faut les sélectionner.

Du coup, le script, bye bye.

Il reste la solution d'un lisp si tu es en version pleine.

Re: Modificatiion couleur attribut texte dans un bloc

Anonymous — Tue, 08 Jan 2019 15:23:46 GMT

oui je peux lancer les lisp.

par contre la programmation ce n'est pas ma tasse de the 🙂

Re: Modificatiion couleur attribut texte dans un bloc

patrick_35 — Tue, 08 Jan 2019 15:58:15 GMT

Voici un lisp

(defun c:mumudidi(/ att col doc obj sel nombl Mes_Attributs Mon_Bloc)

  (defun nombl(bl)
    (if (vlax-property-available-p bl 'effectivename)
      (strcase (vla-get-effectivename bl))
      (strcase (vla-get-name bl))
    )
  )

  (vl-load-com)
  (setq doc (vla-get-activedocument (vlax-get-acad-object)))
  (vla-startundomark doc)

;;;==============================================================================
;;;
;;; Paramètres à définir par l'utilisateur
;;;
;;; Mon_Bloc = Le nom du bloc à modifier
;;;
;;; Mes_Attributs = Une liste des attributs à modifier
;;; La liste de compose du nom de l'étiquette et de sa couleur
;;; Par exemple l'étiquette ETQ1 et la couleur rouge (1)
;;;		l'étiquette ETQ2 et la couleur jaune (2)
;;; (setq Mes_Attributs '(("ETQ1" 1) ("ETQ2" 2)))
;;;
;;;==============================================================================

  (setq Mon_Bloc "AUTO4DE")
  (setq Mes_Attributs '(("TITRE1" 1) ("PLAN" 2)))

;;;==============================================================================
;;;
;;; Fin des paramètres à définir par l'utilisateur
;;;
;;;==============================================================================

  (and (ssget "_x" (list (cons 0 "insert") (cons 66 1)))
    (progn
      (vlax-for obj (setq sel (vla-get-activeselectionset doc))
	(and (eq (nombl obj) Mon_Bloc)
	  (foreach att (vlax-invoke obj 'getattributes)
	    (and (setq col (assoc (vla-get-tagstring att) Mes_Attributs))
	      (vla-put-color att (cadr col))
	    )
	  )
	)
      )
      (vla-delete sel)
    )
  )
  (vla-endundomark doc)
  (princ)
)

Tu peux dans un script, charger puis lancer le lisp.

Tu testes en premier le lisp sur un folio, et si c'est ok, tu le scriptes.

Re: Modificatiion couleur attribut texte dans un bloc

Anonymous — Wed, 09 Jan 2019 09:03:28 GMT

bonjour,

quelques explications supplémentaires svp:

dois-je mettre le chemin du fichier ici "(defun c:mumudidi..." ?

est ce que le 1 et le 2 dans "setq Mes_Attributs '(("TITRE1" 1) ("PLAN" 2)))" je les remplace par la couleur initiale ou finale ? exp initiale jaune = 255.255.0 et finale vert=0.255.0

merci d'avance

Re: Modificatiion couleur attribut texte dans un bloc

patrick_35 — Wed, 09 Jan 2019 11:30:15 GMT

Salut

@Anonymous a écrit :dois-je mettre le chemin du fichier ici "(defun c:mumudidi..." ?

Non, tu as juste à lancer le lisp pout tester s'il te convient.

@Anonymous a écrit :
est ce que le 1 et le 2 dans "setq Mes_Attributs '(("TITRE1" 1) ("PLAN" 2)))" je les remplace par la couleur initiale ou finale ? exp initiale jaune = 255.255.0 et finale vert=0.255.0

Non, le lisp n'est pas prévu pour les couleurs RVB. Il faudrait le faire évoluer.

Pour les couleurs, tu indiques simplement la couleur voulue. Pas besoin de connaitre la couleur initiale.

Re: Modificatiion couleur attribut texte dans un bloc

Anonymous — Tue, 15 Jan 2019 06:53:59 GMT

bonjour, désolé j'avais un dossier à finir absolument.. avec un peu de retard je reviens sur mes plans.

pouvez vous me valider le scrip que j'ai complété svp :

(defun c:mumudidi(/ att col doc obj sel nombl (("TITRE1" VERT) ("PLAN" VERT)) AUTO2AT)

(defun nombl(bl)
    (if (vlax-property-available-p bl 'effectivename)
      (strcase (vla-get-effectivename bl))
      (strcase (vla-get-name bl))
    )
)

(vl-load-com)
(setq doc (vla-get-activedocument (vlax-get-acad-object)))
(vla-startundomark doc)

;;;==============================================================================
;;;
;;; Paramètres à définir par l'utilisateur
;;;
;;; Mon_Bloc = Le nom du bloc à modifier
;;;
;;; Mes_Attributs = Une liste des attributs à modifier
;;; La liste de compose du nom de l'étiquette et de sa couleur
;;; Par exemple l'étiquette ETQ1 et la couleur rouge (1)
;;; l'étiquette ETQ2 et la couleur jaune (2)
;;; (setq Mes_Attributs '(("ETQ1" 1) ("ETQ2" 2)))
;;;
;;;==============================================================================

(setq Mon_Bloc "AUTO2AT")
(setq Mes_Attributs '(("TITRE1" VERT) ("PLAN" VERT)))

;;;==============================================================================
;;;
;;; Fin des paramètres à définir par l'utilisateur
;;;
;;;==============================================================================

(and (ssget "_x" (list (cons 0 "insert") (cons 66 1)))
    (progn
      (vlax-for obj (setq sel (vla-get-activeselectionset doc))
(and (eq (nombl obj) AUTO2AT)
   (foreach att (vlax-invoke obj 'getattributes)
     (and (setq col (assoc (vla-get-tagstring att) (("TITRE1" VERT) ("PLAN" VERT))))
       (vla-put-color att (cadr col))
     )
   )
)
      )
      (vla-delete sel)
    )
)
(vla-endundomark doc)
(princ)
)

Re: Modificatiion couleur attribut texte dans un bloc

patrick_35 — Tue, 15 Jan 2019 12:13:54 GMT

Bonjour

Tu n'as pas besoin de toucher à

@Anonymous a écrit :
(defun c:mumudidi(/ att col doc obj sel nombl (("TITRE1" VERT) ("PLAN" VERT)) AUTO2AT)

Juste ce qui est compris entre

@Anonymous a écrit :
;;;============================================================================
;;;
;;; Paramètres à définir par l'utilisateur
;;;
;;; Mon_Bloc = Le nom du bloc à modifier
;;;
;;; Mes_Attributs = Une liste des attributs à modifier
;;; La liste de compose du nom de l'étiquette et de sa couleur
;;; Par exemple l'étiquette ETQ1 et la couleur rouge (1)
;;; l'étiquette ETQ2 et la couleur jaune (2)
;;; (setq Mes_Attributs '(("ETQ1" 1) ("ETQ2" 2)))
;;;
;;;============================================================================

@Anonymous a écrit :
;;;============================================================================
;;;
;;; Fin des paramètres à définir par l'utilisateur
;;;
;;;============================================================================

Donc pour correspondre à ton besoin

  (setq Mon_Bloc "AUTO2AT")
  (setq Mes_Attributs '(("TITRE1" 3) ("PLAN" 3)))

Re: Modificatiion couleur attribut texte dans un bloc

Anonymous — Thu, 17 Jan 2019 07:03:26 GMT

bonjour désolé mais je n'y arrive pas : la programmation ! ce n'est vraiment pas ma tasse de thé 😞

rappel:

1 folio =1fichier,

dans mon bloc cartouche il faut passer la couleur jaune en vert pour les 2 attributs.

bloc cartouche = AUTO4DE

contenant étiquette/attribut = titre1

et étiquette/attribut = plan

Re: Modification couleur attribut texte dans un bloc

patrick.emin — Sun, 20 Jan 2019 18:01:35 GMT

Bonjour @Anonymous

Si une des réponses à votre question résout votre problème, vous a permis de le comprendre ou contribue significativement à sa résolution, voulez vous avoir l'amabilité de cliquer sur le bouton "Accepter comme solution" en bas de la réponse qui apporte une solution?

Merci de ne pas accepter comme solution le message que vous êtes en train de lire.

Si nos équipes de support technique ont pu vous apporter une solution ou contribuer significativement à vous aider en dehors de ce forum, pouvez vous partager ici la solution trouvée et cliquer sur le bouton "Accepter comme solution" de façon qu'elle bénéficie à la communauté?
Merci.