topic Re: Get face(poly) by face(mesh) in Maxscript in 3ds Max Programming Forum

Get face(poly) by face(mesh) in Maxscript

Anonymous — Fri, 17 Nov 2017 08:10:17 GMT

Hi there,

I'm having some trouble finding an elegant solution to what IMO should be a simple problem. I'm trying to find what face a face belongs to. The first face being a poly face (polygon), the second being mesh face (triangle). I guess I could lookup which of it's edges is invisible, find that edge in poly and see what polygon uses it, but it seems to me, there must be more straight forward solution to this. Given the fact that some operations returns mesh face even on editable poly, I assume this is a common problem.

Re: Get face(poly) by face(mesh) in Maxscript

Swordslayer — Fri, 17 Nov 2017 14:38:25 GMT

Depends, most of the time, you can get the matching poly by the three verts of the face, but there are cases where it will return two different results. If you plan on doing multiple such lookups per one mesh/poly, it's better to make a lookup table to give you the poly index at face index:

fn getFacePolyTable obj =
(
	local index = 0
	local polyByFace = #()
	for poly = 1 to polyop.getNumFaces obj do
	(
		local numTris = polyop.getFaceDeg obj poly - 2
		for face = index + 1 to index + numTris do polyByFace[face] = poly
		index += numTris
	)
	return polyByFace
)

Re: Get face(poly) by face(mesh) in Maxscript

Anonymous — Fri, 17 Nov 2017 15:14:18 GMT

Hi Swordslayer,

thanks for the answer. Yeah, getting more than one result is surely a problem. The lookup table should work better, but I've actually found out, that once you convert from mesh to poly it converts the selection. Since I won't be working on highpoly meshes with the tool I'm making, it's a good enough solution for me.

Re: Get face(poly) by face(mesh) in Maxscript

denisT.MaxDoctor — Fri, 17 Nov 2017 17:58:56 GMT

here is how to get a poly index of poly node by mesh tri index:

fn getPolyByTri node tri = 
(
	vv = getface node.mesh tri
	pp0 = #{1..node.numfaces}
	
	for k=1 to 3 do
	(
		pp1 = #{}
		v = vv[k]
		for i=1 to node.getVertexFaceCount v do append pp1 (node.getVertexFace v i)
		pp0 *= pp1
	)
	for p in pp0 do return p
)

there are several ways to optimize the code of course, but it's more to just show the algorithm

Re: Get face(poly) by face(mesh) in Maxscript

Swordslayer — Fri, 17 Nov 2017 18:17:12 GMT

@denisT.MaxDoctor That will work most of the time, but not always, for example for the face right to the two selected edges:

It will report poly 17 which is to the left of it (you can check in the attached scene). And this is a 'proper' quad-only mesh, happens even more often with imported meshes/booleans with large ngons.

Re: Get face(poly) by face(mesh) in Maxscript

Swordslayer — Fri, 17 Nov 2017 18:31:28 GMT

That can be mitigated by checking if the collected poly numberSet is bigger than one, getting the reverseEdge of the invisible edge, and by that the neighbor face, and intersecting with the neighbor candidate polys. Provided that the degree of the poly in question is bigger than three, that is... If not (very low chance of that, of course), this approach still won't work.

Re: Get face(poly) by face(mesh) in Maxscript

denisT.MaxDoctor — Fri, 17 Nov 2017 21:05:20 GMT

Swordslayer wrote:

@denisT.MaxDoctor That will work most of the time, but not always, for example for the face right to the two selected edges:

Yes. You right. The code abode is a translation from my c++ code. It was very easy to fix using c++, but for mxs case I need to think a little.

Re: Get face(poly) by face(mesh) in Maxscript

Swordslayer — Sun, 19 Nov 2017 18:04:00 GMT

@Anonymous wrote:

Yes. You right. The code abode is a translation from my c++ code. It was very easy to fix using c++, but for mxs case I need to think a little.

Out of curiosity, what does the fixed c++ version look like, if you don't mind sharing?

Re: Get face(poly) by face(mesh) in Maxscript

denisT.MaxDoctor — Sun, 19 Nov 2017 21:22:37 GMT

# every vertex in MNMesh has list of faces those include this vertex (mesh->vfac)

# MNFace has GetTriangles method which gives a list of corners in triangulation order

# MNFace has a list of vertices in corners order (f->vtx) and we can make list of mesh vertex indexes

all that we need is to find a poly that contains sequence of tri vertices in this list..

i'm using std::search

Re: Get face(poly) by face(mesh) in Maxscript

denisT.MaxDoctor — Sun, 19 Nov 2017 23:08:41 GMT

the fastest mxs function to get poly by tri is slightly modified Swordslayer's method:

fn getPolyFaceByTri node tri =
(
	local index = 1
	local poly = 0
	local getFaceDeg = polyop.getFaceDeg
	for k = 1 to polyop.getNumFaces node while poly == 0 do
	(
		index += getFaceDeg node k - 2
		if (tri < index) do poly = k
	)
	poly
)