tópico Re: Checar distância entre linhas em AutoCAD - Fórum Português

Checar distância entre linhas

Anonymous — Thu, 08 Sep 2016 18:10:05 GMT

Boa tarde pessoal,

Alguém poderia me ajudar?

Estou começando a mexer com lisps agora, e gostaria da ajuda de vocês, estou montando uma lisp que verifica a distância de uma linha da outra, sendo um padrão de offset de 1.5, passou disso tanto para baixo quanto para cima, está errado e ele pinta de outra cor, como no exemplo simulado abaixo:

Tenho a lisp que está anexado, porem gostaria de saber como adiciono faixas para colorir:

Como neste exemplo, ele pega só o que é maior que 1.5, gostaria de saber como faço faixas de 1.5 até 1.7 / 1.7 até 1.9

(progn
(if (>= (distance p1 p2) 1.5)
(entmake (list '(0 . "LINE") '(62 . 6) (cons 10 p1) (cons 11 p2)))
(entmake (list '(0 . "LINE") (cons 10 p1) (cons 11 p2)))
)

Alguém poderia me ajudar?

Peço desculpa se este não é o lugar certo do post e se alguém puder mover para o correto.

Re: Checar distância entre linhas

hmsilva — Fri, 09 Sep 2016 08:11:59 GMT

Olá luuscarp e bem vindo à Comunidade Autodesk!

Para criares as faixas em função das distancias, podes criar uma condição no entmake com os intervalos/cores que pretendes, por exemplo:

;(progn <<<< este progn não é necessário, a função 'if' será a resposta à 'if' anterior
      (if (>= (setq dis (distance p1 p2)) 1.5); a variavel dis fica com o valor da distancia para não estarmos a repetir a função 'distance'
            (entmake (list '(0 . "LINE")
                           (cons 62
                                 (cond ((<= 1.5 dis 1.7)
                                        6
                                       )
                                       ((<= 1.7 dis 1.9)
                                        7
                                       )
                                       ((<= 1.9 dis 2.1)
                                        8
                                       )
                                       (T 9); todos os valores superiores aos testes anteriores...
                                 )
                           )
                           (cons 10 p1)
                           (cons 11 p2)
                     )
            )
            (entmake (list '(0 . "LINE") (cons 10 p1) (cons 11 p2)))
      )
;)

Espero que ajude
Henrique

Re: Checar distância entre linhas

Anonymous — Fri, 09 Sep 2016 10:22:34 GMT

Muito obrigado hmsilva, me ajudou bastante, so mais uma dúvida, eu consigo fazer algo para selecionar mais de uma linha para analisar e sempre pegar as do lado e não por exemplo a primeira com a ultima. Essa pega as duas que seleciono e mede as distâncias com a linha.

Muito obrigado.

Re: Checar distância entre linhas

hmsilva — Fri, 09 Sep 2016 10:44:28 GMT

luuscarp escreveu:

Muito obrigado hmsilva, me ajudou bastante, so mais uma dúvida, eu consigo fazer algo para selecionar mais de uma linha para analisar e sempre pegar as do lado e não por exemplo a primeira com a ultima. Essa pega as duas que seleciono e mede as distâncias com a linha.

Muito obrigado.

luuscarp, fico feliz por ter podido ajudar!

Quanto a utilizar uma seleção multipla...pode ser possivel, mas quando lidamos com polilinhas é dificil definir qual está ao 'lado' porque as polilinhas podem ter o formato que entendermos...

Anexa um dwg de exemplo (um exemplo real das 'linhas para analisar', apenas algumas) com o antes e o depois para eu vêr o que dá para fazer...

Henrique

Re: Checar distância entre linhas

Anonymous — Fri, 09 Sep 2016 10:52:38 GMT

Segue anexo algumas linhas e o lisp.

Obs:

Coloquei as distâncias das linhas e as cores, valores maiores que 1.5 funcionaram, agora os menores está ficando com linhas brancas.

Re: Checar distância entre linhas

hmsilva — Fri, 09 Sep 2016 10:59:55 GMT

luuscarp escreveu:

Segue anexo algumas linhas e o lisp.

Obs:

Coloquei as distâncias das linhas e as cores, valores maiores que 1.5 funcionaram, agora os menores está ficando com linhas brancas.

Ok!

Isto hoje por aquí está caotico...mt trabalho!!!!

Mas quando tiver um tempinho, eu vejo o que dá para fazer.

Henrique

Re: Checar distância entre linhas

Anonymous — Fri, 09 Sep 2016 11:05:23 GMT

Sem problemas hmsilva, muito obrigado mesmo pela atenção.

Fico no aguardo.

Re: Checar distância entre linhas

Anonymous — Tue, 13 Sep 2016 19:36:24 GMT

Estou empacado nisto ainda, conseguiu ver algo amigo?

Re: Checar distância entre linhas

hmsilva — Tue, 13 Sep 2016 20:11:43 GMT

Olá luuscarp
Ainda não tive tempo para escrever o código.

O que me ocorre para criar uma selecção das polylines ė pedir ao utilizador que pique dois pontos (tipo fence / limha) e com esses pontos utilizar o ssget opção fence para criar a selecção, utilizar os pontos para criar uma linha temporária para testar a distância entre o primeiro pt e cada uma das polylines usando o método intetsectwith e guardar esse resultado numa lista juntamente c o ename de cada polyline. Organizar a lista da distancia mais pequena para a maior e processar esses elementos da list...

Este método de selecção funcionaria para ti?

Henrique

Re: Checar distância entre linhas

Anonymous — Wed, 14 Sep 2016 10:34:27 GMT

Bom dia @hmsilva,

Perfeito, creio que ja agiliza bastante.

Re: Checar distância entre linhas

hmsilva — Wed, 14 Sep 2016 10:44:46 GMT

luuscarp escreveu:

Bom dia @hmsilva,

Perfeito, creio que ja agiliza bastante.

Olá luuscarp,

com o pseudo código que eu postei anteriormente, consegues escrever a rotina?

Henrique

Re: Checar distância entre linhas

Anonymous — Wed, 14 Sep 2016 11:03:27 GMT

Posso tentar, mas ainda estou aprendendo lisp, então irei ter um grande nível de dificuldade, se puder me ajudar com apenas um "start" de exemplo, eu me viro.

Re: Checar distância entre linhas

hmsilva — Wed, 14 Sep 2016 11:08:58 GMT

luuscarp escreveu:
Posso tentar, mas ainda estou aprendendo lisp, então irei ter um grande nível de dificuldade, se puder me ajudar com apenas um "start" de exemplo, eu me viro.

Ok!

Hoje de noite, vou tentar arranjar um 'tempinho' para escrever uma 'demo'...

Henrique

Re: Checar distância entre linhas

hmsilva — Wed, 14 Sep 2016 14:19:45 GMT

Olá luuscarp,

apenas como 'demo'... 🙂

(vl-load-com)
(defun c:demo (/ a1 d1 d2 d3 dis dist dist_lst e1 e2 hnd i intersection line line_obj n obj obj_lst p1 p2 ps1 ps2 pt sp ss xl zv)
    (if (and
            (setq ps1 (getpoint "\nEspecifique o ponto de inicio da seleção das Polylines: "))
            (setq ps2 (getpoint ps1 "\nEspecifique o ponto final da seleção das Polylines: "))
            (progn
                (initget 6)
                (setq d1 (getdist "\nEspecifique o espaçamento das linhas que seram inseridas: "))
            )
        )
        (progn
            (command "_zoom" ps1 ps2)
            (if (setq ss (ssget "_F" (list ps1 ps2) '((0 . "LWPOLYLINE"))))
                (progn
                    (command "_line" "_NON" ps1 "_NON" ps2 "")
                    (setq line (entlast))
                    (setq line_obj (vlax-ename->vla-object line))
                    (repeat (setq i (sslength ss))
                        (setq hnd (ssname ss (setq i (1- i)))
                              obj (vlax-ename->vla-object hnd)
                        )
                        (if (setq intersection (vlax-invoke line_obj 'IntersectWith obj acExtendNone))
                            (progn
                                (setq n -1)
                                (repeat (/ (length intersection) 3)
                                    (setq pt       (list (nth (setq n (1+ n)) intersection)
                                                         (nth (setq n (1+ n)) intersection)
                                                         (nth (setq n (1+ n)) intersection)
                                                   )
                                          dist_lst (cons (distance pt ps1) dist_lst)
                                    )
                                )
                                (setq dist (apply 'min dist_lst))
                                (setq obj_lst (cons (cons dist hnd) obj_lst))
                                (setq obj_lst (vl-sort obj_lst '(lambda (a b) (< (car a) (car y)))))
                            )
                        )
                    )
                    (while (and (setq e1 (cdar obj_lst))
                                (setq obj_lst (cdr obj_lst))
                                (setq e2 (cdar obj_lst))
                           )
                        (setq d3 (- d1)
                              e2 (vlax-ename->vla-object e2)
                              d2 (vlax-curve-getdistatparam e1 (vlax-curve-getendparam e1))
                              zv (trans '(0.0 0.0 1.0) 1 0 t)
                              sp (vlax-get-property
                                     (vla-get-activedocument (vlax-get-acad-object))
                                     (if (= 1 (getvar 'cvport))
                                         'paperspace
                                         'modelspace
                                     )
                                 )
                        )
                        (while (<= (setq d3 (+ d3 d1)) d2)
                            (setq p1 (vlax-curve-getpointatdist e1 d3)
                                  a1 (- (angle '(0.0 0.0) (trans (vlax-curve-getfirstderiv e1 (vlax-curve-getparamatpoint e1 p1)) 0 1))
                                        (/ pi 2.0)
                                     )
                                  xl (vlax-invoke sp 'addxline p1 (trans (polar (trans p1 0 1) a1 1.0) 1 0))
                            )
                            (if
                                (setq p2
                                         (car
                                             (vl-sort (LM:group3 (vlax-invoke xl 'intersectwith e2 acextendthisentity))
                                                      '(lambda (a b) (< (distance a p1) (distance b p1)))
                                             )
                                         )
                                )
                                   (if (>= (setq dis (distance p1 p2)) 1.5)
                                       (entmake (list '(0 . "LINE")
                                                      (cons 62
                                                            (cond ((<= 1.5 dis 1.52)
                                                                   80
                                                                  )
                                                                  ((<= 1.52 dis 1.57)
                                                                   84
                                                                  )
                                                                  ((<= 1.57 dis 1.65)
                                                                   50
                                                                  )
                                                                  ((<= 1.65 dis 1.8)
                                                                   30
                                                                  )
                                                                  ((<= 1.8 dis 2.5)
                                                                   10
                                                                  )
                                                                  ((<= 2.5 dis 9.0)
                                                                   220
                                                                  )
                                                                  ((<= 1.499 dis 1.48)
                                                                   80
                                                                  )
                                                                  ((<= 1.48 dis 1.43)
                                                                   84
                                                                  )
                                                                  ((<= 1.43 dis 1.35)
                                                                   50
                                                                  )
                                                                  ((<= 1.35 dis 1.2)
                                                                   30
                                                                  )
                                                                  ((<= 1.2 dis 0.5)
                                                                   10
                                                                  )
                                                                  ((<= 0.5 dis 0.1)
                                                                   220
                                                                  )
                                                                  (T 9)
                                                            )
                                                      )
                                                      (cons 10 p1)
                                                      (cons 11 p2)
                                                )
                                       )
                                       (entmake (list '(0 . "LINE") (cons 10 p1) (cons 11 p2)))
                                   )
                            )
                            (vla-delete xl)
                        )
                    )
                    (vla-delete line_obj)
                    (command "_zoom" "_P")
                )
                (command "_zoom" "_P")
            )
        )
    )
    (princ)
)

(defun LM:group3 (lst / rtn)
    (repeat (/ (length lst) 3)
        (setq rtn (cons (list (car lst) (cadr lst) (caddr lst)) rtn)
              lst (cdddr lst)
        )
    )
    (reverse rtn)
)

Espero que ajude
Henrique

Re: Checar distância entre linhas

Anonymous — Wed, 14 Sep 2016 16:07:27 GMT

Perfeito Henrique, muito obrigado mesmo, agora daqui pra frente eu me viro, ja me esclareceu bastante.

Agradeço.

Re: Checar distância entre linhas

hmsilva — Wed, 14 Sep 2016 16:09:57 GMT

luuscarp escreveu:

Perfeito Henrique, muito obrigado mesmo, agora daqui pra frente eu me viro, ja me esclareceu bastante.

Agradeço.

luuscarp, fico feliz por ter podido ajudar! 🙂

Qualquer dúvida, pergunta...

Henrique

Re: Checar distância entre linhas

Anonymous — Wed, 21 Sep 2016 10:18:45 GMT

Bom dia @hmsilva

Está rodando certinho a lisp, mas ai me surgiu uma dúvida, eu consigo colocar essa tabela com a % de cada uma no total?

Exemplo:

Faixa 1 - 1000 metros lineares - 50%

Faixa 2 - 800 metros lineares - 40%

Faixa 3 - 200 metros lineares - 10%

Re: Checar distância entre linhas

hmsilva — Thu, 22 Sep 2016 09:58:48 GMT

luuscarp escreveu:

Bom dia @hmsilva

Está rodando certinho a lisp, mas ai me surgiu uma dúvida, eu consigo colocar essa tabela com a % de cada uma no total?

Exemplo:

Faixa 1 - 1000 metros lineares - 50%

Faixa 2 - 800 metros lineares - 40%

Faixa 3 - 200 metros lineares - 10%

Olá luuscarp,

estou com uma carga de trabalho gigante.... e não tenho tempo livre nenhum... 😞

Com uma vista de olhos 'rápida' à tabela, não vejo como se poderá calcular a percentagem das faixas...

Tenta anexar um dwg (pequeno) com algumas faixas e com uma tabela para eu ver se consigo arranjar uma relação entre o desenho e a tabela...

Henrique

Re: Checar distância entre linhas

Anonymous — Thu, 22 Sep 2016 17:37:48 GMT

(defun c:Layleg (/ aDoc alllayer space b mtx dist d)
;;; pBe 14Nov2013 ;;;
(vl-load-com)
(setq alllayer nil
adoc (vla-get-activedocument (vlax-get-acad-object))
space (vlax-get (vla-get-ActiveLayout adoc) 'Block)
dist (+ (setq d (getvar 'Textsize)) (* d 0.5))
)
(vlax-for lay (vla-get-layers aDoc)
(setq alllayer
(cons (list (vla-get-name lay) (vla-get-description lay))
alllayer
)
)
)
(if (and
(setq alllayer (vl-remove-if
'(lambda (x)
(or (member (car x) '("0" "Defpoints"))
(eq (cadr x) "")
)
)
alllayer
)
)
(setq b (getpoint "\nPick point to place Legend: "))
)
(foreach itm (reverse alllayer)
(setq mtx (vlax-invoke
space
'addmtext
(trans b 1 0)
0.0
(strcat (car itm) " " (cadr itm))
)
)
(vla-put-layer mtx (car itm))
(setq b (polar b (* pi 1.5) dist))
)
(cond
((null alllayer)(princ "\nInvalid Layer List"))
((null b)(princ "\nInvalid point"))
)
)
(princ)
)

Achei esse aqui, que soma o total linear das linhas e insere uma tabela.

Eu estava pensando, definir cada faixa para um layer e talvez colocar fixo na tabela cada layer, sera que daria certo?

Re: Checar distância entre linhas

hmsilva — Fri, 23 Sep 2016 10:30:46 GMT

luuscarp escreveu:

Achei esse aqui, que soma o total linear das linhas e insere uma tabela.

....

Eu estava pensando, definir cada faixa para um layer e talvez colocar fixo na tabela cada layer, sera que daria certo?

Olá luuscarp,

o codigo do pbejse que postaste apenas cria uma legenda dos nomes e descrição dos layers...

Como tinha pedido na minha anterior msg:

Tenta anexar um dwg (pequeno) com algumas faixas e com uma tabela para eu ver se consigo arranjar uma relação entre o desenho e a tabela...

Com um desenho é mais facil tentar arranjar uma solução.

Henrique