Community
@BIll.gilliss wrote:Is there a similar solution for ILP?
Here's a 'single defun' not very readable
;; ILP3PTS
;; Returns the intersection point between an unbounded line (defined by 2 points)
;; and an unbounded plane (defined by three points).
;;
;; Arguments
;; p1 et p2: two 3d points defining the line
;; p3 p4 p5: three 3d points defining the plane
(defun ilp3pts (p1 p2 p3 p4 p5 / x1 y1 z1 x2 y2 z2 x3 y3 z3 x4 y4 z4 x5
y5 z5 xn yn zn sc pt)
(mapcar 'set
'(x1 y1 z1 x2 y2 z2 x3 y3 z3 x4 y4 z4 x5 y5 z5)
(append p1 p2 p3 p4 p5)
)
(setq xn (- (* (- y4 y3) (- z5 z3)) (* (- y5 y3) (- z4 z3)))
yn (- (* (- z4 z3) (- x5 x3)) (* (- z5 z3) (- x4 x3)))
zn (- (* (- x4 x3) (- y5 y3)) (* (- x5 x3) (- y4 y3)))
)
(if (not
(zerop
(setq
sc (+ (* xn (- x2 x1)) (* yn (- y2 y1)) (* zn (- z2 z1)))
)
)
)
(setq sc (/ (+ (* xn (- x1 x3)) (* yn (- y1 y3)) (* zn (- z1 z3)))
sc
)
pt (list
(+ (* sc (- x1 x2)) x1)
(+ (* sc (- y1 y2)) y1)
(+ (* sc (- z1 z2)) z1)
)
)
)
)
The same thing 'factorised' for a better readability
;; DotProduct
;; Returns the dot product (scalar product) of two vectors
;;
;; Arguments: two vectors
(defun DotProduct (v1 v2) (apply '+ (mapcar '* v1 v2)))
;; CrossProduct
;; Returns the cross product of two vectors
;;
;; Arguments: two vectors
(defun CrossProduct (v1 v2)
(list (- (* (cadr v1) (caddr v2)) (* (caddr v1) (cadr v2)))
(- (* (caddr v1) (car v2)) (* (car v1) (caddr v2)))
(- (* (car v1) (cadr v2)) (* (cadr v1) (car v2)))
)
)
;; ILP
;; Returns the intersection point between an unbounded line (defined by 2 points)
;; and an unbounded plane (defined by a point and a normal vector).
;;
;; Arguments
;; p1 and p2 : two points lying on the line
;; org : a point lying on the plane
;; nor : the plane normal vector
(defun ilp (p1 p2 org nor / scl)
(if (and
(/= 0 (setq scl (DotProduct nor (mapcar '- p2 p1))))
(setq scl (/ (DotProduct nor (mapcar '- p1 org)) scl))
)
(mapcar (function (lambda (x1 x2) (+ (* scl (- x1 x2)) x1)))
p1
p2
)
)
)
;; ILP3PTS
;; Returns the intersection point between an unbounded line (defined by 2 points)
;; and an unbounded plane (defined by three points).
;;
;; Arguments
;; p1 et p2: two 3d points defining the line
;; p3 p4 p5: three 3d points defining the plane
(defun ilp3pts (p1 p2 p3 p4 p5)
(ilp p1 p2 p3 (CrossProduct (mapcar '- p4 p3) (mapcar '- p5 p3)))
)
I use a similar process for detecting welded connections between pipe components. Not only do I find it faster to work on the (car...) of the list instead of stepping an (nth...) index through it, I find the code easier to follow as well.
----------------------------------
If you are going to fly by the seat of your pants, expect friction burns.
"I don't know" is the beginning of knowledge, not the end.
If you are going to fly by the seat of your pants, expect friction burns.
"I don't know" is the beginning of knowledge, not the end.
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
