sujet Re: Transformer une liste simple en liste de paires pointées. dans AutoCAD – tous produits - Forum Français

Transformer une liste simple en liste de paires pointées.

DenisHen — Fri, 06 Mar 2020 14:02:10 GMT

Bonjour à tous.

Je cherche à transformer une liste simple en liste de paires pointées, de ça :

("lundi" "mardi" "mercredi"...)

J'aimerais en faire ça :

((1 . "lundi") (2 . "mardi") (3 . "mercredi")...)

Je pense que ça doit se faire avec un mapcar, mais cette fonction reste pour moi un mystère.

Bon week-end à tous.

Denis...

Re: Transformer une liste simple en liste de paires pointées.

CADaSchtroumpf — Fri, 06 Mar 2020 14:06:34 GMT

Salut,

et oui (mapcar est la solution, pourtant les exemples de l'aide sont assez explicite...

(mapcar '(lambda ( x y ) (cons x y)) '(1 2 3 4 5 6 7) '("lundi" "mardi" "marcredi" "jeudi" "vendredi" "samedi" "dimanche"))

Re: Transformer une liste simple en liste de paires pointées.

DenisHen — Fri, 06 Mar 2020 14:19:22 GMT

Salut CADaSchtroumpf, et merci pour ton aide.

L'aide est peut-être "explicite" pour toi, pour moi, c'est autre chose (surtout en anglais).🤔

Mon problème est que je ne connais pas la longueur de cette liste.

J'ai pris les jours de la semaine comme exemple, je trouvais ça plus "parlant" que ma propre liste...

Denis...

Re: Transformer une liste simple en liste de paires pointées.

patrick.emin — Fri, 06 Mar 2020 14:27:56 GMT

Voir le site de Didier Aveline : https://www.da-code.fr/mapcar/

Re: Transformer une liste simple en liste de paires pointées.

CADaSchtroumpf — Fri, 06 Mar 2020 14:34:44 GMT

Si tu veux faire des paires pointée à partir de 2 listes, il faut obligatoirement que celles ci soient de même longueur.

Autrement mapcar va tronquer à la liste la plus courte.

pour preuve:

(mapcar '(lambda ( x y ) (cons x y)) '(1 2 3 4 5 6) '("lundi" "mardi" "marcredi" "jeudi" "vendredi" "samedi" "dimanche"))
-> ((1 . "lundi") (2 . "mardi") (3 . "marcredi") (4 . "jeudi") (5 . "vendredi") (6 . "samedi"))

(mapcar '(lambda ( x y ) (cons x y)) '(1 2 3 4 5 6 7) '("lundi" "mardi" "marcredi" "jeudi" "vendredi" "samedi"))
-> ((1 . "lundi") (2 . "mardi") (3 . "marcredi") (4 . "jeudi") (5 . "vendredi") (6 . "samedi"))

et sans passer par mapcar :

(cons "toto" nil) -> ("toto") liste simple

(cons nil "toto") -> (nil . "toto") paire pointée dont le premier élément et vide

Re: Transformer une liste simple en liste de paires pointées.

DenisHen — Fri, 06 Mar 2020 14:36:56 GMT

Bonjour Patrick et merci pour cette réponse.

Je cherche toujours l'aide sur le site de Maître Didier, découvert grâce à CadXP.

Mais sur cette fonction, j'ai beaucoup de mal.

Je n'arrive pas à incrémenter le premier élément pour en faire ma liste de paires pointées.

J'ai fais plein de testes dans la console, mais je n'arrive à rien...

Denis.

Re: Transformer une liste simple en liste de paires pointées.

DenisHen — Fri, 06 Mar 2020 14:39:15 GMT

Merci CADaSchtroumpf pour ton aide.

Je vais faire des essais avec ta proposition...

Re: Transformer une liste simple en liste de paires pointées.

Bruno-VDH — Fri, 06 Mar 2020 15:12:35 GMT

Bonjour,

Comme ceci

(defun consNum (n l)
(if l
(cons (cons n (car l)) (consNum (1+ n) (cdr l)))))

_$ (consNum 1 '("lundi" "mardi" "mercredi" "jeudi" "vendredi" "samedi" "dimanche"))
((1 . "lundi") (2 . "mardi") (3 . "mercredi") (4 . "jeudi") (5 . "vendredi") (6 . "samedi") (7 . "dimanche"))

Ou en ajoutant un compteur pour la solution avec mapcar

(setq i 0)
(mapcar '(lambda (x) (cons (setq i (1+ i)) x)) '("lundi" "mardi" "mercredi" "jeudi" "vendredi" "samedi" "dimanche") )

Salutations

Re: Transformer une liste simple en liste de paires pointées.

O_Eckmann — Fri, 06 Mar 2020 15:55:29 GMT

Si tu ne t'en sors pas avec mapcar, utilise une simple boucle

(setq Liste (list "Lundi" "Mardi")) (setq i 0) (repeat (length Liste) (setq newListe (append newListe (list (cons (1+ i) (nth i Liste))))) (setq i (1+ i)) )

Olivier

Re: Transformer une liste simple en liste de paires pointées.

_gile — Fri, 06 Mar 2020 16:11:11 GMT

Salut,

A priori, ce que tu veux faire est inutile. Le principal intérêt des listes de paires pointées est l'accès aux éléments de la liste par 'clé' (avec assoc).

Si la clé est incrémentée elle n'offre de ce point de vue aucun avantage par rapport à la fonction nth.

(nth (1- n) '("lundi" "mardi" "mercredi" "jeudi" "vendredi" "samedi" "dimanche" ) )

est équivalent à :

(cdr (assoc n '((1 . "lundi") (2 . "mardi") (3 . "mercredi") (4 . "jeudi") (5 . "vendredi") (6 . "samedi") (7 . "dimanche") ) ) )

Re: Transformer une liste simple en liste de paires pointées.

DenisHen — Mon, 09 Mar 2020 07:43:22 GMT

Bonjour à tous, et merci pour votre aide.

J'ai fini par adopter une autre méthode, je construit ma liste directement en liste de paire pointées.

J'avais besoin de paires pointées pour utiliser le LISP de Maître _Gile, "ListBox".

Encore merci à vous.

Denis...

Re: Transformer une liste simple en liste de paires pointées.

Bruno-VDH — Mon, 09 Mar 2020 09:11:35 GMT

Bonjour

Dans l'entête de la fonction listbox, il y avait la solution:

;; Exemple d'utilisation
;; (listbox "Présentation" "Choisir une présentation" (mapcar 'cons (layoutlist) (layoutlist)) 1)

Pour ton cas:

(mapcar 'cons lst lst)

Cordialement