topic Re: Lisp to create polyline with arrow in the ends, but not everytime! in AutoCAD Forum

Lisp to create polyline with arrow in the ends, but not everytime!

Anonymous — Thu, 29 Jul 2021 23:37:58 GMT

Dear all,
Can someone help me?
I need to create A LOT of polylines in my projects and sometimes they need to have an arrow at the beginning, end, or both, and I think a lisp like this could be helpful, instead of create a polyline then copy an arrow to the end.
I'm new with lisp and don't know hot to do it but I imagine something that, after the command, when I click on the screen pops up a window with options "yes" and "no" so I can choose to put an arrow on the beginning, then I would click on everywhere I need to extend my polyline, and in the end, with ESC, it opens another window asking me again if I want to leave an arrow in the end or not. All this made with the current layer. I've tried to use "leader" but it's not what I need, although the style of the arrow was fine! With leader the arrow should be "Closed Filled" with size 2.5, if that can help with the style.

This is what I need:

I'm sorry if my english is not right, it's not used at all in my country
Since now, thank you for your attention!

Re: Lisp to create polyline with arrow in the ends, but not everytime!

RobDraw — Fri, 30 Jul 2021 12:04:22 GMT

Leaders should work fine. You can change the size in the style definition.

For LISP, I would suggest using the Customization and LISP forum.

Re: Lisp to create polyline with arrow in the ends, but not everytime!

Kent1Cooper — Fri, 30 Jul 2021 13:05:31 GMT

@RobDraw wrote:

Leaders should work fine. ....

For LISP, I would suggest using the Customization and LISP forum.

Leaders won't give you the both-ends option. But I agree, the >Customization Forum< is the place to go.

Re: Lisp to create polyline with arrow in the ends, but not everytime!

RobDraw — Sat, 31 Jul 2021 18:43:50 GMT

Personally, I don't use polylines for this. I use a block for the arrowheads and draw lines.

Re: Lisp to create polyline with arrow in the ends, but not everytime!

ВeekeeCZ — Sun, 01 Aug 2021 15:11:49 GMT

This should do the work. You can pre-select the existing pline to add arrows to it.

(vl-load-com)
;; beekeecz 21-08-01

(defun c:PArrow ( / :PLAddVertex e len)

  ;; From Lee Mac's code
(defun :PLAddVertex (e p / tan LM:LWVertices a b e h l n r w x z)
  (defun tan ( x ) (if (not (equal 0.0 (cos x) 1e-10)) (/ (sin x) (cos x))))
  (defun LM:LWVertices ( e )
    (if (setq e (member (assoc 10 e) e))
      (cons (list (assoc 10 e) (assoc 40 e) (assoc 41 e) (assoc 42 e))
	    (LM:LWVertices (cdr e)))))
  
  (if (and p
	   e
	   (setq p (vlax-curve-getclosestpointto e (trans p 1 0))
		 n (vlax-curve-getparamatpoint e p)))
    (if (not (equal n (fix n) 1e-8))
      (progn
	(setq e (entget e)
	      h (reverse (member (assoc 39 e) (reverse e)))
	      l (LM:LWVertices e)
	      z (assoc 210 e))
	(repeat (fix n)
	  (setq a (cons (car l) a)
		l (cdr l)))
	(setq x (car l)
	      r (- n (fix n))
	      w (cdr (assoc 40 x))
	      w (+ w (* r (- (cdr (assoc 41 x)) w)))
	      b (atan (cdr (assoc 42 x))))
	(entmod (append h
			(apply 'append (reverse a))
			(list (assoc 10 x)
			      (assoc 40 x)
			      (cons  41 w)
			      (cons  42 (tan (* r b))))
			(list
			  (cons  10 (trans p 0 (cdr z)))
			  (cons  40 w)
			  (assoc 41 x)
			  (cons  42 (tan (* (- 1.0 r) b))))
			(apply 'append (cdr l))
			(list z)))))))

  ; -----------------------------------------------------------------------------------------------------

  (if (ssget "_I" '((0 . "LWPOLYLINE")))
    (setq e (ssname (ssget "_I") 0))
    (progn
      (command "_.pline") (while (> (getvar 'cmdactive) 0) (command pause))
      (setq e (entlast))))

  (setq o (vlax-ename->vla-object e))

  (or *pa-t*
      (setq *pa-t* "End"))
  (initget "Start Both End")
  (setq *pa-t* (cond ((getkword (strcat "\nAdd arrows to [Start/Both/End] <" *pa-t* ">: "))) (*pa-t*)))

  (and (vl-position *pa-t* '("Start" "Both"))
       (< (vlax-curve-getparamatdist e 2.5) 1.)
       (:PlAddVertex e (vlax-curve-getpointatdist e 2.5))
       ;(not (vla-SetBulge o 0 0))
       (vla-SetWidth o 0 0 0.833))
  
  (and (vl-position *pa-t* '("End" "Both"))
       (setq len (vlax-curve-getdistatparam e (vlax-curve-getendparam e)))
       (< (- (vlax-curve-getendparam e) (vlax-curve-getparamatdist e (- len 2.5))) 1)
       (:PlAddVertex e (vlax-curve-getpointatdist e (- len 2.5)))
       ;(not (vla-SetBulge o (1- (vlax-curve-getendparam o)) 0))
       (vla-SetWidth o (1- (vlax-curve-getendparam o)) 0.833 0))
  (princ)
  )

Re: Lisp to create polyline with arrow in the ends, but not everytime!

Anonymous — Sun, 01 Aug 2021 18:51:21 GMT

Thank you very much for this LISP @ВeekeeCZ, it's just what I was in need! You're awesome!
When I use linetype "dashed" the arrow shows dashed too. Is it something that I need to correct on my AutoCAD?
If not, can you please fix this for me??

I'm sorry for using the wrong area, I'm new here. It won't happen again!

Re: Lisp to create polyline with arrow in the ends, but not everytime!

Erik_Le — Mon, 06 Apr 2026 16:42:00 GMT

Hi BeekeeCZ,

I like this routine, but is there a way to modify it to be able to use a block for the arrowhead at the ends and have it oriented (rotation / angle) in the same direction / angle of the polyline at the beginning and at the end?

Re: Lisp to create polyline with arrow in the ends, but not everytime!

Erik_Le — Mon, 06 Apr 2026 16:47:26 GMT

I also saw your other posting https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/routine-for-double-arrows/m-p/7800481#M108350 , but this seems to only draw one segment line. Can I combine the two routines to draw a multi-segmented polyline (possibly with arcs) with a block of an arrowhead pointing in the correct direction? I appreciate any guidance.

Re: Lisp to create polyline with arrow in the ends, but not everytime!

ВeekeeCZ — Tue, 07 Apr 2026 14:07:58 GMT

This should do the trick.

(vl-load-com)

(defun c:ArrowDouble ( / pnt enl ent ss i)

  (if (setq pnt (getpoint "\nFirst point <select>: "))
    (progn
      (setq enl (entlast))
      (command-s "_.PLINE" "_none" pnt)
      (if (not (equal enl (setq enl (entlast))))
	(setq ss (ssadd enl))))
    (setq ss (ssget "_:L" '((0 . "LWPOLYLINE,LINE,ARC")))))

  (if ss
    (repeat (setq i (sslength ss))
      (setq ent (ssname ss (setq i (1- i))))
      
      (command "._INSERT"
               "DIM-AH"
               "_Scale" (/ 1. (getvar 'CANNOSCALEVALUE) 120)
               "_Rotate" "_none" (trans (vlax-curve-getFirstDeriv ent (vlax-curve-getParamAtPoint ent (vlax-curve-getStartPoint ent))) 0 1) "_none" (trans '(0 0 0) 0 1) 
               "_none" (trans (vlax-curve-getStartPoint ent) 0 1))

      (command "._INSERT"
               "DIM-AH"
               "_Scale" (/ 1. (getvar 'CANNOSCALEVALUE) 120)
               "_Rotate" "_none" (trans '(0 0 0) 0 1) "_none" (trans (vlax-curve-getFirstDeriv ent (vlax-curve-getParamAtPoint ent (vlax-curve-getEndPoint ent))) 0 1)
               "_none" (trans (vlax-curve-getEndPoint ent) 0 1))))
  (princ)
)

Re: Lisp to create polyline with arrow in the ends, but not everytime!

Erik_Le — Tue, 07 Apr 2026 15:35:34 GMT

Genius! Thanks a bunch! This is exactly what I was looking for. If you are looking for additional challenge, is there a way to dynamically adjust the polyline with grips so that if the ends of the line get adjusted the arrowheads would adjust with the polyline?

Thanks again!