topic Re: LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION in AutoCAD Forum

LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

Jgmargarito26 — Wed, 10 Apr 2019 11:15:59 GMT

COULD I GET SOME HELP, ON CREATING A LISP WERE INSTEAD OF PICKING CENTER POINT TO CENTERPOINT, YOU COULD BE ABLE TO SELECT A CIRCLE TO CIRCLE AND IT GIVES YOU A DISTANCE ON YOUR COMMAND BAR OR IN A DIM STYLE.

LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

Jgmargarito26 — Wed, 10 Apr 2019 11:15:52 GMT

Re: LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

imadHabash — Wed, 10 Apr 2019 12:04:41 GMT

Hi,

Try QDIM command .

Re: LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

Jgmargarito26 — Wed, 10 Apr 2019 12:08:51 GMT

THAT ITS GOOD, BUT IT CREATES A DIMENSION I WAS HOPING FOR SOMETHING WERE IT TELLS YOU IN THE COMMAND BAR, WE DEAL WITH A HIGH VOLUME OF WORK SO SOMETHING FAST WITH OUT ME GOING BACK AND DELETING.

Re: LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

Moshe-A — Wed, 10 Apr 2019 12:28:51 GMT

@Jgmargarito26 hi,

here you are but untested

enjoy

moshe

(defun c:cdist ( / ss elist0 elist1 c0 c1)
 (if (setq ss (ssget '((0 . "circle"))))
  (cond
   ((/= (sslength ss) 2)
    (prompt "\nerror: select only two circles.")
   ); case
   ( t
    (setq elist0 (entget (ssname ss 0)) elist1 (entget (ssname ss 1)))
    (setq c0 (cdr (assoc '10 elist0)) c1 (cdr (assoc '10 elist1)))
    (princ (strcat "\nDistance= " (rtos (distance c0 c1))))
   ); case
  ); cond
 (princ)
)

Re: LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

Kent1Cooper — Wed, 10 Apr 2019 12:38:26 GMT

The Customization Forum is the better place to request something like this, but quickly and in simplest terms [and untested]:

(defun C:C2CD (/ c1 c2); = Circle-{to}-Circle Distance
  (setq
    c1 (car (entsel "\nSelect a Circle: "))
    c2 (car (entsel "\nSelect another Circle: "))
  ); setq
  (prompt
    (strcat
      "\nDistance between Circle centers is "
      (rtos ; [in current Units mode/precision settings]
        (distance
          (cdr (assoc 10 (entget c1)))
          (cdr (assoc 10 (entget c2)))
        ); distance
      ); rtos
      "."
    ); strcat
  ); prompt
); defun

It could be made to verify that you actually picked two Circles, and not the same one twice, and could make different use of the information, etc., etc.

Re: LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

Jgmargarito26 — Wed, 10 Apr 2019 12:35:07 GMT

NO LUCK

Re: LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

Jgmargarito26 — Wed, 10 Apr 2019 12:38:51 GMT

HEY THIS IS EXACTLY WHAT I WAS LOOKING FOR, IS THERE A WAY FOR IT SELECT MULTIPLE INSTEAD OF CHOSSING ONE CIRCLE AT A TIME? I KNOW IAM ASKING FOR TO MUCH

Re: LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

Kent1Cooper — Wed, 10 Apr 2019 12:50:25 GMT

@Jgmargarito26 wrote:

.... IS THERE A WAY FOR IT SELECT MULTIPLE INSTEAD OF CHOSSING ONE CIRCLE AT A TIME? ....

I'm not sure I see the advantage in that. You'd still need to make at least two picks, to define a window, or at best a pick-and-hold and a release using Lasso selection. What if the selection contains more than two Circles? What should it do then?

Re: LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

Jgmargarito26 — Wed, 10 Apr 2019 12:49:57 GMT

WHEN I MEANT MULTIPLE I MEAN JUST 2 CIRCLES.

Re: LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

Moshe-A — Wed, 10 Apr 2019 13:03:39 GMT

you are right, here's a fix

(defun c:cdist ( / ss elist0 elist1 c0 c1)
 (if (setq ss (ssget '((0 . "circle"))))
  (cond
   ((/= (sslength ss) 2)
    (prompt "\nerror: select only two circles.")
   ); case
   ( t
    (setq elist0 (entget (ssname ss 0)) elist1 (entget (ssname ss 1)))
    (setq c0 (cdr (assoc '10 elist0)) c1 (cdr (assoc '10 elist1)))
    (princ (strcat "\nDistance= " (rtos (distance c0 c1))))
   ); case
  ); cond
 ); if
 (princ)
)

Re: LISP FOR DISTANCE BETWEEN 2 CIRCLE SELECTION

Kent1Cooper — Wed, 10 Apr 2019 13:12:32 GMT

@Jgmargarito26 wrote:

WHEN I MEANT MULTIPLE I MEAN JUST 2 CIRCLES.

Well, you can do this, to have it keep asking until you pick two and only two Circles:

(defun C:C2CD (/ ss); = Circle-{to}-Circle Distance
  (prompt "\nFor the distance betwen two Circle centers,")
  (while
    (not
      (and
        (setq ss (ssget '((0 . "CIRCLE"))))
        (= (sslength ss) 2)
      ); and
    ); not
    (prompt "\nMust select 2 and only 2 Circles.")
  ); while
  (prompt
    (strcat
      "\nDistance between Circle centers is "
      (rtos ; [in current Units mode/precision settings]
        (distance
          (cdr (assoc 10 (entget (ssname ss 0))))
          (cdr (assoc 10 (entget (ssname ss 1))))
        ); distance
      ); rtos
      "."
    ); strcat
  ); prompt
  (princ)
); defun

But that seems a disadvantage to me, in terms of selection steps. Not only do you still need at least two picks or a pick-and-hold-and-release to make the selection, but you also need to Enter to complete the selection. For me, I'd rather use just two picks as in my first suggestion.