topic Re: rounding to nearest floor. in AutoCAD Forum

rounding to nearest floor.

Anonymous — Thu, 26 Oct 2017 05:00:36 GMT

Hello, i want to achieve something like this when dimensioning my drawings.

i.e measurement 1.1 rounds to 1.

1.5 rounds to 1, not 2.

1.6 round also 1, not 2.

in programming it called nearest floor.

Re: rounding to nearest floor.

Anonymous — Thu, 26 Oct 2017 05:04:35 GMT

In the DIMSTYLE, go to Primary Units, Adjust Precision and Round off value that you want.

Re: rounding to nearest floor.

Anonymous — Thu, 26 Oct 2017 05:12:07 GMT

that i knew. it doesn't change the way how autocad round numbers, it only gives limits. Rounding is still as regular: <0.5 down; and >=0.5 up.

Re: rounding to nearest floor.

Anonymous — Thu, 26 Oct 2017 07:27:10 GMT

I can't found the Round down method anywhere.

So I tried to make lisp code.

(defun C:DIMROUNDDOWN (/)

(defun rounddown ( n m )
    ((lambda ( r ) (cond ((equal 0.0 r 1e-8) n) ((< n 0) (- n r m)) ((- n r)))) (rem n m))
)


(setvar "DIMASSOC" 2)
(setq m (getreal "\n Round off value : "))                   ;; Set round off
(setq p1 (getpoint "\n Specify First extension line : "))    ;; First Dim position
(setq p2 (getpoint "\n Specify Second extension line : "))   ;; Second Dim Position
(setq p3 (getpoint "\n Specify Third extension line : "))    ;; Dim Text position
(setq dist (distance p1 p2))
  
(command "DIMLINEAR" p1 p2 p3 dist)
(command ".explode" (entlast))
(setq ed (entget (entlast)))
(setq n (atof (cdr (assoc 1 ed))))

(setq res (rounddown n m))
(setq ed (subst (cons 1 (rtos res)) (assoc 1 ed) ed))
(entmod ed)
)

When it prompts, Set round off value.

Then set dimension coordinate.

Finally, Just one click, You can get Rounddown value.

But It is only for DIMLINEAR command.

If you want another dimension type, It needs to fix

Feel free Point out my Lisp code, please.

Re: rounding to nearest floor.

Kent1Cooper — Thu, 26 Oct 2017 17:47:49 GMT

In addition to allowing for different varieties of Dimensions [all the length-oriented kinds, not the angular kinds], the following works by imposing a text override on the Dimension, rather than Exploding it and modifying the resulting Text object. [Besides, in Radius and Diameter Dimensions, which one presumably might also want to do this with, when you Explode, (entlast) is not the Text, but the arrowhead, so the approach would need to be different.] So the Dimension remains one thing, though bear in mind that the text content will not update with Stretching, etc.

One thing that's much simpler is the rounding down part, because the measured distance of a Dimension is never negative, eliminating that possibility in your rounding-down subroutine.

It asks what kind of Dimension so that angular ones are not allowed. It would be nice if the generic-sounding DIM command included all the various possibilities so you could just start that and check whether whichever type was drawn is not angular, but linearly DIM seems to do only the Aligned variety.

It uses whatever the current Units mode and precision settings are for the text override [as does yours], regardless of what the current Dimension Style uses. And it doesn't include the preceding diameter symbol or R for Diameter/Radius Dimensions. But those shortcomings could be overcome if needed.

(defun C:DIMRD ; = Dimension and Round text value Down
  (/ floor dtype dobj)
  (if (= (getvar 'dimassoc) 0) (setvar 'dimassoc 2)); [assuming 1 can be left alone]
  (setq floor (getreal "\nRound value Down to the nearest multiple of: "))
  (initget "Linear Horizontal Vertical Aligned ROtated RAdius Diameter")
  (setq dtype (getkword "\nType of Dimension [Linear/Horizontal/Vertical/Aligned/ROtated/RAdius/Diameter]: "))
  (command (strcat "_.DIM" dtype)); start command
  (while (> (getvar 'cmdactive) 0) (command pause)); wait for completion
  (setq dobj (vlax-ename->vla-object (entlast)))
  (vla-put-TextOverride dobj (rtos (* floor (fix (/ (vla-get-Measurement dobj) floor)))))
  (princ)
); defun

Re: rounding to nearest floor.

Anonymous — Thu, 26 Oct 2017 19:00:47 GMT

Thank you, @Kent1Cooper

I need to study more Visual lisp...

I think that vlisp has the excellent function.