tópico Re: script para layers - Lisp em AutoCAD - Fórum Português

script para layers - Lisp

Anonymous — Thu, 25 Sep 2014 12:25:33 GMT

boas pessoal..

preciso de um script que altere as layers todas de um desenho para uma cor e expessuras á minha escolhas e que logo de seguida coloque algumas layers com que trabalho com uma cor diferente e com a respectiva expessura..

preciso de algo deste género.... (command "layer" "m" "layer_1" "c" "56" "" "")...mas este cria a layer com a côr 56......mas era deste tipo que pretendia.

Obrigado

Re: script para layers - Lisp

hmsilva — Thu, 25 Sep 2014 13:50:14 GMT

Olá nmareis,

qual a cor e expessura para todas as layers, quais os nome da layers que trabalhas, cor e expessura?

Henrique

Re: script para layers - Lisp

Anonymous — Thu, 25 Sep 2014 15:15:06 GMT

preciso apenas de um exemplo...depois eu adapto ás minhas necessidades...obrigado

Re: script para layers - Lisp

hmsilva — Thu, 25 Sep 2014 15:33:25 GMT

Só mais uma pergunta, com"script" queres dizer um ficheiro .scr ou pode ser uma rotina de lisp?

Henrique

Re: script para layers - Lisp

Anonymous — Thu, 25 Sep 2014 15:56:54 GMT

pode ser uma rotina lisp....ou seja ( .lsp) obrigado...

Re: script para layers - Lisp

hmsilva — Thu, 25 Sep 2014 16:10:12 GMT

Aqui vai...

(defun c:demo (/ lay process)

  (defun process (la col lwt / trc)
    (if (= (vla-get-Lock la) :vlax-true)
      (progn
        (vla-put-Lock la :vlax-false)
        (setq trc (vla-get-truecolor la))
        (vla-put-colorindex trc col)
        (vla-put-truecolor la trc)
        (vlax-release-object trc)
        (vla-put-Lineweight la lwt)
        (vla-put-Lock la :vlax-True)
      )
      (progn
        (setq trc (vla-get-truecolor la))
        (vla-put-colorindex trc col)
        (vla-put-truecolor la trc)
        (vlax-release-object trc)
        (vla-put-Lineweight la lwt)
      )
    )
  )

  (vlax-for Layer (vla-get-layers (vla-get-ActiveDocument (vlax-get-acad-object)))
    (cond ((wcmatch (strcase (vla-get-Name Layer)) "LAYER A,LAYER B")
           (process layer 3 acLnWt020)
          )
          ((wcmatch (strcase (vla-get-Name Layer)) "LAYER C,LAYER D")
           (process layer 6 acLnWt020)
          )
          ((wcmatch (strcase (vla-get-Name Layer)) "LAYER E,LAYER F")
           (process layer 4 acLnWt020)
          )
          (T
           (process layer 1 acLnWt009)
          )
    )
  )
  (princ)
)

em que

((wcmatch (strcase (vla-get-Name Layer)) "LAYER A,LAYER B");; escreve o nome das layers em maiusculas
(process layer 3 acLnWt020);; 3 é a cor e acLnWt020 a expessura 0.2
)

(T
(process layer 1 acLnWt009);; todas as outras na cor 1 e expessura 0.09
)

Espero que ajude

Henrique

Re: script para layers - Lisp

Anonymous — Thu, 25 Sep 2014 16:32:54 GMT

Acho que ajuda mesmo...obrigadão....hoje já não tenho tempo mas amanhã vou tratar disso e vou experimentar depois dou o feedback...mais uma vez um muito obrigado.

Re: script para layers - Lisp

helmoatayde — Tue, 30 Jun 2020 14:22:56 GMT

Não funcionou como lisp. Funcionou como script mesmo, copiei o conteúdo e colei no "command line" do Autocad. Muito bom mesmo. Obrigado também.