How can I assign position controllers for knots to spline in spline using 4 loo

Anonymous — Fri, 03 Aug 2018 07:28:51 GMT

--Hello,
--I was wondering if someone could give me some advice on how to simplify the last section of this script.
--the script creates a spline with all the knots positioned at the first array value. Later they will be animated by moving the point helpers.
--The challenge is setting up the controllers for the knots. This example works but I need to simplify the last part to handle possibilty of greater than 4 values in the array.
--Does anyone have suggestions? The way I have it now uses $ScanTail_Helper_?? and is done knot by knot. I was hoping to do that part in a loop. Ideas? You can select my whole post and try it if you want. You move the pointer to move the spline. problem is optimizing to handle large number of items that could end up in the array. Thanks
--
resetMaxFile #noPrompt

myarray = #([0,0,20],[20,0,20],[40,0,20],[60,0,20]) --total number of items in array varies. I use 4 items for testing

----------------------------------------------------Create what I call a Scan Box which outlines the VMC FOV intecept on the planets Mars Surface surface.
ScanTail = splineShape name:"ScanTail_Spline"
addnewSpline ScanTail
------------------------------------------------------------------------------------------------------------------------------------------
m = 0
for m in 1 to myarray.count do
(
addknot ScanTail 1 #smooth #curve myarray[1] ---creates a bunch of knots on spline based on the total number of values in array and place all of them at the 1st value in the array
)
updateShape ScanTail
animateVertex ScanTail #all

u = (myarray.count * 3) --total number of values in the array * 3 gives you the total number of X,Y Z point controllers you need to make in this loop
for m = 2 to u by 3 do
(
ScanTail[#Object__Editable_Spline][#Master][m].controller = Point3_XYZ()
)
-----------------------------------------------------------------------------------------------SECTION BELOW NEED TO SIMPLIFY
-----------Create Point Helpers for all knots on the spline
for s in 1 to myarray.count do
(
nm = "ScanTail_Helper_" + s as string
PointHelperObj name:nm pos:[0,0,0] size:258 centermarker:true axistripod:false cross:false box:false drawnontop:true axisLength:4000 constantscreensize:false
)

--------------------------------This section works but is limited to 4 helpers. I need to simplify it
(
for i = 1 to 3 by 1 do (ScanTail[#Object__Editable_Spline][#Master][2].controller[i].controller = $ScanTail_Helper_1.position.controller[i].controller)
--------------------------------------------------------------------------------------
for i = 1 to 3 by 1 do (ScanTail[#Object__Editable_Spline][#Master][5].controller[i].controller = $ScanTail_Helper_2.position.controller[i].controller)
--------------------------------------------------------------------------------------
for i = 1 to 3 by 1 do (ScanTail[#Object__Editable_Spline][#Master][8].controller[i].controller = $ScanTail_Helper_3.position.controller[i].controller)
-------------------------------------------------------------------------------------
for i = 1 to 3 by 1 do (ScanTail[#Object__Editable_Spline][#Master][11].controller[i].controller = $ScanTail_Helper_4.position.controller[i].controller)
)

-------------------------------------------------------------------------------------------THIS ATTEMPT AT SIMPLIFYING FAILS I need something where the ????? is but dont know what.
-- for j = 2 to u by 3 do
-- (
--
-- for w = 1 to 3 by 1 do (ScanTail[#Object__Editable_Spline][#Master][j].controller[w].controller = ?????.position.controller[w].controller)
-- )

Re: How can I assign position controllers for knots to spline in spline using 4

blakestone — Mon, 06 Aug 2018 03:14:49 GMT

Is something like this what you're after?

(
	resetMaxFile #noPrompt
	
	local myarray = #([0,0,20],[20,0,20],[40,0,20],[60,0,20])
	local inc = for i=2 to (myarray.count * 3) by 3 collect i
	
-- Spline
	local ScanTail = splineShape name:(uniqueName "ScanTail_Spline")
	
	addNewSpline ScanTail
	
	for i in myarray do addknot ScanTail 1 #smooth #curve i
		
	updateShape ScanTail
	animateVertex ScanTail #all

-- Controller Helpers
	local nm = for i in myarray collect PointHelperObj name:(uniqueName "ScanTail_Helper_") pos:i size:258 centermarker:true axistripod:false cross:false box:false drawnontop:true axisLength:4000 constantscreensize:false
	
	for n=1 to nm.count do (
		ScanTail[#Object__Editable_Spline][#Master][inc[n]].controller = Point3_XYZ()
		for i=1 to 3 do ScanTail[#Object__Editable_Spline][#Master][inc[n]].controller[i].controller = nm[n].position.controller[i].controller
	)
	
	forceCompleteRedraw()
)

Re: How can I assign position controllers for knots to spline in spline using 4

Anonymous — Tue, 07 Aug 2018 04:41:07 GMT

Thank you. I found a way to do it on my own that is very similar to yours and your works to so thanks again!

Re: How can I assign position controllers for knots to spline in spline using 4

blakestone — Tue, 07 Aug 2018 05:27:37 GMT

No problem, well done for finding the solution yourself!

topic Re: How can I assign position controllers for knots to spline in spline using 4 in 3ds Max Programming Forum

How can I assign position controllers for knots to spline in spline using 4 loo

Re: How can I assign position controllers for knots to spline in spline using 4

Re: How can I assign position controllers for knots to spline in spline using 4

Re: How can I assign position controllers for knots to spline in spline using 4