topic Re: nested rollout questions (2) in 3ds Max Programming Forum

nested rollout questions (2)

bhnh — Mon, 21 Jan 2008 04:06:32 GMT

I've run into a couple questions concerning rollouts...

Question 1. Here's a short test script for a utility:


utility test3 "Test3"
(
local v
rollout r1 "panel A"
(    
    spinner spn_r1 "spinner 1 "
    on spn_r1 changed value do
    (v = spn_r1.value)
)

rollout r2 "panel B"
(
    spinner spn_r2 "spinner 2 "
    on spn_r2 changed value do
    (spn_r2.value = v)
)


    on test3 open do
    (
        addRollout r1
        addRollout r2
    )
    
    on test3 close do
    (
        removeRollout r1
        removeRollout r2
    )
)

My question is on the attached .gif... basically, how do I get the rollouts "grouped" within the utility?

Question 2: Can rollouts be nested within another rollout? I guess a better way of phrasing that is, can a variable be assigned locally on the RolloutFloater level such that it will be read by added rollouts? Here's what I'm getting at...


rollout one "One"
(
    button btn_1 "First Button"

)
rollout two "Two"
(
    button btn_2 "Second Button"
)

rf = newRolloutFloater "Floater" 200 300
(button btn_f "Floater Button")
addRollout one rf
addRollout two rf

In the above I tried to add a "Floater" button on the floater level, to be followed the two rollouts. When I run it, there's no button on the floater level.

Many thanks in advance.

Re: nested rollout questions (2)

Anonymous — Mon, 21 Jan 2008 04:48:40 GMT

I haven't tried it yet but look at subRollout in the Reference. It might be what you're looking for.

Re: nested rollout questions (2)

bhnh — Mon, 21 Jan 2008 05:12:47 GMT

Bless ya, Pat. That's just what I was looking for in regards to the rollouts within rollouts. Many thanks! 🙂

Still a bit in mystified about the utility.

Re: nested rollout questions (2)

Anonymous — Mon, 21 Jan 2008 07:11:56 GMT

From my answer on CGTalk:

"The scripted Utility was introduced back in Max 2 and became obsolete around Max 3. It was the way it worked, with the additional rollouts placed behind the main body of the Utility that had the Close button added automatically. I know the Help still shows you how to use it and it is rather simple to script so it is a good starter material, but don't expect too much control over formatting from it, as it was part of the "first baby steps" of MAXScript and is barely used nowadays."

Re: nested rollout questions (2)

bhnh — Mon, 21 Jan 2008 08:37:26 GMT

Many thanks, Bobo... particularly because you answered this as well over at CGT. I'm repeating my CGT reply here for anyone who's following this in the Area rather than CGT.

@Caprier, et.al.
I've been playing with the subRollouts since the first post in this thread. I'm stymied by whether a variable local to the parent rollout can be referenced in the subrollouts. Here's an example I pulled whole-hog from the MAXScript Reference and threw in a local and global variable:


rollout test "test" height:200
( 
-- here I added a local and a global variable
local L = 25.0
global G = 37.0
--
subrollout test1 "test1"
subrollout test2 "test2"
)
rollout test1a "test1a"
( spinner test1as "test1as"
-- the following throws an "undefined to type:Float" error
on test1as changed value do
(test1as.value = L)
--
)
rollout test1b "test1b"
( spinner test1bs "test1bs"
-- this works; the spinner displays the global value
on test1bs changed value do
(test1bs.value = G)
)
createdialog test
AddSubRollout test.test1 test1a
AddSubRollout test.test1 test1b
test.test1.height += 100
test.test2.pos += 
rollout test2a "test2a"
( spinner test2as "test2as"
)
AddSubRollout test.test2 test2a
test.test2.height += 50

The question is, is it possible to access a variable from the parent rollout? I'm thinking of, for instance, of Array elements. When I tried this in the (antiquated) Utilities format, both parent-local and global were identified. Many thanks!

Re: nested rollout questions (2)

Anonymous — Mon, 21 Jan 2008 12:42:10 GMT

It is indeed possible.
Remember that Scopes are like Onions (if I may quote Shrek+Donkey) - they have many layers, and any local variable declared in the higher scope is visible in the lower scopes. In your example though, you have declared a multitude of rollouts (where each rollout defines its own local scope) WITHIN the GLOBAL scope of MAXScript, so the L variable exists only locally in rollout test but not in the other rollouts.

The correct way to do this would be

(--open top-level local scope

local L = 25.0 --declare a local variable higher than all rollouts

rollout test "test" 
( 
subrollout test1 "test1" height:50
subrollout test2 "test2" height:50
)

rollout test1a "test1a"
( 
spinner test1as "test1as"
on test1as changed value do (test1as.value = L) --L is visible because declared in a higher scope
)

createdialog test
AddSubRollout test.test1 test1a

)--close top-level local scope

Re: nested rollout questions (2)

bhnh — Mon, 21 Jan 2008 19:26:17 GMT

Thank you immensely, Bobo. I realize this was something of a "ground-level" question.

Re: nested rollout questions (2)

bhnh — Mon, 21 Jan 2008 23:08:01 GMT

Just as a follow-up (that top-level local scope works a charm!) I'm finding that, at least to my taste, placing the rollouts in a floater works better visually than the subrollouts. Here's a mini-routine:


(
local m
rollout setm "Set Value"
(
    spinner spn_set "Set m " range:
    spinner spn_show "m = "
    on spn_set changed value do
    (m = spn_set.value)
    on spn_show changed value do
    (
        spn_show.value = m
        spn_set.value = spn_show.value
    )    
    
)

rollout setm2 "Set Value by Slider"
(
    slider sld_set "Set m" range:
    on sld_set changed value do
    (m = sld_set.value)
)
nf = newRolloutFloater "m Value" 200 170
addRollout setm nf
addRollout setm2 nf
)

With the floater, when one rollout is rolled up the other rollouts will "tighten up" the spacing, whereas a subRollout will claim a fixed amount of space whether it's rolled up or not.