Community
@pbejse wrote:@ tharwat.
Perhaps it would be better to include (cons 2 (strcat bname ",`*U*"))) on your ssget filter to reduce the number of blocks for iteration on "global mode" and "Window" mode.
Better yet combine the two options like i had in mine.
Cheers Tharwat
Correct pbejse 
I tried to modify the code but it gave me a message that I ran put of time to rectify the post . so it is okay for now .
Thank you for the correction mate .
Cheers
Tharwat,
This routine is amazing, far beond what I expected... Thank you very much.
The only thing I can think to alter is the Layer option would only show the layers found within the block selected.
Example:
Getblocks
Select a block on a layer named CW-30-UC, which is a Casework block
All Casework Blocks found would report their Layers in the Layers popup_list (see image)
-->Note: All other layers in the drawing would not be listed to condense the layer list
Again, I appreciate your help with this. If you were not half a world away I would shake your hand with great gratitude.
You are very welcome David , I am really happy that you liked the idea and the program itself .
Now let me explain what I got from your new request to modify the routine accordingly :
You want to select the fore-said block and when the routine bring you back to its dialog , you want to list the layers that all similar blocks with the same name to be listed in the popup_list ?
If so , what to do after you have that list of layers in the popup_list ?
I need to know what you want to do with the layers after all .
The more you are clear on your aim of the routine, the best routine and codes would be written for you .
Regards
@dortega4226 wrote:Tharwat,
I guess that is a correct assumption. I would no longer need the global or window selection modes for the layer selection. If it makes it more challanging, they can be omitted, but if it's all the same they can stay. I can't think of a need for them now, but that doesn't mean I won't in the furture...
It is all up to you and I have no problem to keep them if you may be in need of them in the future if you intend to use the routine the same way that imagined and designed the routine accordingly .
You still did reply to my question about layers , and what to do after returning back to dialog when a user select a block and have the layers in that drop list ?
Tharwat,
Sorry for the confusion, I guess it comes from not designing something like this before.
For the layers...
- Once I have selected a block
- Received a filtered layer lists based on what is being used by selected blocks
- I would make a choice of using the --On Any Layer-- feature or pick a Specific Layer being used
- -->If I opt to use the --On Any Layer-- feature, then all blocks would be selected based on the name
- -->If I opt to use a Specific Layer (CW-30-UC B3) feature, then all blocks using the layer I selected would be found (similar to Quick Select tool)
- After this process I would add hyperlinks to the item based on documentation
- Finally I would run the PutURL routine to add the Layer Description to the Hyperlink name
I hope this is more clear and concise, I actually tried to answer you this time.
Hope this would meet your needs
(defun c:GetBlocks (/ *error* D f id run go sel blocks s lst ss i layer
sn bn go BlockTable
)
;; Author: Tharwat Al Shoufi ;;
;; GetBlocks Program ;;
;; Date : 04. August. 2014 ;;
(defun *error* (msg)
(if (and D (setq D (findfile D)))
(vl-file-delete D)
)
(if (wcmatch (strcase msg) "*BREAK*,*CANCEL*,*EXIT*")
(princ msg)
(princ (strcat "\n ** Error : " msg " **"))
)
)
;; ;;
(defun BlockTable (/ i a l nm)
(while (setq i (tblnext "BLOCK" (not i)))
(if (not (wcmatch (setq nm (cdr (assoc 2 i))) "`**"))
(setq l (cons nm l))
)
)
(setq l (acad_strlsort l))
)
;; ;;
(if (ssget "_X" '((0 . "INSERT")))
(setq run t)
(alert "No blocks found in this drawing !!")
)
(if (and run
(setq D (vl-filename-mktemp nil nil ".dcl"))
(setq f (open D "w"))
)
(progn
(write-line
(strcat
"test : dialog { label = \"Highlight Blocks\"; width = 36;"
"spacer;" ": boxed_column { label = \"Options\";"
": button { label = \"Select >>\"; key = \"sbk\";}" "spacer;"
": popup_list { label = \"Block:\"; key = \"bl\"; width = 32;}"
"spacer;"
": popup_list { label = \"Layer:\"; key = \"lay\"; width = 32;}}"
"spacer;" ": boxed_radio_column { label = \"Selection Way:\";"
": radio_button { label = \"Global\"; key = \"g\"; value = \"1\";}"
": radio_button { label = \"Window\";key = \"w\";}}" "spacer;"
": boxed_row { label = \"Action\"; fixed_width = true; alignment = centered;"
": button { label = \"Okay\"; key = \"oki\"; is_default = true; height = 1.75; width = 12;}"
": button { label = \"Exit\"; key = \"esc\"; is_cancel = true; height = 1.75; width = 12;}}}"
)
f
)
(close f)
)
)
(if (or (not D)
(not (new_dialog "test" (setq id (load_dialog D))))
)
(progn (if (> id 0)
(unload_dialog id)
)
(if (and D (setq D (findfile D)))
(vl-file-delete D)
)
)
(progn
(setq blocks (BlockTable))
(start_list "bl")
(mapcar 'add_list blocks)
(end_list)
(if *layers*
(progn
(start_list "lay")
(mapcar 'add_list (acad_strlsort *layers*))
(end_list)
)
)
(if (and *GetBlockName* (tblsearch "BLOCK" *GetBlockName*))
(set_tile "bl" (itoa (vl-position *GetBlockName* blocks)))
)
(action_tile "sbk" "(setq sel t *layers* nil)(done_dialog)")
(action_tile
"oki"
"(setq lst (mapcar 'get_tile (list \"bl\" \"lay\" \"g\" \"w\"))
bn (nth (atoi (car lst)) blocks)
go t *GetBlockName* nil *layers* nil) (done_dialog)"
)
(action_tile "esc" "(setq go nil) (done_dialog)")
(start_dialog)
(unload_dialog id)
(vl-file-delete D)
)
)
(if (and sel
(princ "\n Pick Block :")
(setq s (ssget "_+.:S:E" '((0 . "INSERT"))))
(setq *GetBlockName*
(vla-get-effectivename
(vlax-ename->vla-object (ssname s 0))
)
)
(setq
ss (ssget "_X" (list '(0 . "INSERT") (cons 2 *GetBlockName*)))
)
)
(progn
(repeat (setq i (sslength ss))
(if (not (member (setq layer
(cdr (assoc 8 (entget (ssname ss (setq i (1- i)))))
)
)
*layers*
)
)
(setq *layers* (cons layer *layers*))
)
)
(c:GetBlocks)
)
)
(if (and bn
go
(setq ss (ssget (if (eq (caddr lst) "1")
"_X"
"_:L"
)
(list '(0 . "INSERT")
(cons 8
(if (eq (cadr lst) "0")
"*"
(nth (atoi (cadr lst)) layers)
)
)
(cons 2 (strcat "`*U*," bn))
)
)
)
)
(progn (repeat (setq i (sslength ss))
(if (not (eq (vla-get-effectivename
(vlax-ename->vla-object
(setq sn (ssname ss (setq i (1- i))))
)
)
bn
)
)
(ssdel sn ss)
)
)
(sssetfirst nil ss)
)
)
(princ)
)
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
