
Lab 1 – Hello World:  Project Setup 

Create your first AutoCAD managed application

In this lab, let us see what we need to set up a project without using the ObjectARX wizard. We will use Visual Studio .NET and create a new Class Library project. This project will create a .NET dll that can be loaded into AutoCAD which will add a new command to AutoCAD named “HelloWorld”. When the user runs the command, the text “Hello World” will be printed on the command line. 

1) Launch Visual Studio and then select File> New> Project. In the New Project dialog select Visual Basic Projects for the Project Type. Select “Class Library” template. Make the name “Lab1” and set the location where you want the project to be created. Select ok to create the project
2) If the solution explorer is not visible in visual studio, you may turn it on by going to “View” menu and selecting “Solution Explorer”. This view will allow us to browse through files in the project and add references to managed or COM Interop assemblies. Open Class1.vb that was added by the NET wizard by double-clicking on it in the solution explorer. 
Connect to the AutoCAD Managed API – AcMgd.dll and AcDbMgd.dll

3) In Class1.vb notice that a public class “Class1” was automatically created. We will add our command to this class. To do this we need to use classes in the AutoCAD .NET managed wrappers. These wrappers are contained in two managed modules. To add references to these modules:

a. Right click on “References” and select “Add Reference”. 

b. In the “Add Reference” dialog select “Browse”. 

c. Navigate to the AutoCAD 2007 directory (Typically C:\Program Files\AutoCAD 2007\). Find “acdbmgd.dll” and select OK. “Browse” again then find and open “acmgd.dll”. You can also type *mgd.dll to filter for the required assemblies.. 

i. acdbmgd.dll contains ObjectDBX managed types (everything to do with manipulating drawing files)

ii. acmgd.dll contains the AutoCAD’s managed types (classes which only work in AutoCAD).

4) Use the Object Browser to explore the classes available in these managed modules. (View > Object Browser). Expand the “AutoCAD .NET Managed Wrapper” (acmgd) object. Throughout the labs we will be using these classes. In this lab an instance of “Autodesk.AutoCAD.EditorInput.Editor” will be used to display text on the AutoCAD command line. Expand the “ObjectDBX .NET Managed Wrapper” (acdbmgd) object. The classes in this object will be used to access and edit entities in the AutoCAD drawing. (following labs)
5) Now that we have the classes referenced we can import them. At the top of Class1.vb above the declaration of Class1 import the ApplicationServices, EditorInput and Runtime namespaces.

Imports Autodesk.AutoCAD.ApplicationServices

Imports Autodesk.AutoCAD.EditorInput

Imports Autodesk.AutoCAD.Runtime

Define your first command

6) We will now add our command to Class1. To add a command that can be called in AutoCAD use the “CommandMethod” attribute. This attribute is provided by the Runtime namespace. Add the following attribute and Sub to Class1. Notice the use of the line continuation character “_”. 
Public Class Class1


<CommandMethod("HelloWorld")> _


Public Sub HelloWorld()


End Sub

End Class

7)  When the “HelloWorld” command is run in AutoCAD, the HelloWorld Sub will be called. In this Sub we will get the instance of the editor class which has methods for accessing the AutoCAD command line (as well as selecting objects and other important features). The editor for the active document in AutoCAD can be returned using the Application class. After the editor is created, use the WriteMessage method to display “Hello World” on the command line. Add the following to the Sub HelloWorld:
Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor

ed.WriteMessage("Hello World")
Test in AutoCAD

To test this in AutoCAD we can have Visual Studio start a session of AutoCAD. Right click on “Lab1” project in Solution Explorer and select “Properties”. In the Lab1 Property Pages dialog select ‘Debug’, check ‘Start External Program’ and use the ellipses button and browse to acad.exe. After changing this setting, hit F5 key to launch a session of AutoCAD.

The “NETLOAD” command is used to load the managed application. Type NETLOAD on the AutoCAD command line to open the “Choose .NET Assembly” dialog. Browse to the location of “lab1.dll” (..\lab1\bin\debug), select it and then hit open.

Enter “HellowWorld” on the command line. If all went well, the text “Hello World” should appear. Switch to Visual Studio and add a break point at the line: ed.WriteMessage(“Hello World”). Run the HelloWorld command in AutoCAD again and notice that you can step through code. 

If you have time you can explore the CommandMethod attribute. Notice that it has seven different flavors. We used the simplest one that only takes one parameter, (the name of the command). You can use the other parameters to control how the command will work.

*A point to note for future reference is that if you do get problems loading your application, use the fuslogvw.exe to diagnose.

Back in Visual Studio try Exploring the CommandMethod attribute in the ObjectBrowser. Notice that it has seven different flavors. We used the simplest one that only takes one parameter, the name of the command. You can use the other parameters to control how the command will work. For example, you can specify command group name, global and local names, command flag (for the context in which the command will run), and more. 
Lab 2 – .NET AutoCAD Wizard and Simple User Input

The AutoCAD Managed Application Wizard

In the first lab we used a Class Library template and had to manually reference acdbmgd.dll and acmgd.dll. In this Lab we will use the AutoCAD Managed VB Application Wizard to create the .NET project which will do this for us. You will need to install the ObjectARX wizard before beginning this lab if you have not already done so. Install the ObjectARX 2007\utils\ObjARXWiz\ArxWizards.msi  

1) So, to create a new project using the AutoCAD Managed VB Application Wizard

a. Launch Visual Studio and then select File> New> Project. 

b. In the New Project dialog select Visual Basic for the Project Type. 

c. Select the “AutoCAD Managed VB Project Application” template. 

d. Make the name “Lab2” and set the location where you want the project to be created. Select ok. 

e. The “AutoCAD Managed VB Application Wizard” will then appear. 

i. 'We will not be using unmanaged code so leave the “Enable Unmanaged Debugging” unchecked. 

ii. The “Registered Developer Symbol” will have the value entered when the Wizard was installed. 

f. Click finish to create the project. 

2) Take a look at the project that the Wizard created. In Solution Explorer notice that acdbmgd and acmgd have been referenced automatically. In Class1.vb “Autodesk.AutoCAD.Runtime” has been imported for us and the default public class name uses the registered developer symbol name. Also the wizard has added a CommandMethod attribute and a function (Or subroutine) that we can use for our command. 

Prompt for User Input
3) In the previous lab we used the “Autodesk.AutoCAD.EditorInput.Editor” object to write a message on the AutoCAD command prompt. In this lab we will use this object to prompt the user to select a point in the drawing and then display the x, y, z value that the user selected. As in the previous lab import Autodesk.AutoCAD.ApplicationServices and Autodesk.AutoCAD.EditorInput namespaces. 

Imports Autodesk.AutoCAD.ApplicationServices

Imports Autodesk.AutoCAD.EditorInput
4) Rename the string in the CommandMethod to something more meaningful like “selectPoint”. (The name of the function can remain the same as the CommandMethod simply links to the next function after the ‘_’). 

The PromptPointOptions class is used for setting the prompt string and other options to control the prompting. An instance of this class is passed into the editor.GetPoint method. At the beginning of the function instantiate an object of this class and set the prompt string to “Select a point”. The result of prompting will be stored in an object of type PromptPointResult, so lets declare a variable of that type. Add the following to the command method.

Dim prPointOptions As PromptPointOptions = New PromptPointOptions("Select a point")

Dim prPointRes As PromptPointResult

5) Next get the editor object and use its GetPoint method passing in the PromptPointOptions object. Make the PromptPointResult object equal to the return value of the GetPoint method. We can then test the status of the PromptPointResult and exit the function if it is not ok. (Because this is a function it needs to return Nothing) 

Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor 
prPointRes = ed.GetPoint(prPointOptions)

If prPointRes.Status <> PromptStatus.OK Then

Return Nothing ' Just “Return” if it is a subroutine
End If

6) Now that the PromptPointResult has a valid point we can print out the values to the command line. Use the editor’s WriteMessage method. The ToString method of the Point3d class (PromptPointResult.Value) makes it easy to convert the point to a string:

ed.WriteMessage("You selected point " & prPointRes.Value.ToString())
7) So lets run the application.

g. Hit F5 or select Debug>Start from the menu to debug your application in AutoCAD. (Notice that the wizard enabled debugging with acad.exe automatically). 

h. Enter NETLOAD and navigate to the location of Lab2.dll in the “bin” folder and open it. 

i. On the command line enter the name you gave the command “selectpoint” (case insensitive). 

j. At the select point prompt click somewhere in the drawing. If all is ok you will see the values of the selected point printed on the command line. 

k. In Class1.vb put a break point on the line “Return Nothing” and then run the selectpoint command again. This time hit escape instead of selecting a point. The status of the PromptPointResult will not be ok so the if statement is true and “Return Nothing” gets called.

Prompt to for a geometric distance

8) Now we will add another command that will get the distance between two points. The wizard does not have a feature to add a command so we will need to do this manually. Create a new command in Class1.vb named getdistance below the function that selects a point. As this has been covered several times the code is not listed here. Use the CommandMethod attribute and make the string for the command “getdistance” or something similar. In the function for the command use PromptDistanceOptions instead of   PromptPointOptions.  Also the result of GetDistance is a PromptDoubleResult so use this in place of PromptPointResult. You will have to get the editor object again in this command:

Dim prDistOptions As PromptDistanceOptions = New PromptDistanceOptions("Find distance, select first point:")

Dim prDistRes As PromptDoubleResult

prDistRes = ed.GetDistance(prDistOptions)

9) As with the previous command test the status of the PromptDoubleResult. Then use the WriteMessage method to display the values on the command line.

If prDistRes.Status <> PromptStatus.OK Then

Return Nothing

End If

ed.WriteMessage("The distance is: " & prDistRes.Value.ToString) 

Lab 3 – Database Fundamentals:  Creating our Employee Object

Start a new project named Lab3 or continue where you left off in Lab2.

In this lab, we will create an ‘Employee object’ (1 circle, 1 ellipse and one MText object) which is housed by a Block Definition called ‘EmployeeBlock’ which uses a layer called ‘EmployeeLayer’ which is inserted into AutoCAD’s Model Space using a BlockReference type. 

Don’t worry, the lab will be executed in verifiable steps so that it is clear what each code section is meant to accomplish.  The first step will demonstrate simply how to create a circle in Model Space.  Each subsequent step will progress evenly until we have created our Block and Layer appropriately.

[image: image1.png]Earnest Shackiefon





The focus of this lab should be on the fundamentals of database access in AutoCAD.  The major points are Transactions, ObjectIds, Symbol Tables (such as BlockTable and LayerTable) and Object References.  

Other objects are used in conjunction with our steps such as Color, Point3d and Vector3d, but the focus should remain on the fundamentals.  A clear picture of the flavor of the .NET API should begin to take shape throughout this lab.

Add a command to create the Employee object

1) First lets create a command called ‘CREATE’, which calls the function CreateEmployee().  Within this function, add one circle to MODELSPACE at 10,10,0 with a radius of 2.0:

<CommandMethod("CREATE")> _

Public Function CreateEmployee()

‘First, declare the objects that we will use

Dim circle As Circle ‘This will be the circle we add to ModelSpace

Dim btr As BlockTableRecord ‘To Add that circle, we must open ModelSpace up

Dim bt As BlockTable ‘To open ModelSpace, we must access it through the BlockTable

 
‘We encapsulate our entire database interaction in this function with an object called a ‘Transaction’
Dim trans As Transaction

‘We delineate the boundaries of this interaction with StartTransaction() member of TransactionManager

trans = HostApplicationServices.WorkingDatabase().TransactionManager.StartTransaction()

‘Now, create the circle…look carefully at these arguments – Notice ‘New’ for the Point3d and the static ZAxis

circle = New Circle(New Point3d(10, 10, 0), Vector3d.ZAxis, 2.0)

‘We need to get object references for the BlockTable and ModelSpace:

‘Notice here that we obtain them with the transaction’s GetObject member!

bt = trans.GetObject(HostApplicationServices.WorkingDatabase.BlockTableId, OpenMode.ForRead)

‘Now, we declare an ID to represent the ModelSpace block table record…

Dim btrId As ObjectId = bt.Item(BlockTableRecord.ModelSpace)

‘and use it to obtain the object reference – notice we open for Write

btr = trans.GetObject(btrId, OpenMode.ForWrite)

‘Now, use the btr reference to add our circle

btr.AppendEntity(circle)

trans.AddNewlyCreatedDBObject(circle, True) ’and make sure the transaction knows about it!

trans.Commit() ’Once we’re done, we commit the transaction, so that all our changes are saved…
trans.Dispose() ’…and dispose of the transaction, since we’re all done (this is not a DB-resident object)

End Function

Study the structure of this code block, and see the comments for details.

Note:  You may need to import Autodesk.AutoCAD.DatabaseServices and Autodesk.AutoCAD.Geometry namespaces in order to compile the code.
Run this function to see it work.  It should produce a white Circle of radius 2.0 at 10,10,0.

2) We can save some typing cramps by declaring a Database variable instead of HostApplicationServices.WorkingDatabase():


Dim db as Database = HostApplicationServices.WorkingDatabase()

Use this variable in place of HostApplicationServices.WorkingDatabase() in your code.

3) Notice the code:  bt.Item(btr.ModelSpace)  used to obtain the ModelSpace block table record ID.  We can use the enumerable property of BlockTable to do the same:

bt(btr.ModelSpace)

This makes the same code much easier and shorter (modify your relevant code section to look like this):

            bt = trans.GetObject(db.BlockTableId, OpenMode.ForRead)

            btr = trans.GetObject(bt(btr.ModelSpace), OpenMode.ForWrite)

Handling Exceptions – First look

4) In the above code we are not using any exception handling, which is fundamental to a correct .NET application.  We want to be in the habit of adding this code as we go.  Let’s add a try-catch-finally for this function.

5) For compact code, we can spare ourselves the need to have a separate line for declaration and initialization for many of our variables.  After these changes, you code should look like this:

<CommandMethod("CREATE")> _

Public Function CreateEmployee()

Dim db As Database = HostApplicationServices.WorkingDatabase()

Dim trans As Transaction = db.TransactionManager.StartTransaction()

     Try

          Dim Circle As Circle = New Circle(New Point3d(10, 10, 0), Vector3d.ZAxis, 2.0)

          Dim bt as BlockTable = trans.GetObject(db.BlockTableId, OpenMode.ForRead)

          Dim btr as BlockTableRecord = trans.GetObject(bt(btr.ModelSpace), OpenMode.ForWrite)

          btr.AppendEntity(circle)

          trans.AddNewlyCreatedDBObject(circle, True)

          trans.Commit()

     Catch

          MsgBox("Error Adding Entities")

     Finally

          trans.Dispose()

     End Try

End Function

Run your code to test…

Transactions, Exception Handling and Dispose

See here that the catch block simply shows a message box.  The actual cleanup is handled in the finally block.  The reason this works is that if Dispose() is called on the transaction before Commit(), the transaction is aborted.  The assumption is made that any error condition that will throw before trans.Commit() should abort the transaction (since Commit would have never been called).  If Commit() is called before Dispose(), as is the case when nothing is thrown, the transaction changes are committed to the database.

Therefore in this case, the Catch block is really not necessary for anything other than notifying the user of a problem.  It will be removed in subsequent code snippets.

Finish up the Employee object

6) Now, let’s add the rest of our Employee; an Ellipse and an MText instance.


For the MText Entity:



Center should be same as our Circle’s: 

(Suggestion: Create a Point3d variable to handle this called ‘center’ at 10,10,0)



The MText contents should be your name.

For the Ellipse (Hint, see the Ellipse constructor)

The normal should be along the Z axis (See the Vector3d type)

Major axis should be Vector3d(3,0,0) (hint, don’t forget to use New)

radiusRatio should be 0.5

The ellipse should be closed (i.e. start and end should be the same)

Run your code to test…it should produce a Circle, Ellipse and Text centered at 10,10,0.

More about Transactions, Exception Handling and Dispose

Note:  The structure of the Try-Catch-Finally block in relation to the transaction objects in the .NET API should be of interest to the keen observer.  The fact that we are instantiating objects within the Try block, but never explicitly Dispose() of them, even when an exception occurs may seem troubling, especially if the observer notes that we are actually wrapping unmanaged objects!  Remember, however that the garbage-collection mechanism will take care of our memory allocation when resources become strained.  This mechanism in-turn calls Dispose() on the wrapper, deleting our unmanaged object under the hood.

It is important to note here that Dispose() behaves differently with the wrapped unmanaged object depending on whether the object is database-resident or not.  Dispose() called on a non-database resident object will call delete on the unmanaged object, while Dispose() called on a database-resident object will simply call close().

Create a Layer for the Employee

7) Next, let’s create a new function which creates an AutoCAD Layer called “EmployeeLayer” with its color set to Yellow.  

This function should check to see whether the layer already exists, but either way should return the ObjectId of the “EmployeeLayer”.  Here is the code for this function:

    Private Function CreateLayer() As ObjectId

        Dim layerId As ObjectId 'the return value for this function

        Dim db As Database = HostApplicationServices.WorkingDatabase

        Dim trans As Transaction = db.TransactionManager.StartTransaction()

        Try

            'Get the layer table first, open for read as it may already be there

            Dim lt As LayerTable = trans.GetObject(db.LayerTableId, OpenMode.ForRead)

            'Check if EmployeeLayer exists...

            If lt.Has("EmployeeLayer") Then

                layerId = lt.Item("EmployeeLayer")

            Else

                'If not, create the layer here.

                Dim ltr As LayerTableRecord = New LayerTableRecord()

                ltr.Name = "EmployeeLayer" ' Set the layer name

                ltr.Color = Color.FromColorIndex(ColorMethod.ByAci, 2)

                ' it doesn't exist so add it, but first upgrade the open to write

                lt.UpgradeOpen()

                layerId = lt.Add(ltr)

                trans.AddNewlyCreatedDBObject(ltr, True)

                trans.Commit()

            End If

        Catch ex As System.Exception

            MsgBox("Error in CreateLayer Command" + ex.Message)

        Finally

            trans.Dispose()

        End Try

        Return layerId

    End Function

Notice how the basic structure of the function is similar to the code we wrote to add the entities to Model Space?  The database access model here is:  Drill down from the Database object using transactions, and add entities to the symbol tables, letting the transaction know.

8) Next, let’s change the color of our new layer.  Here is a code snippet to do this.  Go ahead and add it to the code:

ltr.Color = Color.FromColorIndex(ColorMethod.ByAci, 2)

Note the method ByAci allows us to map from AutoCAD ACI color indices…in this case 2=Yellow.

9) Back in CreateEmployee(), we need to add the code to set our entities to the EmployeeLayer layer.  Dimension a variable as type ObjectId and set it to the return value of our CreateLayer function.  Use each entity’s (text, circle and ellipse) layerId property to set the layer.

e.g. text.LayerId = empId

Run the code to see that the “EmployeeLayer” is created, and all entities created reside on it (and are yellow)

Add color to the Employee

10) Now let’s set the color for our entities explicitly, using the ColorIndex property (ColorIndex reflects AutoCAD colors)


Circle should be Red – 1


Ellipse should be Green – 3


Text should be Yellow – 2

Run and test to see that the entities take on their correct color, even though the entities still reside on our “EmployeeLayer”.

Create an explicit Employee Block

11) Next, we want to create a separate Block in the AutoCAD database, and populate that block, instead of ModelSpace.  

First, change the name of our CreateEmployee function to CreateEmployeeDefinition().

Add the code to create a separate Block:

Dim myBtr As BlockTableRecord = New BlockTableRecord()

myBtr.Name = "EmployeeBlock"

Dim myBtrId As ObjectId = bt.Add(myBtr)

trans.AddNewlyCreatedDBObject(myBtr, True)

12) Now, simply modify the code that added our entities to ModelSpace to populate this block instead (hint: remember the open mode of the BlockTable).

Now, run the code and use the INSERT command to make sure we can insert our block properly.

Create a Block Reference for the new Employee block

13) Lastly, we want to create a true block reference in ModelSpace which represents an instance of this block.  This last step will be left as an exercise.

Here are the basic steps we want to follow:

A) Create a new function called CreateEmployee

B) Move the command attribute “CREATE” to CreateEmployee()

C) Modify the CreateEmployeeDefinition to return the ObjectId of the newly created block, “EmployeeBlock”, just like we did for the CreateLayer() member (hint – scope of the variable newBtrId).

D) You will need to modify the CreateEmployeeDefintion() to detect whether the BlockTable already contains an “EmployeeBlock” and return the existing ObjectId instead (just as we do in CreateLayer().  Hint:  Move the declaration of ‘bt’ to the top of the Try block and use BlockTable.Has(), moving all our preexisting code to the Else clause:
Try

            
'Now, drill into the database and obtain a reference to the BlockTable

            
Dim bt As BlockTable = trans.GetObject(db.BlockTableId, OpenMode.ForWrite)

            
If (bt.Has("EmployeeBlock")) Then

                newBtrId = bt("EmployeeBlock") 'Alreayd there...no need to recreate it!

Else

   …

E) From within the new CreateEmployee() function, create a new BlockReference object, and add it to ModelSpace. Place the block reference at (10,10,0) Hint – we can steal some of the code in CreateEmployeeDefinition() that references Model Space that is no longer needed there.
F) Call CreateEmployeeDefinition() from CreateEmployee, and set the BlockReference’s BlockTableRecord() to point to the return of this function. Hint – see the constructor of the BlockReference object.
Visual Studio 2005 Using Keyword

14) Beginning with Visual Studio 2005, Visual Basic includes the Using keyword which wraps an object implementing IDisposable for automatic disposal.  Objects which you would normally call ‘dispose’ on can be automatically handled with this keyword.  Using the ‘Using’ keyword with transactions then makes a tremendous amount of sense, as it makes our code much more compact.  The finished version of Lab3 uses the ‘Using’ keyword almost exclusively, as do the remainder of the labs in both C# and VB.
Notice below that the explicit exception handling has been removed from this function.  Since the Using keyword can take care of proper transaction management, the exception handling can be performed by the top-level, calling functions, where it belongs.  Since CreateLayer() itself is not invoked by the user, the calling function can handle any exceptions that are thrown from here.  This is the model we recommend, and will demonstrate this in the remainder of the labs.

Here is an example of the finished CreateLayer() method using the ‘Using’ keyword:

Private Function CreateLayer(ByVal layerName As String) As ObjectId

    Dim layerId As ObjectId 'the return value for this function

    Dim db As Database = HostApplicationServices.WorkingDatabase

    Using trans As Transaction = db.TransactionManager.StartTransaction()

        'Get the layer table first...

        Dim lt As LayerTable = trans.GetObject(db.LayerTableId, OpenMode.ForRead)

        'Check if EmployeeLayer exists...

        If lt.Has(layerName) Then

            layerId = lt.Item(layerName)

        Else

            'If not, create the layer here.

            Dim ltr As LayerTableRecord = New LayerTableRecord()

            ltr.Name = layerName ' Set the layer name

            ltr.Color = Color.FromColorIndex(ColorMethod.ByAci, 2)

           ' it doesn't exist so add it, but first upgrade the open to write

            lt.UpgradeOpen()

      layerId = lt.Add(ltr)

            trans.AddNewlyCreatedDBObject(ltr, True)

        End If

        trans.Commit()

    End Using

    Return layerId

End Function
And the top-level calling method which defines the exception handling frame for all the called methods

      <CommandMethod("EMPLOYEECOUNT")> _

      Public Sub EmployeeCount()

      
Dim db As Database = HostApplicationServices.WorkingDatabase

      
Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor


Try

     

Using trans As Transaction = db.TransactionManager.StartTransaction() 




‘…




trans.Commit()



End Using


Catch ex As System.Exception



ed.WriteMessage("Error Counting Employees: " + ex.Message)


End Try
       End Sub

Extra credit questions:

Once we see that this works, and our command produces a Block Reference for the EmployeeBlock, we see that it is inserted at 20,20,0 rather than 10,10,0.  Why?

If we know why, how can we make this reference come in properly?

When we list the BlockReference, it says it is on layer ‘0’ (or the current layer when the command was run).  Why?  


How can we always place the BlockReference on the EmployeeLayer?

Lab 4 – Database Fundamentals Part 2:  Adding Custom Data

In this lab we will create a new dictionary representing the Division our employee works in within the fictional ‘Acme Corporation’.  This division dictionary will include a record representing the division’s manager.  We will also add code to the employee creation process which adds a reference to the specific division the employee works for.

What we want to show is how to define custom data in a DWG file that is ‘per-drawing’ and ‘per-entity’  ‘Per-drawing’ data is custom data that is added once to an entire drawing, representing a single style or trait that objects can reference.  ‘Per-entity’ data is a custom data set that is added for specific objects and entities in the database.

In our example, we will add the per-drawing data to the Named Objects Dictionary, or ‘NOD’.  The NOD exists in every DWG file.  The per-entity data is added for each employee in an optional dictionary, called the ‘Extension Dictionary’.  Each AcDbObject-derived object can have its own Extension Dictionary to hold custom data, and in our example will include such data as Name, Salary and Division.

The focus of this lab, therefore, is Dictionary objects and XRecords; the containers we use for custom data in DWG files.

Create a custom structure in the Named Objects Dictionary

The first step is to create our corporate entry.  We will create the following division hierarchy in the first few steps of this lab:

NOD - Named Objects Dictionary

   ACME_DIVISION - Custom corporate dictionary

       Sales - Division dictionary

           Department Manager - Division entry

Open the Lab3 project in the Lab3 folder, or continue where you left off in your Lab3 code.

1) The first thing we want to do is to define a new function which will create the corporate dictionary object in the Named Objects Dictionary.  Create a function called CreateDivision(), with a command attribute defining the CREATEDIVISION command.

Here is the body of the function, which in its simplest form simply creates an ACME_DIVISION in the NOD:

  <CommandMethod("CREATEDIVISION")> _

        Public Function CreateDivision()

        Dim db as Database = HostApplicationServices.WorkingDatabase

        Using trans As Transaction = db.TransactionManager.StartTransaction()

            'First, get the NOD...

            Dim NOD As DBDictionary = trans.GetObject(db.NamedObjectsDictionaryId, OpenMode.ForWrite, False)

            'Define a corporate level dictionary

            Dim acmeDict As DBDictionary

            Try

                'Just throw if it doesn’t exist…do nothing else.

                acmeDict = trans.GetObject(NOD.GetAt("ACME_DIVISION"), OpenMode.ForRead)

            Catch

                'Doesn't exist, so create one, and set it in the NOD…

                acmeDict = New DBDictionary()

                NOD.SetAt("ACME_DIVISION", acmeDict)

                trans.AddNewlyCreatedDBObject(acmeDict, True)

            End Try

            trans.Commit()

        End Using

    End Function

Study the structure of this code block, and see the comments for details.  Notice how we use a separate Try-Catch block to handle the case for whether the ACME_DIVISION exists or not?  If the dictionary doesn’t exist, GetObject() will throw, and the catch block is executed which creates the new entry.

Run this function to see it work.  Use a database snoop tool to see the dictionary added (suggestion: ArxDbg in the ARX SDK), or perhaps use this lisp code at the command line. (dictsearch (namedobjdict) “ACME_DIVISION”).
2) Next, we want to add the ‘Sales’ entry in the ACME_DIVISION.  The ‘Sales’ entry will also be a dictionary, and since the relationship between the ‘Sales’ dictionary to the ACME_DIVISION dictionary is exactly the same as between ACME_DIVISION and the NOD, the code can be nearly identical.  Define the next block to create a dictionary called ’Sales’ to the ACME_DIVISION dictionary.

Code hint:

Dim divDict As DBDictionary

      Try

     divDict = trans.GetObject(acmeDict.GetAt("Sales"), OpenMode.ForWrite)

      Catch


…

Run the function to see that ‘Sales’ entry added to the ACME_DIVISION dictionary.

Add an Xrecord to our new structure hold custom data

3) Now we want to add a special record to this dictionary which can contain arbitrary custom data.  The data type we will add is called an XRecord, and can contain anything that we can define with the ARX type ResultBuffer (known to some as a ‘resbuf’).  A ResultBuffer can hold a number of different types of predefined data.  XRecords hold linked lists of any number of these buffers, and can be potentially very large.  Here are some of the types we can contain in each one of these ResultBuffers (from ‘DXF Group Codes for XRecords in the online help):
	Code
	Data Type

	kDxfText
	Text

	kDxfLinetypeName
	Text

	kDxfXCoord
	Point or vector (3 reals)

	kDxfReal
	Real

	kDxfInt16
	16-bit integer

	kDxfInt32
	32-bit integer

	kDxfControlString
	Control string “{“ or “}”

	kDxfXReal
	real

	kDxfXInt16
	16-bit integer

	kDxfNormalX
	Real

	kDxfXXInt16
	16-bit integer

	kDxfInt8
	8-bit integer

	kDxfXTextString
	Text

	kDxfBinaryChunk
	Binary chunk

	kDxfArbHandle
	Handle

	kDxfSoftPointerId
	Soft pointer ID

	kDxfHardPointerId
	Hard pointer ID

	kDxfSoftOwnershipId
	Soft ownership ID

	kDxfHardOwnershipId
	Hard ownership ID


In this next code section, we are going to create an XRecord which contains only one Resbuf.  This Resbuf will contain a single string value, representing the name of the Division Manager for the ‘Sales’ division.  We add an XRecord exactly the same way we added our dictionary.  Only defining the XRecord is different:

mgrXRec = New Xrecord()

mgrXRec.Data = New ResultBuffer(New TypedValue(DxfCode.Text, "Randolph P. Brokwell"))

See how we declare a new XRecord with New, but also use New to create a ResultBuffer passing an object called a ‘TypedValue’.  A ‘TypedValue’ is analogous to the ‘restype’ member of a resbuf.  This object basically represents a DXF value of a specific type, and we use them whenever we need to populate a generic data container such as XData or an XRecord.  In this case, we simply define a TypedValue with a key of DxfCode.Text and a value of “Randolph P. Brokwell”, and pass it as the single argument for the new ResultBuffer.

The ‘Data’ property of XRecord is actually just the first ResultBuffer in the chain.  We use it to specify where our chain begins.

So our next code block will look very similar to the preceding two:

   Dim mgrXRec As Xrecord

   Try

   
mgrXRec = trans.GetObject(divDict.GetAt("Department Manager"), OpenMode.ForWrite)

   Catch

   
mgrXRec = New Xrecord()

    
mgrXRec.Data = New ResultBuffer(New TypedValue(DxfCode.Text, "Randolph P. Brokwell"))

     
divDict.SetAt("Department Manager", mgrXRec)

      trans.AddNewlyCreatedDBObject(mgrXRec, True)

   End Try

Run the function and snoop to see that manager has been added to the ‘Sales’ dictionary.

Add an XRecord for each Employee Block Reference Instance

4)
Now that we have defined our corporate dictionary entries, we want to add the per-employee data to our BlockReferences defined in the previous lab.  The data we want to add is the name, salary and the division name the employee belongs to.  To add this data we will use an XRecord, as in the previous step.  Since we will add three items, we will utilize the XRecords ability to link our data together.

Generally, XRecords only exist in Dictionaries.  Since we are adding this data per‑employee, how can we do this?  The answer is that every object or entity in AutoCAD actually has an optional dictionary called an ‘Extension Dictionary’.  We can add our XRecord directly to this!

Navigate to the CreateEmployee() function we created in the last lab.  This is the one we created the BlockReference code with.

Let’s create a new XRecord, just as we did in the previous step.  Since we need to add 3 entries, we can either use the Add member of ResultBuffer, which will add a link to the chain, or we can take advantage of the fact that the ResultBuffer constructor takes a variable number of arguments.

Either way, create an XRecord in the CreateEmployee() method with ResultBuffers for the following types and values:


Text – “Earnest Shackleton” 
(or the employee name you have chosen)


Real – 72000


or a more appropriate salary (

Text – “Sales”


for the division

5)
In order to add this to our BlockReference, we must add it to the ExtensionDictionary.  Normally, this dictionary is not present, unless specifically created, as is the case with our BlockReference.  To create an Extension Dictionary on an object, call its member ‘CreateExtensionDictionary()’.  This function returns nothing, so to access the dictionary once it is created, call the member ‘ExtensionDictionary().  Therefore, we can create and access ours like this:

            br.CreateExtensionDictionary()

            Dim brExtDict As DBDictionary = trans.GetObject(br.ExtensionDictionary(), OpenMode.ForWrite, False)

Since it is just a dictionary, we can add our XRecord to it just as we did for step 3.  Go ahead and complete the code to create and access the extension dictionary of our new BlockReference, add the XRecord you created in step 4, and add the XRecord to the transaction.

6)
Back to the NOD… Since the creation of the corporate dictionaries in the NOD only needs to happen once, just as the creation of our Employee Block, we should remove the command attributes of the CreateDivision function, and call this function from within CreateEmployeeDefinition().  Go ahead and make this change.  When this is done, all the functions will be called the first time the CREATE command is run.

Iterate Model Space to Count each Employee Object

7)
The next step is unrelated.  We will create a function which iterates through ModelSpace to find the number of Employee objects (in our case just BlockReferences)added.  In VB.NET, we can treat the ModelSpace BlockTableRecord as a collection, and iterate with ‘For Each’.  Study the following code snippet:

            Dim id As ObjectId ‘ First, dimension an ID variable used in the For Loop.

            For Each id In btr

                Dim ent As Entity = trans.GetObject(id, OpenMode.ForRead, False) 'Use it to open the current object!

Once we have a pointer to ModelSpace, we can dimension an ObjectId variable, and use it with the For Each loop.  We can then use the Id to obtain the Entity reference.

Now, we need some way to filter our employees; we know that all objects in ModelSpace are ‘Entities’, but not all are Employees.  We need some way to differentiate.  For this we can use the VB.NET TypeOf keyword, and CType for a conversion:

                If TypeOf ent Is BlockReference Then 'We use .NET's RTTI to establish type.



Dim br As BlockReference = CType(ent, BlockReference)



…

This is an important concept in AutoCAD programming, since often our containers hold various types.  You will see this sort of conversion countless times in development in AutoCAD.

Go ahead and define a function called EmployeeCount() which uses the above constructs to count the number of BlockReferences encountered in ModelSpace.  It will not have any output at this point, but you can step through to see the integer variable increment with each instance found.

8)  Next, in order to write our output to the commandline, we need to enlist the services of the Application.DocumentManager.MdiActiveDocument.Editor object.  To use it, add the following code:

Imports Autodesk.AutoCAD.EditorInput

Imports Autodesk.AutoCAD.ApplicationServices

And within the function:

Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor


And finally after the loop has determined how many instances there are:

ed.WriteMessage("Employees Found: {0}" + ControlChars.Lf, nEmployeeCount.ToString())

Notes about the completed lab

Below are two methods (ListEmployee() and PrintoutEmployee()) which demonstrate a how to obtain the full listing of the employee object, including the name of the division manager within the ACME_DIVISION dictionary.  It is included in later labs, but since it is relevant to this section, we have included it in this text.  Time permitting, please have a look at the code to see how it functions.  It can be placed directly in your class, and run.  The command defined is PRINTOUTEMPLOYEE.  The ListEmployee() sub takes a single ObjectId and returns by reference a string array containing the relevant employee data.  The calling function PrintoutEmployee(), simply prints this data to the commandline.  Pay special attention to the exception handling model – the calling function has the Try-Catch, and handles all the errors in the called functions.  This is the recommended practice...
    Private Shared Sub ListEmployee(ByVal employeeId As ObjectId, ByRef saEmployeeList() As String)

        Dim nEmployeeDataCount As Integer

        Dim db As Database = HostApplicationServices.WorkingDatabase

        Using trans As Transaction = db.TransactionManager.StartTransaction() 'Start the transaction.

            Dim ent As Entity = trans.GetObject(employeeId, OpenMode.ForRead, False) 'Use it to open the current object!

            If TypeOf ent Is BlockReference Then 'We use .NET's RTTI to establish type.

                'Not all BlockReferences will have our employee data, so we must make sure we can handle failure

                Dim bHasOurDict As Boolean = True

                Dim EmployeeXRec As Xrecord = Nothing

                Try

                    Dim br As BlockReference = CType(ent, BlockReference)

                    Dim extDict As DBDictionary = trans.GetObject(br.ExtensionDictionary(), OpenMode.ForRead, False)

                    EmployeeXRec = trans.GetObject(extDict.GetAt("EmployeeData"), OpenMode.ForRead, False)

                Catch

                    bHasOurDict = False 'Something bad happened...our dictionary and/or XRecord is not accessible

                End Try

                If bHasOurDict Then 'If obtaining the Extension Dictionary, and our XRecord is successful...

                    'Stretch the employee list to fit three more entries...

                    ReDim Preserve saEmployeeList(saEmployeeList.GetUpperBound(0) + 4)

                    'Add Employee Name

                    Dim resBuf As TypedValue = EmployeeXRec.Data.AsArray(0)

                    saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)

                    nEmployeeDataCount += 1

                    'Add the Employee Salary

                    resBuf = EmployeeXRec.Data.AsArray(1)

                    saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)

                    nEmployeeDataCount += 1

                    'Add the Employee Division

                    resBuf = EmployeeXRec.Data.AsArray(2)

                    Dim str As String = resBuf.Value()

                    saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)

                    nEmployeeDataCount += 1

                    'Now, we get the Boss' name from the corporate dictionary...

                    'Dig into the NOD and get it.

                    Dim NOD As DBDictionary = trans.GetObject(db.NamedObjectsDictionaryId, OpenMode.ForRead, False)

                    Dim acmeDict As DBDictionary = trans.GetObject(NOD.GetAt("ACME_DIVISION"), OpenMode.ForRead)

                    'Notice we use the XRecord data directly...

                    Dim salesDict As DBDictionary = trans.GetObject(acmeDict.GetAt(EmployeeXRec.Data.AsArray(2).Value), OpenMode.ForRead)

                    Dim salesXRec As Xrecord = trans.GetObject(salesDict.GetAt("Department Manager"), OpenMode.ForRead)

                    'Finally, write the employee's supervisor to the commandline

                    resBuf = salesXRec.Data.AsArray(0)

                    saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)

                    nEmployeeDataCount += 1

                End If

            End If

            trans.Commit()

        End Using

    End Sub

    <CommandMethod("LISTEMPLOYEES")> _

    Public Sub List()

        Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor

        Try

            Dim Opts As New PromptSelectionOptions()

            'Build a filter list so that only block references are selected

            Dim filList() As TypedValue = {New TypedValue(DxfCode.Start, "INSERT")}

            Dim filter As SelectionFilter = New SelectionFilter(filList)

            Dim res As PromptSelectionResult = ed.GetSelection(Opts, filter)

            'Do nothing if selection is unsuccessful

            If Not res.Status = PromptStatus.OK Then Return

            Dim SS As Autodesk.AutoCAD.EditorInput.SelectionSet = res.Value

            Dim idArray As ObjectId() = SS.GetObjectIds()

            Dim employeeId As ObjectId

            Dim saEmployeeList(4) As String

            'collect all employee details in saEmployeeList array

            For Each employeeId In idArray

                ListEmployee(employeeId, saEmployeeList)

                'Print employee details to the command line

                Dim employeeDetail As String

                For Each employeeDetail In saEmployeeList

                    ed.WriteMessage(employeeDetail)

                Next

                'separator

                ed.WriteMessage("----------------------" + vbCrLf)

            Next

        Catch ex As System.Exception
            ed.WriteMessage("Error Listing Employees: " + ex.Message)

        End Try

    End Sub

Lab 5 – User Interaction:  Prompts and Selection

Prompts usually consist of a descriptive message, accompanied by a pause for the user to understand the message and enter data. Data can be entered in many ways, for example through the command line, a dialog box or the AutoCAD editor. It is important when issuing prompts to follow a format that is consistent with existing AutoCAD prompts. For example, command keywords are separated by forward slash “/” and placed within square brackets “[]”, the default value placed within angles “<>”. Sticking to a format will reduce errors on how the message is interpreted by a regular AutoCAD user. 

Whenever an operation involves a user-chosen entity within the AutoCAD editor, the entity is picked using the Selection mechanism. This mechanism includes a prompt, for the user to know what to select and how (e.g., window or single entity pick), followed by a pause. 

Try a command like PLINE to see how prompts show, and PEDIT to see how single or multiple polylines are selected. 

Prompts:

In this lab we will prompt for employee name, position coordinates, salary and division, to create an employee block reference object. If the division does not exist, then we will prompt for the division’s manager name to create the division. As we go on, let us try to reuse existing code. 

For selection, we will prompt the user to select objects within a window or by entity, and list only employee objects in the selection set. 

[image: image5.png]


Earlier, we created a single employee called “Earnest Shackleton”, where the name was stored as MText within the “EmployeeBlock” block definition (block table record). If we insert this block multiple times, we will see the same employee name for all instances. How do we then customize the block to show a different employee name each time? This is where block attributes are helpful. Attributes are pieces of text stored within each instance of the block reference and displayed part of the instance. The attribute derives properties from attribute definition stored within the block table record. 

Block Attributes:

Let us change the MText entity type to attribute definition. In CreateEmployeeDefinition() function, replace the following: 

'Text:

Dim text As MText = New MText()

text.Contents = "Earnest Shackleton"

text.Location = center
With

'Attribute

Dim text As AttributeDefinition = New AttributeDefinition(center, "NoName", "Name:", "Enter Name", db.Textstyle)

text.ColorIndex = 2
Try to test the CreateEmployeeDefinition() function by creating a TEST command and calling the function:

    <CommandMethod("TEST")> _

    Public Function Test()

        CreateEmployeeDefinition()

    End Function
You should now be able to insert the EmployeeBlock with INSERT command and specify the employee name for each instance. 

When you insert the Employee Block, notice where the block is inserted. Is it placed exactly at the point you choose, or offset? Try to determine how to fix it. (Hint: Check the center of the circle in the block definition)

Modify CreateEmployee () for reuse:

1) Let us modify the CreateEmployee() function, so that it accepts the name, salary, division and position, and returns the objectId of the employee block reference created. The signature of the function will be something like (the order of parameters may vary for you):

Public Function CreateEmployee(ByVal name As String, ByVal division As String, ByVal salary As Double, ByVal pos As Point3d) as ObjectId
2) Remove the CommandMethodAttribute “CREATE” for the above function, as it will no longer be a command to create the employee. 

3) Make modifications to the body of the function so that the name, position, division and salary are appropriately set for the block reference and its extension dictionary. 

Replace

Dim br As New BlockReference(New Point3d(10, 10, 0), CreateEmployeeDefinition())
With

Dim br As New BlockReference(pos, CreateEmployeeDefinition())

Replace

xRec.Data = New ResultBuffer( _

New TypedValue(DxfCode.Text, "Earnest Shackleton"), _

New TypedValue(DxfCode.Real, 72000), _

New TypedValue(DxfCode.Text, "Sales"))
With

xRec.Data = New ResultBuffer( _

New TypedValue(DxfCode.Text, name), _

New TypedValue(DxfCode.Real, salary), _

New TypedValue(DxfCode.Text, division))
4) Since we replaced the employee name MText to attribute definition in the block, we will create a corresponding attribute reference to display the name of the Employee.  The attribute reference will take on the properties of the attribute definition. 

Replace

btr.AppendEntity(br) 'Add the reference to ModelSpace

trans.AddNewlyCreatedDBObject(br, True) 'Let the transaction know about it

With

Dim attRef As AttributeReference = New AttributeReference()

'Iterate the employee block and find the attribute definition

Dim empBtr As BlockTableRecord = trans.GetObject(bt("EmployeeBlock"), OpenMode.ForRead)
Dim id As ObjectId

For Each id In empBtr

    Dim ent As Entity = trans.GetObject(id, OpenMode.ForRead, False) 'Use it to open the current object! 

    If TypeOf ent Is AttributeDefinition Then 'We use .NET's RTTI to establish type.

       'Set the properties from the attribute definition on our attribute reference

      Dim attDef As AttributeDefinition = CType(ent, AttributeDefinition)

      attRef.SetPropertiesFrom(attDef)

      attRef.Position = New Point3d(attDef.Position.X + br.Position.X, _

                                  attDef.Position.Y + br.Position.Y, _

                                  attDef.Position.Z + br.Position.Z)

                    attRef.Height = attDef.Height

                    attRef.Rotation = attDef.Rotation

                    attRef.Tag = attDef.Tag

                    attRef.TextString = name

      End If

Next

btr.AppendEntity(br) 'Add the reference to ModelSpace

'Add the attribute reference to the block reference

br.AttributeCollection.AppendAttribute(attRef)

'let the transaction know

trans.AddNewlyCreatedDBObject(attRef, True)

trans.AddNewlyCreatedDBObject(br, True) 
Study the code and see how we copy the attribute definition’s properties to the attribute reference except the text string that it will display. The attribute is added to the block reference’s attribute collection property. This is how you customize the Employee name per instance. 

5) Don’t forget to return the objectId of the employee block reference, but do that after you commit the transaction (because to obtain the ObjectId the mgrXRec must be open for read (remember the commit closes everything):

'Return the objectId of the employee block reference

        retId = mgrXRec.ObjectId      

        trans.Commit();

     End Using

     Return retId

6) Test CreateEmployee. 

Add a Test command to test CreateEmployee as follows:

<CommandMethod("TEST")> _

Public Function Test()


CreateEmployee("Earnest Shackleton", "Sales", 10000, New Point3d(10, 10, 0))

End Function

Modify CreateDivision() for reuse:

Now lets modify the CreateDivision() function so that it takes the Division Name and Manager Name, and returns the objectId of the department manager XRecord. If a Division Manager already exists, we will not change the Manager name.

7) If you previously called CreateDivision() from within CreateEmployeeDefinition(), comment it as we will not be creating a division there.
8) Change the signature of CreateDivision() to accept division and manager names and return an ObjectId:
Public Function CreateDivision(ByVal division As String, ByVal manager As String) As ObjectId

9) Modify the body of the above function, so that a division with the Name and Manager is created:
Replace:

divDict = trans.GetObject(acmeDict.GetAt("Sales"), OpenMode.ForWrite)

With:

divDict = trans.GetObject(acmeDict.GetAt(division), OpenMode.ForWrite)

· Replace:

acmeDict.SetAt("Sales", divDict)
With:

acmeDict.SetAt(division, divDict)

Replace:

mgrXRec.Data = New ResultBuffer(New TypedValue(DxfCode.Text, "Randolph P. Brokwell"))
With 

mgrXRec.Data = New ResultBuffer(New TypedValue(DxfCode.Text, manager))

Don’t forget to return the objectId of the department Manager XRecord, but do that after you commit the transaction:

trans.Commit()
'Return the department manager XRecord

Return mgrXRec.ObjectId

10) Now test CreateDivision() by calling the function from TEST command. Use ArxDbg tool and check out entries added to the Named Objects Dictionary under “ACME_DIVISION”.

CreateDivision("Sales", "Randolph P. Brokwell")
Define the CREATE command to create the employee:
We will add a new command called CREATE that will be used for prompting employee details to create the employee block reference. Let’s see how the command works.

11) Let’s add a new command called CREATE and declare commonly used variables and a try-catch block.

<CommandMethod("CREATE")> _

Public Sub Create()

    Dim db = HostApplicationServices.WorkingDatabase

    Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor

    Try

    Using trans As Transaction = db.TransactionManager.StartTransaction()

      ‘…   

trans.Commit()

    End Using

    Catch ex As System.Exception


Ed.WriteMessage(“Error…” + ex.Message)

    End Try

  End Sub
12) Now let us prompt for values from the user. We will first initialize the prompt string that will be displayed using a class of type PromptXXXOptions.  Within the Using Block…:

'Prompts for each employee detail

Dim prName As PromptStringOptions = New PromptStringOptions("Enter Employee Name")

Dim prDiv As PromptStringOptions = New PromptStringOptions("Enter Employee Division")

Dim prSal As PromptDoubleOptions = New PromptDoubleOptions("Enter Employee Salary")

Dim prPos As PromptPointOptions = New PromptPointOptions("Enter Employee Position or")
13) The method is designed to prompt for the position in an outer loop, supplying three keywords as optional prompts for Name, Division and Salary within the position prompt.  The app will continue to prompt for position until it is either entered or cancelled by the user.  If the user does not choose to alter the additional keyword values, the default values are used during creation instead.
An example of the command prompt will be like:

Command: CREATE

Enter Employee Position or [Name/Division/Salary]:

An example of a chosen keyword
Command: CREATE

Enter Employee Position or [Name/Division/Salary]:N

Enter Employee Name <Earnest Shackleton>:

If the user decides to choose the default name again, he/she presses the return key.

14) Let us set up a list of keywords for position prompt:

'Add keywords when prompting for position

prPos.Keywords.Add("Name")

prPos.Keywords.Add("Division")

prPos.Keywords.Add("Salary")

'Set conditions for prompting

prPos.AllowNone = False 'Do not allow null values
15) Next, setup the default values for each of these, and an additional condition for the position prompt:
 'Set the default values for each of these

   prName.DefaultValue = "Earnest Shackleton"

   prDiv.DefaultValue = "Sales"

   prSal.DefaultValue = 10000.0F

   'Set conditions for prompting

   prPos.AllowNone = False 'Do not allow null values

16) Now let us declare PromptXXXResult variable types for obtaining the result of prompting, and set them explicitly to null so we can determine whether they were used within the loop, where they are set by the editor method appropriate for each type (e.g. Editor.GetString() for PromptResult).

'prompt results

Dim prNameRes As PromptResult = Nothing
Dim prDivRes As PromptResult = Nothing
Dim prSalRes As PromptDoubleResult = Nothing
Dim prPosRes As PromptPointResult = Nothing
17) We will now loop to until the user has successfully entered a point. If there is any error in prompting, we will alert the user and exit the function. 

To check if a keyword was entered when prompting for a point, see that we check the status of the prompt result as shown below:

   'Loop to get employee details. Exit the loop when positon is entered

   Do

      'Prompt for position

      prPosRes = ed.GetPoint(prPos)

      If prPosRes.Status = PromptStatus.Keyword Then 'Got a keyword

      
Select Case (prPosRes.StringResult)

            
Case "Name"

                  
'Get employee name

                        prName.AllowSpaces = True

                        prNameRes = ed.GetString(prName)

                        If prNameRes.Status <> PromptStatus.OK Then

                           Throw New System.Exception("Error or User Cancelled Input")

                        End If

                        Case "Division"




‘…



End Select
       End If

       If prPosRes.Status = PromptStatus.Cancel Or prPosRes.Status = PromptStatus.Error Then

       
Throw New System.Exception("Error or User Cancelled")

       End If

       Loop While (prPosRes.Status <> PromptStatus.OK)
18) The above code only prompts for Name. Add code to prompt for the Salary and the Division.

19) Once we are done prompting, we will use the obtained values to create our Employee. 

CPH – NOTE Can use the ‘IIf’ statement in VB.NET

'Create the Employee - either use the input value or the default value...

      Dim name As String

      If prNameRes Is Nothing Then

      
name = prName.DefaultValue

      Else

      
name = prNameRes.StringResult

      End If

      Dim division As String

      If prDivRes Is Nothing Then

      
division = prDiv.DefaultValue

      Else

      
division = prDivRes.StringResult

      End If

      Dim salary As Double

      If prSalRes Is Nothing Then

      
salary = prSal.DefaultValue

      Else

      
salary = prSalRes.Value

      End If

      'Create the Employee

      CreateEmployee(name, division, salary, prPosRes.Value)

20) Now let’s check if a manager to the division already exists. We would do that by checking the manager name from the division’s XRecord in NOD. If it is an empty string, then we will prompt the user to enter a manager name at that time. Note that getting the manager name is made easy by our modification to CreateDivision() function. 


Dim manager As String = New String("")

      'Now create the division 

      'Pass an empty string for manager to check if it already exists

      Dim depMgrXRec As Xrecord

      Dim xRecId As ObjectId

      xRecId = CreateDivision(division, manager)

      'Open the department manager XRecord

      depMgrXRec = trans.GetObject(xRecId, OpenMode.ForRead)

      Dim val As TypedValue

      For Each val In depMgrXRec.Data

      
Dim str As String

            str = val.Value

            If str = "" Then

            
' Manager was not set, now set it

                  ' Prompt for  manager name first

                  ed.WriteMessage(vbCrLf)

                  Dim prManagerName As PromptStringOptions = New PromptStringOptions("No manager set for the division! Enter Manager Name")

                  prManagerName.DefaultValue = "Delton T. Cransley"

                  prManagerName.AllowSpaces = True

                  Dim prManagerNameRes As PromptResult = ed.GetString(prManagerName)

                  If prManagerNameRes.Status <> PromptStatus.OK Then

                  
Throw New System.Exception("Error or User Cancelled Input")

                  End If

                  'Set a manager name

                  depMgrXRec.Data = New ResultBuffer(New TypedValue(DxfCode.Text, prManagerNameRes.StringResult))

            End If

      Next
21) Test the CREATE command

Selection:

Now let us create a command that would list employee details when the user chooses a selection of employee objects in the drawing.

We will reuse the ListEmployee() function we created in the previous lab to print employee details to the command line. 

Here are roughly the steps you will follow

22) Let us call the command “LISTEMPLOYEES”

23) Call the Editor object’s GetSelection() to select entities

Dim res As PromptSelectionResult = ed.GetSelection(Opts, filter)
24) The filter in the above line is to filter out block references from the selection. You may build the filter list as shown below:

Dim filList() As TypedValue = {New TypedValue(DxfCode.Start, "INSERT")}

Dim filter As SelectionFilter = New SelectionFilter(filList)
25) Get the objectId array from the selection set as shown:

     'Do nothing if selection is unsuccessful

      If Not res.Status = PromptStatus.OK Then Return

      Dim SS As Autodesk.AutoCAD.EditorInput.SelectionSet = res.Value

   Dim idArray As ObjectId() = SS.GetObjectIds()

26) Finally pass each objectId in the selection set to ListEmployee() function to get a string array of employee detail. Print the employee detail to the command line. For example:

'collect all employee details in saEmployeeList array

For Each employeeId In idArray


ListEmployee(employeeId, saEmployeeList)

      
'Print employee details to the command line

      
Dim employeeDetail As String

      
For Each employeeDetail In saEmployeeList

      

ed.WriteMessage(employeeDetail)

      
Next

      
'separator

      
ed.WriteMessage("----------------------" + vbCrLf)

Next

Lab 6 – More User Interface:  Adding Custom Data

In this lab, we will stretch out to see what the user interface portion of the .NET API is capable of.  We will start by defining a custom context menu.  Next we will implement a modeless, dockable palette (a real AutoCAD Enhanced Secondary Window) supporting Drag and Drop.  Next we’ll demonstrate entity picking from a modal form.  Finally we’ll show defining Employee defaults with an extension to AutoCAD’s ‘Options’ dialog.

The lab will demonstrate several facets of the API, as mentioned above.

Custom Context Menu

As yet, all of our code we have written has only reacted to commands defined with the CommandMethod attribute.  To perform load-time initialization, an AutoCAD .NET application can implement a specific class to allow this.  A class need only implement the IExtensionApplication .NET interface, and expose an assembly-level attribute which specifies this class as the ExtensionApplication.  The class can then respond to one-time load and unload events.  Example:

<Assembly: ExtensionApplication(GetType(AsdkClass1))> 

Public Class AsdkClass1

    Implements IExtensionApplication

1) Go ahead and modify the AsdkClass1 class to implement this interface.  The blue lines you receive indicate that there are some required methods to implement; namely Initialize() and Terminate.  Since we are implementing an interface, this base class is pure virtual by definition.

Notice the keywords ‘Overridable’ and ‘Implements’.  These inform the compiler that we are overriding the virtual functions required by the interface to implement.  These functions must be implemented in your base class.

    Overridable Sub Initialize() Implements IExtensionApplication.Initialize

    End Sub

    Overridable Sub Terminate() Implements IExtensionApplication.Terminate

    End Sub

To add our context menu, we must define a ‘ContextMenuExtension’ member for us to use.  This class is a member of the Autodesk.AutoCAD.Windows namespace.

To use the ContextMenuExtension, we need to instantiate one with new, populate the necessary properties, and finally call Application.AddDefaultContextMenuExtension().  The way the Context menu works is that for each menu entry, we specify a specific member function to be called ‘handling’ the menu-clicked event.  We do this with .NET ‘Delegates’.  We use the VB keywords ‘AddHandler’ and ‘AddressOf’ to specify that we want the event handled by one of our functions.  Get used to this design pattern; it is used many, many times in .NET.

2) Add a ‘ContextMenuExtension’ member variable, and the following two functions to add and remove our custom context menu.  Study the code thoroughly to see what is happening here.

    Private Sub AddContextMenu()

        Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor

        Try

            m_ContextMenu = New ContextMenuExtension()

            m_ContextMenu.Title = "Acme Employee Menu"

            Dim mi As MenuItem

            mi = New MenuItem("Create Employee")

            AddHandler mi.Click, AddressOf CallbackOnClick

            m_ContextMenu.MenuItems.Add(mi)

            Application.AddDefaultContextMenuExtension(m_ContextMenu)

        Catch ex As System.Exception
            ed.WriteMessage("Error Adding Context Menu: " + ex.Message)

        End Try

    End Sub

    Sub RemoveContextMenu()

        Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor

        Try

            If Not m_ContextMenu Is Nothing Then

                Application.RemoveDefaultContextMenuExtension(m_ContextMenu)

                m_ContextMenu = Nothing

            End If

        Catch ex As System.Exception

            ed.WriteMessage("Error Removing Context Menu: " + ex.Message)

        End Try

    End Sub

Note: You may need to add a reference to System.Drawing required for one of the parameters for the MenuItem.

Notice that we specify that ‘CallbackOnClick’ function here.  This is the function (we have not added yet) which we want called in response to the menu item selection.  In our example, all we want to do is call our member function ‘Create()’, so add the following code:

    Sub CallbackOnClick(ByVal Sender As Object, ByVal e As System.EventArgs)

        Create()

    End Sub

Now, call the AddContextMenu() function from Initialize(), and similarly, call RemoveContextMenu() from Terminate().

Go ahead and run this code.  Load the built assembly with NETLOAD, and right-click in a blank space in AutoCAD…you should see the ‘Acme’ entry there.  If you crash, what could be the reason?

By design, AutoCAD’s data (including drawing databases) is stored in documents, where commands that access entities within them have rights to make modifications.  When we run our code in response to a context-menu click, we are accessing the document from outside the command structure.  When the code we call tries to modify the document by adding an Employee, we crash.  To do this right, we must ‘lock’ the document for access, and for this we use the Document.LockDocument() method.

3) Modify the callback to lock the document: 

    Sub CallbackOnClick(ByVal Sender As Object, ByVal e As System.EventArgs)

        Dim docLock As DocumentLock = Application.DocumentManager.MdiActiveDocument.LockDocument()

        Create()

        docLock.Dispose()

    End Sub

Notice we keep a copy of the ‘DocumentLock’ object.  In order to unlock the document, we simply dispose DocumentLock object returned on the original lock request.

Run the code again.  We now have a working custom context menu.

Modeless, Dockable Palette Window with Drag and Drop

In order to make our user interface as seamless as possible in AutoCAD, we want to use the same UI constructs wherever possible.  This makes the application appear seamless, and avoids ‘re-inventing the wheel’ for functionality that is included in AutoCAD.  A great example of this is dockable palette windows in AutoCAD.

With the .NET API, we can create a simple form and include it in our palettes.  We can instantiate a custom ‘PaletteSet’ object to contain our form, and customize the palette set with styles we prefer.

4) Add a new UserControl to the project by right-clicking on the project in the Solution Explorer, and select a ‘User Control’.  Give it a name of ‘ModelessForm’.  Use the ‘ToolBox’ (from the view pulldown) to add ‘Edit Boxes’ and ‘Labels’ similar to the form shown below:

Use the ‘Properties’ window to set the three ‘Edit’ boxes shown.  Set the properties to:

<First, top edit box>

(Name)
= tb_Name

Text = <Chose a name>

<Second edit box>

(Name) = tb_Division

Text = Sales

<Third edit box>

(Name) = tb_Salary

Text = <Chose a salary>
<’Drag to Create Employee’ Label> (in Step 7, below)
(Name) = DragLabel

Text = ‘Drag to Create Employee’
In order to instantiate a palette object with the .NET API, a user control object (our ModelessForm), and a ‘PaletteSet’ object are instantiated.  The PaletteSet member Add is called passing the name to show on the Palette and the user control object.

5) Next, we need to add a command for creating the palette.  Add a procedure to the class called CreatePalette, and a CommandMethod() associated which defines a command called “PALETTE”. 

Take a look at the following code snippet.  This is the code which instantiates the palette:

ps = New Autodesk.AutoCAD.Windows.PaletteSet("Employee Palette”)

Dim myForm As ModelessForm = New ModelessForm()

ps.Add("Employee Palette", myForm)

ps.MinimumSize = New System.Drawing.Size(300, 300)

ps.Visible = True

6) Add the above code to the CreatePalette() method.  ‘ps’ needs to be declared outside the function definition as:

Dim ps As Autodesk.AutoCAD.Windows.PaletteSet = Nothing

Add code in the method to check whether ps is Nothing before instantiating the palette.

Build and run the project.  Load the assembly in AutoCAD, and run the ‘PALETTE’ command to see the palette load.
Experiment with the PaletteSetStyles object with PaletteSet.Style.  Example:

ps.Style = PaletteSetStyles.ShowTabForSingle
We can also experiment with settings such as opacity.  Example:

ps.Opacity = 65

Note:  You will need to add two namespaces for the PaletteSet and PaletteSetStyles objects


Before we go on, let’s perform a quick maintenance update:  Please add the following members to the AsdkClass1 class:

    Public Shared sDivisionDefault As String = "Sales"

    Public Shared sDivisionManager As String = "Fiona Q. Farnsby" ‘ for this, you can chose any name you like

These values will be used from here on out as the defaults for Division and Division Manager.  Since they are declared as ‘Shared’, they are instantiated once per application instance and instantiated at assembly-load time.

Drag and Drop Support in the Modeless Form

In this section, we’ll add code which allows us to create an Employee using the Edit box values in the palette window.  When the user drags from the palette on to the AutoCAD editor, a position is prompted, and a new Employee instance is created using these values.

7) In order to support Drag and Drop, we first need an object to drag.  Add an additional ‘Label’ named ‘DragLabel’ to the ModelessForm user control below the text boxes, and set the text to something like that shown above (‘Drag to Create Employee’).  From this label, we will be able to handle drag and drop into the AutoCAD editor.

To detect when a drag event is taking place, we need to know when certain mouse operations take place.

First, notice that by default our DragLabel object is declared ‘WithEvents’, which allows our object to receive notifications for events that affect it, including the one we’re interested in, ‘MouseMove’.

8) Add this function declaration to the ModelessForm class, adding the Handles keyword so that we can detect the event.
Private Sub DragLabel_MouseMove() Handles DragLabel.<see next step>
Notice from intellisense all the events that we can chose from.  Find ‘MouseMove’ and add it.  We have a blue line under the MouseMove event because (from what Intellisense tells us) ‘…they do not have the same signature’.  Typically, event handlers will take two arguments; a sender as Object, and ‘event arguments’.  For the MouseMove, we must do the same.  Change the declaration to accept ‘sender’ and ‘e’.

    Private Sub DragLabel_MouseMove(ByVal sender As System.Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles DragLabel.MouseMove

    End Sub

Run the project and see that the function is called when the mouse is passed over the text.

It’s enough to see that we know when a mouse-move operation takes place.  We can even go further to tell that the ‘left’ mouse button is currently pressed with (go ahead and add this clause):

If (System.Windows.Forms.Control.MouseButtons = System.Windows.Forms.MouseButtons.Left) Then

End If

However, we need a way to detect when the object is ‘dropped’ in the AutoCAD editor.  For this, we use the .NET base class called DropTarget.  To use it, you simple create a class which inherits this base and implement the methods you need.  In our case, we need OnDrop().

9) Add a class to the project called ‘MyDropTarget’ to the project which inherits from ‘Autodesk.AutoCAD.Windows.DropTarget’.  If you add this class to the ModelessForm.vb file, make sure you add the class after the ModelessForm class.  Within this new class, add a handler for the OnDrop event:

Public Overrides Sub OnDrop(ByVal e As System.Windows.Forms.DragEventArgs)

End Sub

Within this function, we will ultimately want to call the CreateDivision() and CreateEmployee members of AsdkClass1, passing in the values from the tb_xxx edit boxes in the ModelessForm class.  To do this, we will need a way to connect the ModelessForm instance with this class; the best way is with through the DragEventArgs.  However, first we need to connect the Mouse event to the MyDropTarget class.

10) Add the following line within the MouseButtons.Left clause back in the mouse-move handler:

Application.DoDragDrop(Me, Me, System.Windows.Forms.DragDropEffects.All, New MyDropTarget())

Notice that we pass ‘Me’ in twice.  The first time is for the ‘Control’ argument, and the second time is for the user-defined data that is passed through.  Since we pass an instance of the ModelessForm class through, we can use it to obtain the values of the Edit boxes at drop-time.

Next, notice that we instantiate a DropTarget class as the last argument.  This is how our MyDropTarget override is hooked up to the mechanism.

11) Back in the OnDrop handler, let’s use the DragEventArgs argument to obtain the cursor postion at the time of the drop.  Then we can convert this to world coordinates before we call CreateDivision and CreateEmployee using the process described above in the second part of step 9 (Hint the Point data type requires System.Drawing).
Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor

Try


Dim pt As Point3d = ed.PointToWorld(New Point(e.X, e.Y))


‘…
12) Next, extricate the ModelessForm object passed within the DragEventArgs argument:

Dim ctrl As ModelessForm = e.Data.GetData(GetType(ModelessForm))
See how we can coerce our parameter to our ModelessForm instance using the GetType keyword?

13) Call the AsdkClass1 members using this instance:

AsdkClass1.CreateDivision(ctrl.tb_Division.Text, AsdkClass1.sDivisionManager)

AsdkClass1.CreateEmployee(ctrl.tb_Name.Text, ctrl.tb_Division.Text, ctrl.tb_Salary.Text, prPosRes.Value())

Note:  Calling a method of AsdkClass1 without an instance of AsdkClass1 requires that the functions be declared as ‘Shared’.  Since Shared methods can only call other shared methods, we will need to change several function declarations within AsdkClass1 to use ‘Shared’.  Go ahead and make these changes (there should be at least four).

14) Finally, since we are again handling events which are outside the prevue of commands in AutoCAD, we must again perform document locking around the code which will modify the database.  Go ahead and add document locking code just as we did for the context menu, around the above calls to Createxxx(),.

Build, load and run the assembly, running the PALETTE command.  You should be able to create an employee using Drag/Drop.

Entity Picking from a Modal Form

The next section of this lab will demonstrate obtaining details from an employee instance, that we pick on the screen and displaying the information in Edit boxes on a Modal form.  The focus of the lab will be creation of the modal form itself, and hiding it to perform picking interactively before the form is dismissed.  To obtain the employee details, we will use the ListEmployee helper function given at the end of Lab 4.

First we need to create a new form class.  This will be an actual Form rather than a User Control, as we created for the ModelessForm class.

15) Create a new Windows Form class in the project (right click in Solution View).  Call the class ‘ModalForm’.  Add three Edit boxes with labels, and two buttons to the form similar to the following:

Use the ‘Properties’ window to set the three ‘Edit’ boxes shown.  Set the properties to:

<First, top edit box>

(Name)
= tb_Name

Text = <Blank Text>

<Second edit box>

(Name) = tb_Division

Text = <Blank Text>

<Third edit box>

(Name) = tb_Salary

Text = <Blank Text>

<First, top button>

(Name)  = SelectEmployeeButton

Text = Select Employee

<Second, bottom button>

(Name)  = CloseButton

Text = Close

Next, create handlers for the buttons.  The ‘Close’ button can simply call:


Me.Close()
To display the dialog, let’s create a command method in this class which instantiates the form as a modal dialog.  Here is an example of this code:

 CommandMethod("MODALFORM")> _

 Public Sub ShowModalForm()

 
Dim modalForm As ModalForm = New ModalForm()

 
Application.ShowModalDialog(modalForm)

 End Sub

Build, Load and run the MODALFORM command in AutoCAD to see the dialog work.  Try resizing the dialog at the lower right corner, and close the dialog.  Notice that re-running the MODALFORM command brings up the dialog where you left it!  This is a feature of the ShowModalDialog method.  The size and position values are persisted as part of the AutoCAD editor settings.

The ‘Select Employee’ Button will first perform a simple entity selection.  For this we can use the Editor.GetEntity() method, which is easier for single picks than defining a selection set.  Here is a block of code which demonstrates how to use it:

Dim prEnt As PromptEntityOptions = New PromptEntityOptions("Select an Employee")

Dim prEntRes As PromptEntityResult = ed.GetEntity(prEnt)
16) Add this code to the body of the SelectEmployeeButton_Click handler, along with the necessary database, editor and transaction setup variables, and a Try Catch block.  Don’t forget to Dispose within the Finally block.

Test the return value of GetEntity against PromptStatus.OK.  If it is not equal, call Me.Show, and exit from the handler.

Once we have the result, and is OK, we can use the PromptEntityResult.ObjectId() method to obtain the object Id for the selected entity.  This ID can be passed in to the AsdkClass1.ListEmployee function along with a fixed string array to obtain the details.  Here is some code which demonstrates:

            Dim saEmployeeList(-1) As String 'This is right...it is redimed in the ListEmployee function.

            AsdkClass1.ListEmployee(prEntRes.ObjectId, saEmployeeList)

            If (saEmployeeList.Length = 4) Then

                tb_Name.Text = saEmployeeList(0)

                tb_Salary.Text = saEmployeeList(1)

                tb_Division.Text = saEmployeeList(2)

            End If

17) Add this code, which populates our Edit boxes with the Employee details.

Before we can test the code, we need to remember that this code is running from a modal dialog, which means that user interactivity is blocked while the dialog is visible.  Before we can actually pick an Employee to list, we need to hide the form to allow picking.  Then when all is done, we can show the form again (e.g. in the Finally block of the function).

18) Add code to hide before picking (e.g. before the try block), ‘Me.Hide’  and code to show the form when complete (e.g. in the Finally block) , ‘Me.Show’.  

Build, Load and run the MODALFORM command in AutoCAD to see the dialog work.  Try picking an entity and populating the form’s values.

Adding a Page to the AutoCAD Options Dialog

The last section of this lab demonstrates how we can define a new User Control which can be displayed as a page on the AutoCAD Options dialog.  We can use this page to set default values used throughout our application.  In the Employee example, we will simply set the sDivisionDefault and sDivisionManager strings in AsdkClass1.

19) Add (yet) another User Control called ‘EmployeeOptions’ to the project.  Add two edit boxes with labels, so that it looks similar to the following:

Use the ‘Properties’ window to set the three ‘Edit’ boxes shown.  Set the properties to:

<First, top edit box>

(Name)
= tb_EmployeeDivision

Text = <Blank Text>

<Second edit box>

(Name) = tb_DivisionManager

Text = <Blank Text>

To display a custom tab dialog in the .NET API, there are two steps.  The first step is to subscribe to notifications for when the options dialog is launched by passing the address of a member function to be called.  The second step is to implement the callback function; the second argument passed into the callback is a ‘TabbedDialogEventArgs’ object which we must use to call its ‘AddTab’ member.  AddTab takes a title string, and an instance of a ‘TabbedDialogExtension’ object, which wraps our form.  Within the constructor of TabbedDialogExtension, we pass a new instance of our form, and callback addresses we can pass to handle either OnOK, OnCancel or OnHelp.

20) Within the EmployeeOptions class, add a Shared function called AddTabDialog which adds a handler for the system to call:

    Public Shared Sub AddTabDialog()

        AddHandler Application.DisplayingOptionDialog, AddressOf TabHandler

    End Sub

Go ahead and add code to call this function within the Initialize member of AsdkClass1.  Since this method is called during startup (since the class now implements IExtensionApplication), we can setup our tab dialog automatically.

21) Go ahead and implement a similar function which removes the handler, using the RemoveHandler VB keyword.

You can see from this that we are adding a hander for the DisplayingOptionDialog event in the Application object in AutoCAD, specifying that the ‘TabHandler’ method be called.  Therefore our next objective is to implement that function.

22) Add the following code to implement the handler:

Private Shared Sub TabHandler(ByVal sender As Object, ByVal e As Autodesk.AutoCAD.ApplicationServices.TabbedDialogEventArgs)

Dim EmployeeOptionsPage As EmployeeOptions = New EmployeeOptions()

e.AddTab("Acme Employee Options", _

New TabbedDialogExtension( _

EmployeeOptionsPage, _

New TabbedDialogAction(AddressOf EmployeeOptionsPage.OnOk)))

End Sub

You see here that we first instantiate an EmployeeOptions object.  Then call e.AddTab(), passing a new instance of a TabbedDialogExtension object, which takes our EmployeeOptions instance, and a TabbedDialogAction specifying where to callback for the three actions we can subscribe to, Ok, Cancel and Help.  In this example, we chose to handle only OK.  There are two other override versions of the TabbedDialogAction constructor which handle the others.

23) Now all that is left is to specify what happens in our callback, which as you may have guessed, should be ‘OnOK’.  As described above, we intend only to populate the Shared members of the AsdkClass1 with values added to the tb_DivisionManager and tb_EmployeeDivision Edit boxes.  Here is the code:

Public Sub OnOk()

      AsdkClass1.sDivisionDefault = tb_EmployeeDivision.Text

      AsdkClass1.sDivisionManager = tb_DivisionManager.Text

End Sub

Build, Load and run the AutoCAD OPTIONS  to see our custom dialog.  Try setting these values and instantiating an Employee.  You should be able to use the PRINTOUTEMPLOYEE command to see these details fully.

Extra credit:  Setup the dialog so that the values within the Edit boxes automatically reflect the Shared Manager and Division strings in AsdkClass1.

Lab 7 – Handling Events in AutoCAD
In this lab, we will explore how to monitor and respond to events in AutoCAD.  We will discuss the use of event handlers; specifically, how to monitor AutoCAD commands as well as monitor objects which are about to be modified by those commands.  We begin with a brief discussion of events in .NET, before proceeding to demonstrate how to implement AutoCAD event handlers. 

Events in VB.NET

An event is simply a message sent to notify that an action has taken place.  In ObjectARX ,  reactors are used to  monitor actions that occur in AutoCAD..  In the AutoCAD .NET API, the ObjectARX reactors are mapped to events.

Event handlers (or callbacks) are procedures which are placed in the environment to watch and react to events that occur in the application. Events come in a variety of types. 

As an introduction to working with events in AutoCAD's .NET API, a brief description of delegates will be helpful.

Delegates Described
A delegate is a class that holds a reference to a method (the functionality is similar to function pointers). Delegates are type-safe references to methods (similar to function pointers in C).  They have a specific signature and return type.  A delegate can encapsulate any method which matches the specific signature. Under the hood, AutoCAD .NET events are mapped to ObjectARX reactors using delegates. 

Delegates have several uses, one of which is acting as a dispatcher for a class that raises an event.  Events are first-class objects in the .NET environment.  Even though VB.NET hides much of the implementation detail, events are implemented with delegates.  Event delegates are multicast (meaning they hold references to more than one event handling method).  They maintain a list of registered event handlers for the event.  A typical event-handling delegate has a signature like the following:

Public Delegate Event (sender as Object, e as EventArgs)
The first argument, sender, represents the object that raises the event.

The second, e, is an EventArgs object (or a class derived from such).  This object generally contains data that would be of use to the events handler. 

AddHandler and RemoveHandler statements
In order to use an event handler, we must associate it with an event.  This is done by using either the Handles or AddHandler statement.  For our purposes, we will focus on the AddHandler statement, as it is more flexible than the Handles clause. AddHandler, and its counterpart RemoveHandler, allow you to connect, disconnect, or change handlers associated with the event at run time.

When we use the AddHandler statement, we specify the name of the event sender, and we specify the name of our event handler with the AddressOf statement; for example: 

AddHandler MyClass1.AnEvent, AddressOf EHandler
As mentioned, we use the RemoveHandler statement to disconnect an event from an event handler (remove the association).  The syntax is as follows:

RemoveHandler MyClass1.AnEvent, AddressOf EHandler
Handling AutoCAD Events in .NET

In general, the steps for dealing with AutoCAD events are:

1. Create the event handler.
An event handler (or callback) is the procedure to be called when an event is raised (triggered).  Any action we wish to take, in response to an AutoCAD event, takes place in the event handler. 

For example, suppose we just want to notify the user that an AutoCAD object has been appended.  We can use the AutoCAD database event “ObjectAppended” to accomplish this.  We can write our callback (event handler) as follows:

Sub objAppended(ByVal o As Object, ByVal e As ObjectEventArgs)

    MessageBox.Show("ObjectAppended!")

    ‘Do something here

    ‘Do something else, etc.

End Sub  

The first argument, in this case, represents an AutoCAD database.  The second represents the ObjectEventArgs class, which may contain data that is useful to the handler. In this lab we will be creating three event handlers. One each for when a command starts, when a command ends and when an object is modified. 

2. Associate the event handler with an event.
In order to begin monitoring an action, we must connect our handler to the event.

At this point, the ObjectAppended event will fire when an object is added to the database.  However, our handler will not respond to it until we associate it to the event, such as:

Dim db As Database

db = HostApplicationServices.WorkingDatabase()

AddHandler db.ObjectAppended, New ObjectEventHandler(AddressOf objAppended)

3. Disconnect the event handler.
To cease monitoring an action, we must remove the association between our handler and the event.  When we want to stop notifying the user when objects are appended, we need to remove the association between our handler and the ObjectAppended event:

RemoveHandler db.ObjectAppended, AddressOf objAppended

Using event handlers to control AutoCAD behavior

The objective of Lab 7 is to demonstrate how AutoCAD events can be used to control behavior in a drawing.  In this case, let us assume that we have used the previous lab (Lab 6), to create some EMPLOYEE block references in a drawing.  We want to prevent the user from changing the position of the EMPLOYEE block reference in the drawing, without limiting the location of other (non-EMPLOYEE) block references.  We will do this through a combination of Database and Document events. 

We will first monitor AutoCAD commands as they are about to be executed (we use the CommandWillStart event).  Specifically we are watching for the MOVE command.  We also need to be notified when an object is about to be modified (using the ObjectOpenedForModify event), so we can verify that it is an EMPLOYEE block reference.  It would be futile to modify the object from the ObjectOpenedForModify callback, as our change would just re-trigger the event, causing unstable behavior.  So, we will wait for the execution of the MOVE command to end (using the CommandEnded event).  This would be a safe time to modify our object.  Of course any modification to the block reference will again trigger the ObjectOpenedForModify event.  However, we will set some global variables as flags, to indicate that a MOVE command is active, and that the object being modified is an EMPLOYEE block reference.

NOTE:  There is a considerable amount of code required in this lab that is not specifically related to events.   Most of this code is provided.  The goal of this lab is the successful creation of the event handlers and their registration.

Setup the new project

Begin with the solved Lab6 project.  Add a new class AsdkClass2 (use Imports to make the required namespaces available in this new class).  We will need to add four global variables.  The first two are of type Boolean: one to indicate that our monitored command is active, and one to indicate that the ObjectOpenedForModify handler should be bypassed. 

'Global variables

Dim bEditCommand As Boolean

Dim bDoRepositioning As Boolean

Next, we declare a global variable which represents an ObjectIdCollection.  This will hold the ObjectIDs of the objects we have selected to modify.  

Dim changedObjects As New ObjectIdCollection()

Finally, we declare a global variable which represents a Point3dCollection.  This collection contains the position (3dPoint) of our selected objects. 

Dim employeePositions As New Point3dCollection()

Create the first Document event handler (callback)
Now we must create an event handler which notifies us when an AutoCAD command is about to start. (The name of this procedure is passed into the second parameter of AddHandler using AddressOf) Name this Procedure “cmdWillStart”. See the objAppended example (in Part2 above) for an example of the two parameters it needs to take. In this procedure, first ensure that the event’s GlobalCommandName parameter is equal to MOVE

If e.GlobalCommandName = "MOVE" Then

    'Set the global variables

    ‘

    ‘

    ‘'Delete all stored information

    ‘

    ‘

End If

If the MOVE command is about to start, we need to set our Boolean variable bEditCommand accordingly, so we know that our monitored command is active.  Likewise, we should set our other Boolean variable bDoRepositioning to NOT bypass the ObjectOpenedForModify event handler at this time.  After all, it is during this period, while the command is active, that we must acquire information about our selected block references.

At this time, we should also clear any contents from our two Collection objects.  We are only concerned with the currently-selected object. These collection objects wrap the AcGePoint3d and AcDbObjectIdArray. (Uuse the clear method to remove any existing entries). 

Create the Database event handler (callback)

This is the second event handler we will create. (name the procedure objOpenforMod). It will be called whenever an object has been opened for modification.  Of course, if our monitored command is not active at this time, we should bypass any further processing done by this callback: 

If bEditCommand = False Then

    Return

End If

Similarly, if our monitored command has ended, and the ObjectOpenedForModify event is re-triggered by some action taken in another callback, we want to prevent any subsequent executions of this callback while the object is being modified:   

If bDoRepositioning = True Then

    Return

End If

The remainder off the code in this callback is used to validate that we are indeed processing an EMPLOYEE block reference.  If so, we collect its ObjectID and its Position (3dPoint).  The following code can be pasted into this event handler:

Public Sub objOpenedForMod(ByVal o As Object, ByVal e As ObjectEventArgs)

        If bEditCommand = False Or bDoRepositioning = True Then

            Return

        End If

        Dim objId As ObjectId = e.DBObject.ObjectId

        Dim db As Database = HostApplicationServices.WorkingDatabase

        Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor

        Try

            Using trans As Transaction = db.TransactionManager.StartTransaction()

                Dim ent As Entity = trans.GetObject(objId, OpenMode.ForRead, False) 'Use it to open the current object!

                If TypeOf ent Is BlockReference Then 'We use .NET's RTTI to establish type.

                    Dim br As BlockReference = CType(ent, BlockReference)

                    'Test whether it is an employee block

                    'open its extension dictionary

                    If br.ExtensionDictionary().IsValid Then

                        Dim brExtDict As DBDictionary = trans.GetObject(br.ExtensionDictionary(), OpenMode.ForRead)

                        If brExtDict.GetAt("EmployeeData").IsValid Then

                            'successfully got "EmployeeData" so br is employee block ref

                            'Store the objectID and the position

                            changedObjects.Add(objId)

                            employeePositions.Add(br.Position)

                            'Get the attribute references,if any

                            Dim atts As AttributeCollection

                            atts = br.AttributeCollection

                            If atts.Count > 0 Then

                                Dim attId As ObjectId

                                For Each attId In atts

                                    Dim att As AttributeReference

                                    att = trans.GetObject(attId, OpenMode.ForRead, False)

                                    changedObjects.Add(attId)

                                    employeePositions.Add(att.Position)

                                Next

                            End If

                        End If

                    End If

                End If

                trans.Commit()

            End Using

        Catch ex As System.Exception
            ed.WriteMessage("Error in objOpenedForMod: " + ex.Message)

        End Try

    End Sub
Create the Second Document event handler (callback)

The third event handler is called when a command ends (name the procedure cmdEnded). Again, we check our global variable to verify that it is our monitored command that is ending.  If so, we can reset the variable now:

'Was our monitored command active?

If bEditCommand = False Then

    Return

End If

bEditCommand = False

Actions taken by this callback will re-trigger the ObjectOpenedForModify event.  We must ensure that we bypass any action in the callback for that event: 

'Set flag to bypass ObjectOpenedForModify handler

bDoRepositioning = True

The remainder off the code in this callback is used to compare the current (modified) positions of an EMPLOYEE block reference and its associated attribute reference to their original positions.  If the positions have changed, we reset them to the original positions during his callback.  The following code can be pasted into this event handler:

Public Sub cmdEnded(ByVal o As Object, ByVal e As CommandEventArgs)

        'Was our monitored command active?

        If bEditCommand = False Then

            Return

        End If

        bEditCommand = False

        'Set flag to bypass OpenedForModify handler

        bDoRepositioning = True

        Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor

        Try

            Dim db As Database = HostApplicationServices.WorkingDatabase

            Dim oldpos As Point3d

            Dim newpos As Point3d

            For i As Integer = 0 To changedObjects.Count - 1

                Using trans As Transaction = db.TransactionManager.StartTransaction()

                    Dim bt As BlockTable = trans.GetObject(db.BlockTableId, OpenMode.ForRead)

                    Dim ent As Entity = CType(trans.GetObject(changedObjects.Item(i), OpenMode.ForWrite), Entity)

                    If TypeOf ent Is BlockReference Then 'We use .NET's RTTI to establish type.

                        Dim br As BlockReference = CType(ent, BlockReference)

                        newpos = br.Position

                        oldpos = employeePositions.Item(i)

                        'Reset blockref position

                        If Not oldpos.Equals(newpos) Then

                            trans.GetObject(br.ObjectId, OpenMode.ForWrite)

                            br.Position = oldpos

                        End If

                    ElseIf TypeOf ent Is AttributeReference Then

                        Dim att As AttributeReference = CType(ent, AttributeReference)

                        newpos = att.Position

                        oldpos = employeePositions.Item(i)

                        'Reset attref position

                        If Not oldpos.Equals(newpos) Then

                            trans.GetObject(att.ObjectId, OpenMode.ForWrite)

                            att.Position = oldpos

                        End If

                    End If

                    trans.Commit()

                End Using

            Next

        Catch ex As System.Exception
            ed.WriteMessage("Error in cmdEnded: " + ex.Message)

        End Try

    End Sub
Create the commands to register/disconnect the event handlers 

Create a command ADDEVENTS, which uses AddHandler statements to associate each of the three event handlers to the events. See the section above, “Associate the event handler with an event”, for an example. The command events are document events, and the object modified event is a database event.  During this command, we need to  set our global Boolean variables:

bEditCommand = False

bDoRepositioning = False

Create another command REMOVEEVENTS, using RemoveHandler statements to disconnect our event handlers from the events.  

Test the project
To test this project, Create one or more EMPLOYEE block references, using the CREATE command.  For comparison, also insert some non-EMPLOYEE block references, if you like.

Execute the ADDEVENTS command by typing it into the command window.  

Execute the MOVE command at the command window, and select as many block references as you want.  Note that when the MOVE command ends, the EMPLOYEE block references (and attributes) retain their original positions.  

Execute the REMOVEEVENTS command, and try the MOVE command again.  Note that the EMPLOYEE block references can now be moved.

Extra credit:  Add an additional callback which is triggered when the EMPLOYEE block reference “Name” attribute has been changed by the user.

