topic Re: Get all Material/texture nodes connected to certain Material or Texture in 3ds Max Programming Forum

Get all Material/texture nodes connected to certain Material or Texture

denisVFX — Wed, 23 Feb 2022 12:29:21 GMT

I need a solution to get all material/texture nodes connected to the Output of certain Texture or Material.

Material class has methods getSubMtl and getSubTexmap which returns all materials and textured connected to material. But I wonder why it don't have a method for getting output connections.

For example I have a Bitmaptexture which is connected to diffuse slot of material1 and diffuse slot of material2. How I can get this material objects?..

Re: Get all Material/texture nodes connected to certain Material or Texture

Swordslayer — Wed, 23 Feb 2022 13:22:22 GMT

You can get dependents of the map, and filter them based on your criteria. For example, if map is the texture:

dependentMaterials = for r in refs.dependents map where isKindOf r Material and not isKindOf r TextureMap collect r

Re: Get all Material/texture nodes connected to certain Material or Texture

denisVFX — Wed, 23 Feb 2022 13:56:52 GMT

Thank you for a quick reply.

It works but collets all the nodes which are higher in hierarchy. But I need only nodes which are connected to this texture (or material)

map = meditMaterials[1].map2.texmap_diffuse dependentMaterials = for r in refs.dependents map where isKindOf r Material or isKindOf r TextureMap collect r for i in dependentMaterials do ( print i.name )

kerosene_lamp_body_Diffuse_map:Bitmap #(kerosene_lamp_body_metallic_mat:VRayMtl, kerosene_lamp_body_mat:Blend, kerosene_lamp_body_dielectric_mat:VRayMtl)

2 vraymaterials and 1 blend material are in dependentMaterials , but Diffuse bitmap texture isn't connected to blend material....

is there any way to filter refs.dependents result so it will return only nodes which has direct connection the node?...

Re: Get all Material/texture nodes connected to certain Material or Texture

Swordslayer — Wed, 23 Feb 2022 14:31:04 GMT

Then you use getSubTexmap:

fn isSubTexmap m ref is:false = ( for i = 1 to getNumSubTexmaps m where getSubTexmap m i == ref do is = true return is ) dependentMaterials = for r in refs.dependents map where isKindOf r Material and isSubTexmap r map collect r

Re: Get all Material/texture nodes connected to certain Material or Texture

denisVFX — Wed, 23 Feb 2022 14:49:05 GMT

Thank you! It works excellent!

But I if there any easy and elegant way to find to which texture slot output connection is connected? (is it diffuse map, or reflection, or maybe it's connected to mix texture map color 1... )

Re: Get all Material/texture nodes connected to certain Material or Texture

Swordslayer — Wed, 23 Feb 2022 15:01:35 GMT

Since it's going through all the slots anyway, it's easy to save the slotname in the same pass...

fn isSubTexmap m ref &slotName is:false = ( for i = 1 to getNumSubTexmaps m where getSubTexmap m i == ref do (slotName = getSubTexmapSlotName m i; is = true) return is ) dependentMaterials = for r in refs.dependents map where isKindOf r Material and isSubTexmap r map &slotName collect dataPair val:r slot:slotName

Re: Get all Material/texture nodes connected to certain Material or Texture

denisT.MaxDoctor — Wed, 23 Feb 2022 19:14:15 GMT

since this task does not require a real-time solution and is not particularly time-critical, I would go the other way:

fn getTextureMapDirectConnections map = ( cls = classof map tvps = getclassinstances cls astrackviewpick:on cc = for tvp in tvps where tvp.anim == map collect tvp ) tt = getTextureMapDirectConnections map -- where tt is a list of trackviewpicks... see MXS help for details:

TrackViewPick : Value
Instances of the TrackViewPick class store the result of a selection from the Track View Pick dialog.

A TrackViewPick value has the following properties:

<trackViewPick>.name : string

The name of the picked item as shown in the Track View Pick dialog.
<trackViewPick>.anim : subAnim

The subAnim for the item the user picked.
<trackViewPick>.client : MAXWrapper

The owner of the subAnim for the item the user picked. If the owner is a subclass of MAXWrapper, the MAXWrapper value for the owner is returned, otherwise a value of undefined is returned.
<trackViewPick>.subNum : integer

The subAnim index for anim in client.

Of course, we can always filter the list by client class or subAmin name (property).