(defun c:img ( / ang dis ins lst spc )
    (if
        (and
            (setq lst (LM:getfiles "Select Image Files to Insert" img:dir nil))
            (setq ins (getpoint "\nSpecify insertion point: "))
        )
        (progn
            (initget 4)
            (setq dis (cond ((getdist "\nSpecify image spacing <0>: ")) (0.0))
                  spc (vlax-get-property (vla-get-activedocument (vlax-get-acad-object))
                          (if (= 1 (getvar 'cvport)) 'paperspace 'modelspace)
                      )
                  ang (angle '(0.0 0.0 0.0) (trans (getvar 'ucsxdir) 0 1))
                  img:dir (vl-filename-directory (car lst))
            )
            (foreach img lst
                (setq ins
                    (cons
                        (+ (car ins) dis
                           (vla-get-imagewidth (vlax-invoke spc 'addraster img ins 1.0 ang))
                        )
                        (cdr ins)
                    )
                )
            )
        )
    )
    (princ)
)
(vl-load-com) (princ)