topic Assign random vertex color per element in 3ds Max Programming Forum

Assign random vertex color per element

Anonymous — Sat, 03 Jun 2017 22:35:08 GMT

Hi, im using substance painter a lot and i have to assign to my objects random vertex colors to each element to make selections. Is there any script to do this automatically? ty

ps. if there is someone using substance too and knows other way of passing selections into substance im all ears 🙂

Re: Assign random vertex color per element

Swordslayer — Sun, 04 Jun 2017 06:05:16 GMT

If random vertex color per element is enough (which may or may not result in duplicates, changing seed might help sometimes), you can use dataChannel modifier for that:

Re: Assign random vertex color per element

Swordslayer — Sun, 04 Jun 2017 07:00:43 GMT

And as a script that ensures unique colors:

fn shuffle arr =
    for counter = arr.count to 1 by -1 collect
    (
        local swapIndex = random 1 counter
        swap arr[random 1 counter] arr[counter]
    )

fn incrementCounters &r &g &b step =
    if (b += step) > 256 do
    (
        b = 1
        if (g += step) > 256 do
        (
            g = 1
            if (r += step) > 256 do r = 1
        )
    )

fn getElements mesh =
(
    local vertCount = mesh.numVerts
    local faces = mesh.faces as bitArray
    local facesByVert = for v = 1 to vertCount collect #()

    for face in faces do
    (
        local faceVerts = getFace mesh face
        append facesByVert[faceVerts[1]] face
        append facesByVert[faceVerts[2]] face
        append facesByVert[faceVerts[3]] face
    )

    for face in faces collect
    (
        local i = 0, element = #(face), elementVerts = #()

        while (local f = element[i += 1]) != undefined do if faces[f] do
        (
            faces[f] = false
            local faceVerts = getFace mesh f

            for v = 1 to 3 do facesByVert[faceVerts[v]] = 
                for vertFace in facesByVert[faceVerts[v]] where faces[vertFace] collect
                (
                    append element vertFace
                    append elementVerts (int faceVerts[v])
                    dontCollect
                )
        )
        elementVerts as bitarray
    )
)

fn assignUniqueElementColor obj op shuffleElements:off =
(
    local elements = getElements (snapshotAsMesh obj)
    local stepCount = elements.count^(double 1/3) + 1
    local step = 255./stepCount
    local redArr = shuffle (#(0) + #{1..255})
    local greenArr = shuffle (#(0) + #{1..255})
    local blueArr = shuffle (#(0) + #{1..255})
    local r = 1, g = 1, b = 1
    
    if shuffleElements do
      elements = shuffle elements

    for element in elements do
    (
        op.setVertColor obj 0 element [redArr[int r], greenArr[int g], blueArr[int b]]
        incrementCounters &r &g &b step
    )
)

if isKindOf $ Editable_Mesh then assignUniqueElementColor $ meshop shuffleElements:on
else if isKindOf $ Editable_Poly do assignUniqueElementColor $ polyop shuffleElements:on

If you instead want to bind it to a shortcut, you can save it as a .ms file and use the macroscript creator to make a macro for it.

Re: Assign random vertex color per element

Anonymous — Sun, 04 Jun 2017 08:55:58 GMT

Thanks again, exactly what i needed 🙂

Re: Assign random vertex color per element

Anonymous — Sun, 04 Jun 2017 12:48:22 GMT

One more q: this script is independent to data channel modifier and cant be used in previous max versions? thanks again

Re: Assign random vertex color per element

Swordslayer — Sun, 04 Jun 2017 19:53:42 GMT

Yes, it works with any editable mesh / editable poly that's currently selected and should work across most of the old max version, more than a decade back at the very least.

Re: Assign random vertex color per element

Jixal — Thu, 21 May 2020 03:14:42 GMT

Hey, this is super cool.

Is it possible to do the same but apply to all objects instead of just elements?

For example, I have 9 objects that will be textured in Substance Painter and I want a random vertex color for each object (to use as an ID mask).

Re: Assign random vertex color per element

Swordslayer — Fri, 22 May 2020 07:18:41 GMT

@Jixal wrote:

I have 9 objects that will be textured in Substance Painter and I want a random vertex color for each object (to use as an ID mask).

Something like

fn smootherStep x = x * x * x * (x * (x * 6 - 15) + 10) fn shuffle arr = for counter = arr.count to 1 by -1 collect ( local swapIndex = random 1 counter swap arr[random 1 counter] arr[counter] ) fn assignUniqueVertexColor objs shuffleItems:off seed:0 = ( local maxVal = 256^3 - 1d0 local maxCount = objs.count local counter = 0d0 if shuffleItems and ::seed seed == OK do objs = shuffle objs for obj in objs do ( local clr = smootherStep (counter / maxCount) * maxVal if isKindOf obj Editable_Poly do polyOp.setVertColor obj 0 #all [bit.shift (bit.and clr 0xff0000) -16, bit.shift (bit.and clr 0x00ff00) -8, bit.and clr 0x0000ff] counter += 1 ) ) assignUniqueVertexColor (getCurrentSelection())

Re: Assign random vertex color per element

denisT.MaxDoctor — Fri, 22 May 2020 07:40:34 GMT

::seed seed

I like it 🙂

Re: Assign random vertex color per element

Jixal — Tue, 02 Jun 2020 00:03:54 GMT

Thanks 😃

Re: Assign random vertex color per element

Anonymous — Tue, 21 Jul 2020 15:36:18 GMT

Hi,

I tried to use data channel for vertex color element, but it seems that it kills uv map channel...

Your script run fine. Thanks

Re: Assign random vertex color per element

Jixal — Tue, 21 Jul 2020 23:30:30 GMT

Hi all,

Joker Martini just released a really nice script that does everything that we want for vertex colouring objects and elements- https://jokermartini.com/product/vertex-color-editor/

Lightweight, simple and slick. Love it.

Re: Assign random vertex color per element

alnoman.7cgi — Fri, 10 Mar 2023 05:21:25 GMT

Hello,
This is very useful. thanks for the effort!
could it be easy to convert wirecolor to vertex color for all objects or selected objects?

Thanks.