topic Re: Delete all solid hatches in AutoCAD Forum

Delete all solid hatches

kameron1967 — Mon, 22 Sep 2014 22:46:08 GMT

Hi guys,

I would like to be able to go into a drawing and delete all solid hatches from all layers. Is this possible? Thank you kindly. 🙂

Kameron

Re: Delete all solid hatches

Lee_Mac — Mon, 22 Sep 2014 22:59:50 GMT

The following will delete all solid hatches from all layouts and from within blocks & nested blocks (nested to any level):

(defun c:delsolhat ( / d )
    (vlax-for b (vla-get-blocks (setq d (vla-get-activedocument (vlax-get-acad-object))))
        (if (= :vlax-false (vla-get-isxref b))
            (vlax-for o b
                (if (and (= "AcDbHatch" (vla-get-objectname o))
                         (= "SOLID" (strcase (vla-get-patternname o)))
                         (vlax-write-enabled-p o)
                    )
                    (vla-delete o)
                )
            )
        )
    )
    (vla-regen d acallviewports)
    (princ)
)
(vl-load-com) (princ)

Re: Delete all solid hatches

Lee_Mac — Mon, 22 Sep 2014 23:01:11 GMT

Alternatively, for primary hatches only (in all layouts):

(defun c:delsolhat ( / i s )
    (if (setq s (ssget "_X" '((0 . "HATCH") (2 . "SOLID"))))
        (repeat (setq i (sslength s)) (entdel (ssname s (setq i (1- i)))))
    )
    (princ)
)

Re: Delete all solid hatches

kameron1967 — Mon, 22 Sep 2014 23:45:52 GMT

Awesome, Lee. I'll give them a try and will let you know. 🙂

Update: I tried it and it did not appear to have removed the solid hatches. I listed it and it shows solid. My guess is that it's truly a solid, not a solid hatch. Is it possible to update your routine to also include a solid? Thanks again Lee!

Re: Delete all solid hatches

kameron1967 — Tue, 23 Sep 2014 15:21:29 GMT

Lee, the solid does not have z dimensions. I think it was converted from other 3D software. Anyways, I was able to do a quick selection, but then I'd have to specify its exact layer in order to delete them and there are at least 20 layers that have these 3D solid acting as hatches.

Thank you sir.

Re: Delete all solid hatches

Lee_Mac — Tue, 23 Sep 2014 16:45:43 GMT

kameron1967 wrote:

To clarify: there should be nothing wrong with the posted code based on the original request. The two supplied programs will successfully remove all solid hatches from all layouts of a drawing, as described in the two posts.

From what you have described, it would seem that the issue is the objects you need to delete are not hatches, but rather solids.

I would suggest using either the SSX or FILTER commands to make the appropriate selection, and then erase the active selection.

Re: Delete all solid hatches

Kent1Cooper — Tue, 23 Sep 2014 16:54:25 GMT

@kameron1967 wrote:

... I was able to do a quick selection, but then I'd have to specify its exact layer in order to delete them ....

I don't think that's the case. You should be able to get into QSELECT, and in the Object type: section, pull down the list and select the appropriate kind of Solid, and in the Operator: section, pull it down and pick Select All. It should find all of them regardless of Layer [or color, or....] -- hit the Delete button or type E for Erase.

Re: Delete all solid hatches

kameron1967 — Tue, 23 Sep 2014 17:32:42 GMT

You're absolutely right, Lee. Your nicely written routines (both) worked like a charm on solid hatches. Thank you, those would come in handy as well! 🙂

I will do as you suggested.

Re: Delete all solid hatches

kameron1967 — Tue, 23 Sep 2014 17:37:26 GMT

Ken1Cooper - you're right. I was able to do a select all, so that works. Thanks. I miscommunicated about the hatching. So both you and Lee came up with the solutions. Thanks a lot gents! Kudos to you both! 🙂

Re: Delete all solid hatches

Anonymous — Mon, 23 Mar 2015 09:55:59 GMT

Hello everyone, 
I tried using the lisp mentioned , 
only that removes only the hatches and solids remain , you have a solution ?
Mirco

Re: Delete all solid hatches

pbejse — Mon, 23 Mar 2015 10:16:25 GMT

@Anonymous wrote:

Hello everyone, 
I tried using the lisp mentioned , 
only that removes only the hatches and solids remain , you have a solution ?
Mirco

From
(= "SOLID" (strcase (vla-get-patternname o)))
to

(= "_SOLID" (strcase (vla-get-patternname o)))

But the code from this thread will Delete ALL solid hatch. I could've sworn i replied to your psot on another Forum [ CTT ] where you're asking for solid hatch inside blocks only.

Re: Delete all solid hatches

owitzki — Thu, 17 Nov 2016 19:17:35 GMT

Can you also include in this apps deleting all dimensions?

Re: Delete all solid hatches

Kent1Cooper — Thu, 17 Nov 2016 19:29:50 GMT

@Anonymous wrote:

....that removes only the hatches and solids remain , you have a solution ?
....

Yes, an old post....

If you're still out there, welcome to these Forums! By "solids" that remain, do you mean 3D Solids, or the 2D ones made with the SOLID command? It would be a simple matter to add an appropriate entity type to the selection part.

Re: Delete all solid hatches

owitzki — Thu, 17 Nov 2016 19:35:39 GMT

Please also add set all colors 'bylayer'?

Thanks a lot!

Kudos to the experts, the routine above alone helps me a lot. Even better if all dimensions be deleted & set all layer color bylayer! cheers!

Re: Delete all solid hatches

Kent1Cooper — Thu, 17 Nov 2016 19:45:18 GMT

@owitzki wrote:

Can you also include in this apps deleting all dimensions?

Welcome to these Forums!

Do you mean to delete all Dimensions along with all Solid Hatch patterns? Or are you looking for something to delete all Dimensions only?

It gets a little more complicated, because the ObjectName VLA Property [the "AcDbHatch" part in @Lee_Mac's code] varies among different types of Dimensions, but I believe at least they all end with "Dimension." If you want Dimensions along with Solid Hatches, try this modification [untested]:

....
                (if
                  (and
                    (or
                      (and ; Solid Hatches:
                        (= "AcDbHatch" (vla-get-objectname o))
                        (= "SOLID" (strcase (vla-get-patternname o)))
                      ); and
                      (wcmatch (vla-get-objectname o) "*Dimension")
                    ); or
                    (vlax-write-enabled-p o)
                  ); and
                  (vla-delete o); then
                ); if
....

Re: Delete all solid hatches

Kent1Cooper — Thu, 17 Nov 2016 19:51:05 GMT

@owitzki wrote:

Please also add set all colors 'bylayer'?

....

Adding a line to my previous Reply should do it:

                  ); and
                  (vla-delete o); then
                  (vla-put-Color o 256); else
                ); if
....

Re: Delete all solid hatches

owitzki — Thu, 17 Nov 2016 20:51:44 GMT

Yes please, along with solid hatch and solid entity if not too much... tnx

Re: Delete all solid hatches

owitzki — Thu, 17 Nov 2016 21:36:39 GMT

It works seamlessly! Thanks

Re: Delete all solid hatches

Anonymous — Fri, 16 Jun 2017 10:46:17 GMT

Is it possible to modify this code, so that for example only solid hatches in White is deleted ?

Re: Delete all solid hatches

Kent1Cooper — Fri, 16 Jun 2017 14:10:47 GMT

@Anonymous wrote:

Is it possible to modify this code, so that for example only solid hatches in White is deleted ?

Welcome to these Forums!

Do you mean such objects that are white because that is the color of the Layer they are drawn on [and their color is BYLAYER]. or those that are white for being given a color override [their color is 7]? Either can be done pretty easily, but it makes a difference.