topic Re: Select a filter that only partially selects on a specific layer in 3ds Max Programming Forum

Select a filter that only partially selects on a specific layer

anycganycgJ8A6A — Fri, 18 May 2018 01:38:37 GMT

Good morning
I am going to ask today despite my curiosity.
I want you to look good.

like CAD

i would like to Select a filter that only partially object selects on a specific layer
It's possible to script as a CAD without using the select by name interface
I looked for the manual but I can not find it.
I do not know how to select only some objects on that layer

pls can you help me again ~

Re: Select a filter that only partially selects on a specific layer

denisT.MaxDoctor — Fri, 18 May 2018 02:49:17 GMT

fn selectByLayer layer: =
(
 fn layerFilter node layer:layer = 
 (
 node.layer == layer
 )
 selectByName title:"Pick Nodes" buttonText:"Pick" filter:layerFilter
)
-- selectByLayer layer:(layermanager.getlayer 1)

fn selectByLayerName name: =
(
 fn layerFilter node name:name = 
 (
 stricmp node.layer.name name == 0
 )
 selectByName title:"Pick Nodes" buttonText:"Pick" filter:layerFilter
)
-- selectByLayerName name:#0

of course you can combine several filters ...

Re: Select a filter that only partially selects on a specific layer

anycganycgJ8A6A — Fri, 18 May 2018 02:58:06 GMT

Good source too thank you too ~~~~~
But the problem is that there are thousands of objects
There's a problem with choosing what I want.
So, without the select by interface
I want to select it in the viewport

For example

There are multiple layers.
I want to work with the layer name "ddd"
The remaining layers are freeze
Then I can select the "ddd" layered objects in the viewport
However,
It is a problem to unfreeze the remaining layers after selecting

is that possible ~~?

Re: Select a filter that only partially selects on a specific layer

denisT.MaxDoctor — Fri, 18 May 2018 06:58:40 GMT

are you talking about a permanent filter which once set allows select nodes in viewport just from specified layer?

or you need a function that goes into specified filter selection mode?

Re: Select a filter that only partially selects on a specific layer

anycganycgJ8A6A — Fri, 18 May 2018 07:33:31 GMT

Thank you for your reply though it's busy.
I want code.
My lack of English expressions would make you feel uncomfortable.
Please understand it

Re: Select a filter that only partially selects on a specific layer

denisT.MaxDoctor — Fri, 18 May 2018 09:12:28 GMT

unfortunately without c++ sdk you can't write Select Filter that might be used in Selection Filters list in main toolbar.

Re: Select a filter that only partially selects on a specific layer

denisT.MaxDoctor — Fri, 18 May 2018 10:36:52 GMT

try this little tool. it might for you or at least give an idea how it might be organized:

try(destroydialog SelectInActiveLayer) catch()
rollout SelectInActiveLayer "Select In Active Layer" width:200
(
	fn layerFilter = 
	(
		--format "selection changed...\n"
		
		desel = for node in selection as array where node.layer != LayerManager.current collect node
		if desel.count > 0 do undo off
		(
			disablerefmsgs()
			deselect desel
			enablerefmsgs()
		)
	)
	
	checkbutton activate_bt "Activate" width:182 align:#right offset:[4,0]
	on activate_bt changed state do undo off
	(
		if state then
		(
			callbacks.removescripts id:#layer_filter
			callbacks.addscript #selectionSetChanged "::SelectInActiveLayer.layerFilter()" id:#layer_filter
			layerFilter()
		)
		else 
		(
			callbacks.removescripts id:#layer_filter
		)
	)
	on SelectInActiveLayer close do callbacks.removescripts id:#layer_filter
)
createdialog SelectInActiveLayer

in activated mode it has to allow node selecting in the active (current) layer only

Re: Select a filter that only partially selects on a specific layer

anycganycgJ8A6A — Fri, 18 May 2018 14:07:03 GMT

wow
This is what I want.
Thank you very much
Unfortunately, it's often down
I'm afraid I'll be a lot worried about big projects

Re: Select a filter that only partially selects on a specific layer

denisT.MaxDoctor — Sat, 19 May 2018 02:14:49 GMT

try(destroydialog SelectInActiveLayer) catch()
rollout SelectInActiveLayer "Select In Active Layer" width:200
(
	fn layerFilter = 
	(
		--format "selection changed...\n"
		
		desel = for node in selection as array where node.layer != LayerManager.current collect node
		if desel.count > 0 do undo off
		(
			callbacks.removescripts id:#layer_filter
			deselect desel
			callbacks.addscript #selectionSetChanged "::SelectInActiveLayer.layerFilter()" id:#layer_filter
		)
	)
	
	checkbutton activate_bt "Activate" width:182 align:#right offset:[4,0]
	on activate_bt changed state do undo off
	(
		if state then
		(
			callbacks.removescripts id:#layer_filter
			callbacks.addscript #selectionSetChanged "::SelectInActiveLayer.layerFilter()" id:#layer_filter
			layerFilter()
		)
		else 
		(
			callbacks.removescripts id:#layer_filter
		)
	)
	on SelectInActiveLayer close do callbacks.removescripts id:#layer_filter
)
createdialog SelectInActiveLayer

take this version. it might be more stable.

if any answer to your questions solves your problem please don't forget to tag it as "SOLVED". It helps other people to search and find solutions for the same or similar problems

Re: Select a filter that only partially selects on a specific layer

anycganycgJ8A6A — Sat, 19 May 2018 02:34:55 GMT

wow
I had no idea what this would be.
wow
It's really great of you
You are not a max doctor
From now on you are max god
I really appreciate it once again.