topic Re: Simple list of layer contents in AutoCAD Forum

Simple list of layer contents

Netelaana — Wed, 03 Jun 2020 19:36:20 GMT

Can't seem to find any other threads on the topic - if I missed it, please point me in the right direction.

I have an ambiguously named layer with contents spread (presumably) throughout a drawing in various blocks (hundreds), modelspace, and paperspace (dozens of layouts). I would like to find out what is actually on that layer.

Is there a way to get a simple list of the contents of any given layer? something like a pared down dblist but just for a single layer? most helpful would be a list that looks like:

ObjectID1 - ObjectType1 - ObjectLocation1(model or layout XXX or block XXX)-ObjectXCoord1-ObjectYCoord1

ObjectID2 - ObjectType1 - ObjectLocation2(model or layout XXX or block XXX)-ObjectXCoord2-ObjectYCoord2

etc...

even more helpful would be a way to zoom to each object...

does anything along this vein exist?

thanks in advance!

Re: Simple list of layer contents

ВeekeeCZ — Wed, 03 Jun 2020 21:32:07 GMT

If you have acad 2020+ then you can try the upgraded PURGE command. Newly there is the "Non-Purgeable" tab... with list of objects... even a zoom button is there. Seems like made just for you.

Re: Simple list of layer contents

Netelaana — Thu, 04 Jun 2020 00:12:06 GMT

Sorry , forgot to include that pertinent info - I am running AutoCAD 2018 - no bells or whistles. That does look pretty much like what I am looking for though.

Any workarounds,lisp, or other options for 2018?

Re: Simple list of layer contents

imadHabash — Thu, 04 Jun 2020 03:44:51 GMT

Hi,

for selecting same layer objects you can try LAYISO , QSELECT , SELECTSIMILAR and LAYWALK commands .

Re: Simple list of layer contents

Netelaana — Thu, 04 Jun 2020 12:58:58 GMT

Yes, I am aware of those tools, however they are severely limiting in my case since they do not look inside blocks or layouts (unless you are in one, and then it does not vet the rest of the drawing). As mentioned, there are hundreds of blocks and dozens of layouts that would need to individually be opened and vetted.

dblist gives me the information, but only piecemeal and gives it for every object in the entire drawing (ie a verbose dblist filtered for a single layer would do the trick)

dataextraction sort of works, but is quite the process, and then I need to fiddle with the spreadsheet to get my list. it seems that it would be rather straightforward to have a lisp that runs through the objects in the drawing and spits out the information limited to just the layer of interest - it is way beyond the limits of my coding skills though.

Re: Simple list of layer contents

ВeekeeCZ — Thu, 04 Jun 2020 16:20:23 GMT

Not really sure if this helps, but it was easy enought.. so here you go.

(vl-load-com)

(defun c:LayerObjects ( / l c i s e d)
  
  (setq l (getstring "\nLayer name <current>: "))
  (setq c 1000
	i -1)
  
  (if (= l "") (setq l (getvar 'clayer)))
  (or (tblsearch "LAYER" l)
      (prompt "\nError: There is no '" l "' layer in the drawing.")
      (exit))
  
  (if (setq s (ssget "_X" (list (cons 8 l))))
    (repeat (sslength s)
      (setq e (ssname s (setq i (1+ i))))
      (setq d (entget e))
      (princ (strcat "\n"
		     (itoa (setq c (1+ c))) ": " (cdr (assoc 5 d))
		     " - " (strcase (cdr (assoc 0 d)))
		     (if (= (cdr (assoc 0 d)) "INSERT")
		       (strcat ":" (if (vlax-property-available-p (setq o (vlax-ename->vla-object e)) 'EffectiveName)
				     (vla-get-EffectiveName o)
				     (vla-get-Name o)))
		       "")
		     " - Layout: " (cdr (assoc 410 d))
		     " - " (cond ((vl-princ-to-string (cdr (assoc 10 d)))) (""))))))
  
  (vlax-for b (vla-get-Blocks (vla-get-activeDocument (vlax-get-acad-object)))
    (and (= 0 (vlax-get b 'islayout))
	 (= 0 (vlax-get b 'isxref))
	 (/= "AcDbBlockReference" (vlax-get b 'ObjectName))
	 (vlax-for o b
	   (if (= l (vlax-get o 'Layer))
	     (princ (strcat "\n"
			    (itoa (setq c (1+ c))) ": " (vlax-get o 'Handle)
			    " - " (strcase (substr (vlax-get o 'ObjectName) 5))
			    (if (= (vlax-get o 'ObjectName) "AcDbBlockReference")
			      (strcat ": " (if (vlax-property-available-p o 'EffectiveName)
					     (vla-get-EffectiveName o)
					     (vla-get-Name o)))
			      "")
			    " - " (strcat "InBlock: " (vla-get-Name b))))))))
  (princ)
  )

Re: Simple list of layer contents

RobDraw — Thu, 04 Jun 2020 16:21:09 GMT

Isolate the layer, select everything visible, and LIST?

Re: Simple list of layer contents

Netelaana — Thu, 04 Jun 2020 17:31:45 GMT

@ВeekeeCZ wrote:

Not really sure if this helps, but it was easy enough.. so here you go.

(vl-load-com)

(defun c:LayerObjects ( / l c i s e d)
  
  (setq l (getstring "\nLayer name <current>: "))
  (setq c 1000
	i -1)
  
  (if (= l "") (setq l (getvar 'clayer)))
  (or (tblsearch "LAYER" l)
      (prompt "\nError: There is no '" l "' layer in the drawing.")
      (exit))
  
  (if (setq s (ssget "_X" (list (cons 8 l))))
    (repeat (sslength s)
      (setq e (ssname s (setq i (1+ i))))
      (setq d (entget e))
      (princ (strcat "\n"
		     (itoa (setq c (1+ c))) ": " (cdr (assoc 5 d))
		     " - " (strcase (cdr (assoc 0 d)))
		     (if (= (cdr (assoc 0 d)) "INSERT")
		       (strcat ":" (if (vlax-property-available-p (setq o (vlax-ename->vla-object e)) 'EffectiveName)
				     (vla-get-EffectiveName o)
				     (vla-get-Name o)))
		       "")
		     " - Layout: " (cdr (assoc 410 d))
		     " - " (cond ((vl-princ-to-string (cdr (assoc 10 d)))) (""))))))
  
  (vlax-for b (vla-get-Blocks (vla-get-activeDocument (vlax-get-acad-object)))
    (and (= 0 (vlax-get b 'islayout))
	 (= 0 (vlax-get b 'isxref))
	 (/= "AcDbBlockReference" (vlax-get b 'ObjectName))
	 (vlax-for o b
	   (if (= l (vlax-get o 'Layer))
	     (princ (strcat "\n"
			    (itoa (setq c (1+ c))) ": " (vlax-get o 'Handle)
			    " - " (strcase (substr (vlax-get o 'ObjectName) 5))
			    (if (= (vlax-get o 'ObjectName) "AcDbBlockReference")
			      (strcat ": " (if (vlax-property-available-p o 'EffectiveName)
					     (vla-get-EffectiveName o)
					     (vla-get-Name o)))
			      "")
			    " - " (strcat "InBlock: " (vla-get-Name b))))))))
  (princ)
  )

Simple maybe (its more than I could have cobbled together)- but nailed it. Thanks!!!

I might never have found the couple random mleaders someone stuck on this layer buried in a block - with this it took about two seconds....