topic Re: LISP or Command? in AutoCAD Forum

LISP or Command?

anderson51 — Fri, 07 Aug 2015 14:57:41 GMT

I am trying to figure out how to write a LISP routine or generate an equation within a command that will take MASSPROP and divide that number by 17.28, then times it by 4.9.......when I click on a solid?

I apprecite the help.

Anderson

Re: LISP or Command?

hmsilva — Fri, 07 Aug 2015 15:20:44 GMT

@anderson51 wrote:

I am trying to figure out how to write a LISP routine or generate an equation within a command that will take MASSPROP and divide that number by 17.28, then times it by 4.9.......when I click on a solid?

I apprecite the help.

Anderson

Hi Anderson,

@ the Visual LISP, AutoLISP and General Customization forum should be easier to help with Auto/Visual LISP

Perhaps something like this to do the trick

(vl-load-com)
(defun c:demo (/ obj ss val vol)
    (if (and (princ "\n Select a 3D Solid: ")
             (setq ss (ssget "_+.:E:S" '((0 . "3DSOLID"))))
        )
        (progn
            (setq obj (vlax-ename->vla-object (ssname ss 0))
                  vol (vla-get-volume obj)
                  val (* (/ vol 17.28) 4.9)
            )
            (princ (strcat "\n The value is: " (rtos val 2 2)))
        )
        (princ "\n You didn't select a 3D Solid... ")
    )
    (princ)
)

Hope this helps,
Henrique

Re: LISP or Command?

anderson51 — Fri, 07 Aug 2015 16:35:19 GMT

Thank you for the help, that works for selecting 1 solid.

Is there a way to set it up where you can window a group of solids?

Thanks again.

Anderson

Re: LISP or Command?

hmsilva — Fri, 07 Aug 2015 16:41:53 GMT

@anderson51 wrote:

Thank you for the help, that works for selecting 1 solid.

Is there a way to set it up where you can window a group of solids?

Thanks again.

Anderson

You're welcome, Anderson
The final result would be only the total?

Henrique

Re: LISP or Command?

anderson51 — Fri, 07 Aug 2015 16:45:49 GMT

Yes.

Re: LISP or Command?

hmsilva — Fri, 07 Aug 2015 16:53:19 GMT

(vl-load-com)
(defun c:demo (/ obj ss tot val vol)
    (if (and (princ "\n Select a 3D Solid: ")
             (setq ss (ssget '((0 . "3DSOLID"))))
        )
        (progn
            (setq tot 0.0)
            (repeat (setq i (sslength ss))
                (setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i))))
                      vol (vla-get-volume obj)
                      val (* (/ vol 17.28) 4.9)
                      tot (+ tot val)
                )
            )
            (princ (strcat "\n The value is: " (rtos tot 2 2)))
        )
        (princ "\n You didn't select a 3D Solid... ")
    )
    (princ)
)

Hope this helps,
Henrique

Re: LISP or Command?

anderson51 — Fri, 07 Aug 2015 16:59:55 GMT

Fantastic, thank you for the help sir.

Anderson

Re: LISP or Command?

hmsilva — Fri, 07 Aug 2015 18:43:36 GMT

@anderson51 wrote:

Fantastic, thank you for the help sir.

Anderson

You're welcome, Anderson!
Glad I could help

Henrique