@sagar.adhau wrote:
Hi scottbolton,
With reference to your post i have further query.It would be great help if you help me on following,
I have many drawings in one folder and each drawings has multiple layouts.I wanted to run lisp for open, zoom extent, purge all and save all and close all command to this folder.(before closing each drawing it should switch to first layout and then go for save and close command ).
I have tried with your above script and run batch file but there it is not working.
Be aware that an AutoCAD Batchfile (script | *.scr) requires SDI mode (Single Document Interface) to run. You can not use the 'close' command.
Using "fileopen" will close the previous drawing. (& ask to save if it has pending changes) - you can only use qsave or save. (save all has no meaning with just 1 drawing open ...)
Any script or lisp invoking SDI mode can only do so if you don't have multiple drawings open at execution. (closing drawings beyond the one the lisp runs in, is not possible)
The next code is an adaptation of some code i posted earlier for a similar request and will do what you ask for.
After selecting the directory it will create a script to run a purge all, zoom extent, activate the first layout (if present) & qsave on all DWG drawings there (NOT including subdirectories).
Note: As it uses 2 ACET functions, you need express tools for it to work.
(vl-load-com)
(defun c:scrDir ( / dir_path scr_path path files_list abort msg confirm)
; --- INIT
(setq dir_path "C:\\My Documents") ; starting path for file selection
(setq scr_path "c:\\temp") ; path for writing script (scrDir.scr)
; --- Functions
(defun get_files ( dr / dt tl fp i l filelist)
(princ "\nCollecting filenames: ")
(setq filelist nil)
(setq tl (vl-directory-files dr "*.dwg"))
(setq i 0)
(while (< i (length tl))
(setq fp (strcat (parse_path dr) "/" (nth i tl)))
(setq filelist (append filelist (list fp)))
(setq i (1+ i))
)
(princ (itoa (length filelist)))
filelist
)
(defun parse_path (path / temp i)
(setq i 1 temp "")
(repeat (strlen path)
(if (= (substr path i 1) "\\")
(setq temp (strcat temp "/"))
(setq temp (strcat temp (substr path i 1)))
)
(setq i (1+ i))
)
temp
)
(defun scrGen ( scrdir f_list / file_w i f_name iSDI iFILEDIA)
(setq file_w (open (strcat scrdir "/scrDir.scr") "w")
iSDI (getvar "SDI")
iFILEDIA (getvar "FILEDIA")
i 0
)
(if (= iSDI 0)(write-line "(setvar \"SDI\" 1)" file_w))
(if (= iFILEDIA 1)(write-line "(setvar \"FILEDIA\" 0)" file_w))
(while (< i (length f_list))
(setq f_name (nth i f_list))
(write-line (strcat "(command \"_.fileopen\" \"" f_name "\")") file_w)
(write-line "(command \"-purge\" \"a\" \"\" \"n\")" file_w)
(write-line "(command \"_.zoom\" \"e\")" file_w)
(write-line "(if (not (= (nth 0 (layoutlist)) nil))(setvar 'ctab (nth 0 (layoutlist))))" file_w)
(write-line "(command \"_.qsave\")" file_w)
(setq i (1+ i))
)
(if (= iSDI 0)(write-line "(setvar \"SDI\" 0)" file_w))
(if (= iFILEDIA 1)(write-line "(setvar \"FILEDIA\" 1)" file_w))
(close file_w)
)
; *** Main ***
(setq path (acet-ui-pickdir "Select directory:" dir_path))
(if path
(setq files_list (get_files path))
(princ "\n*Cancel*")
)
(setq abort T)
(if files_list
(progn
(setq msg (strcat "Ok to start processing " (itoa (length files_list)) " file(s) ?"))
(setq confirm (acet-ui-message msg "Confirmation" 36))
(if (= confirm 6)
(progn
(scrGen scr_path files_list)
(setq abort nil)
)
(princ "\n*Cancel*")
)
)
)
(if (= abort nil)
(command "_.script" (strcat scr_path "/scrDir"))
)
(princ)
)For anything more sophisticated with a lot more options & features, you'll need some patience, as i'm currently still rewriting my 'script generator'.
