topic Re: Draw transition lines between and arc and a line in AutoCAD Forum

Draw transition lines between and arc and a line

Anonymous — Sun, 04 Sep 2016 02:01:48 GMT

i need to draw multiple parallel lines between the red arc and the red line as its shown on the image.

when i do this with offset i get this problem.... what i need is a perfect transition, the rect line transfor into the arc.

thankss! and sorry for my english!

Re: Draw transition lines between and arc and a line

Patchy — Sun, 04 Sep 2016 03:28:11 GMT

Looks like OFFSET command to me.

Re: Draw transition lines between and arc and a line

Anonymous — Sun, 04 Sep 2016 05:14:34 GMT

the problem with offset is what i show on the second image!!! i need that lines start straight and end curved... and all this in a transition!!!!!

please somenonee???

Re: Draw transition lines between and arc and a line

Anonymous — Sun, 04 Sep 2016 05:55:26 GMT

Dear Wizled

Am not sure about your query but from my end i have done something which may help you....i have done offset with multiple option and trimmed the unwanted entities. screen shot regarding the same is attached with

Re: Draw transition lines between and arc and a line

Anonymous — Sun, 04 Sep 2016 07:04:30 GMT

thanks for your time! but the problem with that is that i need that at the end the lines touch the ground as straight line, as i draw in the images that i attached.

Re: Draw transition lines between and arc and a line

SEANT61 — Sun, 04 Sep 2016 08:24:11 GMT

The transition from curved to straight would not allow the lines to be parallel. A slight variation is required. See sample.

Re: Draw transition lines between and arc and a line

SEANT61 — Sun, 04 Sep 2016 08:29:19 GMT

It could be done with "almost parallel" arcs. Divide the end lines, as well as a line connecting the two closest points between Arc and Line, by whatever sub-division you need (like 30 in my previous example). Now use the Arc with 3 Pt. option, and snap (Node) to the corresponding division points.

Re: Draw transition lines between and arc and a line

ВeekeeCZ — Sun, 04 Sep 2016 13:08:41 GMT

You can try this lisp, see spoiler.

(vl-load-com)

(defun c:TransArc2Line ( / en1 en2 pt1 pt2 dst stp line)

  (if (and (setq en1 (car (entsel "\nSelect first arc/line: ")))
	   (wcmatch (cdr (assoc 0 (entget en1))) "ARC,LINE")
	   (setq en2 (car (entsel "\nSelect second arc/line: ")))
	   (wcmatch (cdr (assoc 0 (entget en2))) "ARC,LINE")
	   (setq stp (getint "\nNumber of steps: ")))
    (progn
      (if (= "LINE" (cdr (assoc 0 (entget en1))) (cdr (assoc 0 (entget en2))))
	(setq line T))
      (setq pt1 (list (vlax-curve-getStartPoint en1)
		      (vlax-curve-getPointAtDist en1 (/ (vlax-curve-getDistAtParam en1 (vlax-curve-getEndParam en1)) 2.))
		      (vlax-curve-getEndPoint en1))
	    pt2 (list (vlax-curve-getStartPoint en2)
		      (vlax-curve-getPointAtDist en2 (/ (vlax-curve-getDistAtParam en2 (vlax-curve-getEndParam en2)) 2.))
		      (vlax-curve-getEndPoint en2))
	    dst (mapcar '(lambda (x y) (/ (distance x y) (float stp))) pt1 pt2))
      (repeat (1- stp)
	(setq stp (1- stp))
	(if line
	  (command "_.LINE"
		   "_none" (polar (car pt1) (angle (car pt1) (car pt2)) (* stp (car dst)))
		   "_none" (polar (last pt1) (angle (last pt1) (last pt2)) (* stp (last dst)))
		   "")
	  (command "_.ARC"
		   "_none" (polar (car pt1) (angle (car pt1) (car pt2)) (* stp (car dst)))
		   "_none" (polar (cadr pt1) (angle (cadr pt1) (cadr pt2)) (* stp (cadr dst)))
		   "_none" (polar (last pt1) (angle (last pt1) (last pt2)) (* stp (last dst))))))))
  (princ)
)

HERE is Lee's tutorial how to use lisp in case you don't know.

Re: Draw transition lines between and arc and a line

Anonymous — Sun, 04 Sep 2016 20:46:47 GMT

thanks!! thats what i need! but i dont undrstand what you do, you start with offset?? and then you modify end lines?

Re: Draw transition lines between and arc and a line

Anonymous — Sun, 04 Sep 2016 20:47:36 GMT

how you usen the this particular one? there is a command?

Re: Draw transition lines between and arc and a line

Anonymous — Mon, 05 Sep 2016 05:44:05 GMT

finally i undestand!!!! thank you very much!!!

Re: Draw transition lines between and arc and a line

ВeekeeCZ — Mon, 05 Sep 2016 07:04:15 GMT

The routine automates the process described by @SEANT61 into a few seconds job.

See the SCREENCAST