Community
I got this nice little lisp from http://autocadtips.wordpress.com/2012/03/12/add-leader-to-text-make-multileader/
(defun c:mt2ml ( / oobj nobj nstrg)
(vl-load-com)
(setq oobj (vlax-ename->vla-object (car (nentsel "\nSelect source text: "))))
(if (= (vlax-get-property oobj 'ObjectName) "AcDbMText")
(setq nstrg (vlax-get-property oobj 'TextString))
(exit)
)
(command "_MLEADER")
(while (= 1 (logand (getvar "CMDACTIVE") 1)) (command PAUSE))
(setq nobj (vlax-ename->vla-object (entlast)))
(if (= (vlax-get-property nobj 'ObjectName) "AcDbMLeader")
(vlax-put-property nobj 'TextString nstrg)
(exit)
)
(entdel (vlax-vla-object->ename oobj))
(princ)
)
It converts MText to a Multileader.
For my purposes, it would be great to add a couple of features to this. Can anyone help me please? I understand Latin and Greek better than Lisp. Thanks.
My goals would be as follows:
- The multileader should end up on the same layer as the Mtext. (Currently it uses the current layer.)
- The multileader should hold the same rotation as the Mtext. (Currently it goes to zero.)
- The multileader should be created in the same location as the Mtext, without the user having to click. (Currently the multileader is created wherever the user clicks.)
- The multileader should be created without a leader. We can add one afterwards if needed, but for many we don't need a leader. (We're just using the object as mtext with a box around it.)
Thanks for any pointers or help. Please let me know if some of my goals are unreasonable.
Mark Green
Working on Civil 3D in Canada
Well, to be honest, last time I was looking over my colleague's shoulder while I got him to test it out. So I went and tried it for myself.
I watched the prompts. You are asked to select a leader. I tried selecting one, or I tried skipping past it and clicking points for a leader. Either way, it glitches. It asks me to enter text. Whether I try to type something or not, it won't proceed correctly. It does not automatically enter the text I selected; rather it asks me to enter the text, but at the same time does not actually allow me to do so. I hit enter a few times to get it to proceed, and it will create a multileader object, with just a leader and no text. I think if you hit enter and don't pick a leader or pick points for a leader, you don't even get the multileader object at all, which is what was happening to my coworker.
Win 7 Pro, 32 bit; Intel Core i5 @ 2.80GHz; 4GB RAM
Civil 3D 2013, SP2, 32 bit
Mark Green
Working on Civil 3D in Canada
Thanks for your efforts, seriously. I did put my spec's at the end of my last message, but here it is again: Civil 3D 2013, SP2, 32 bit.
Unfortunately, it is still not working. It did work one time (and changed the text height, which was weird) but now it won't anymore, even on the same piece of text that it did work on. It is hitting the same error:
Enter text: ; error: Automation Error. Description was not provided.
It is creating a multileader, with no text (just the dog-leg as you call it). The edits you've made are working: it is on the right layer and orientation. But there is no text.
Here is a look at when the error happens. It is asking me to enter text, but it doesn't permit me to do so. So I have to Cancel out and leave the command.
Incidentally, it leaves the current layer on the layer of the object I was editing. Perhaps this is due to canceling the command without completing it.
Mark Green
Working on Civil 3D in Canada
Here is a very rough draft of a program to generate MLeaders from a selection of MText.
The program will use the current MLeader Style at the time of running the program, and will adhere to the MText height, rotation & all other standard properties (such as Layer / Color / Linetype / Lineweight etc.), and should also be compatible with MText with any justification.
;; MText to MLeader (with no Leader)
;; Lee Mac - 2013-11-19
(defun c:mt2ml ( / e h i j m r s w )
(if (setq s (ssget "_:L" '((0 . "MTEXT"))))
(repeat (setq i (sslength s))
(setq e (entget (ssname s (setq i (1- i))))
r (cdr (assoc 50 e))
w (cdr (assoc 42 e))
h (cdr (assoc 43 e))
j (cdr (assoc 71 e))
)
(if
(and
(setq m
(entmakex
(append
'(
(000 . "MULTILEADER")
(100 . "AcDbEntity")
(100 . "AcDbMLeader")
)
(mapcar
'(lambda ( x ) (cond ((assoc (car x) e)) ( x )))
'(
(008 . "0")
(006 . "BYLAYER")
(039 . 0.0)
(062 . 256)
(048 . 1.0)
(370 . -1)
)
)
(list
'(300 . "CONTEXT_DATA{")
(cons 041 (cdr (assoc 40 e)))
(assoc 010 e)
'(290 . 1)
(cons 304 (cdr (assoc 1 e)))
(list 111 (cos r) (sin r) 0.0)
(list 112
(cos (+ r (/ pi 2.0)))
(sin (+ r (/ pi 2.0)))
0.0
)
'(301 . "}")
(cons 090 (+ 1024 65536 262144))
)
)
)
)
(setq m (entget m))
(entmod
(subst
(cons 12
(mapcar '+
(mxv
(list
(list (cos r) (sin (- r)) 0.0)
(list (sin r) (cos r) 0.0)
'(0.0 0.0 1.0)
)
(list
(cond
((member j '(2 5 8)) (/ w -2.0))
((member j '(3 6 9)) (- w))
(0.0)
)
(cond
((member j '(4 5 6)) (/ h 2.0))
((member j '(7 8 9)) h)
(0.0)
)
0.0
)
)
(cdr (assoc 10 e))
)
)
(assoc 12 m)
m
)
)
)
(entdel (cdr (assoc -1 e)))
)
)
)
(princ)
)
;; Matrix x Vector - Vladimir Nesterovsky
;; Args: m - nxn matrix, v - vector in R^n
(defun mxv ( m v )
(mapcar '(lambda ( r ) (apply '+ (mapcar '* r v))) m)
)
(princ)
Note that the above is only compatible with MText residing in the WCS plane.
I hope this helps.
Lee
@troma wrote:
Lee, that's great!
Your comment crossed mine, so I didn't even notice it until I came back here an hour later. Very smooth.
Excellent, thank you troma - it was an interesting one to write 
@Lee_Mac wrote:
Here is a very rough draft of a program to generate MLeaders from a selection of MText.
The program will use the current MLeader Style at the time of running the program, and will adhere to the MText height, rotation & all other standard properties (such as Layer / Color / Linetype / Lineweight etc.), and should also be compatible with MText with any justification.
...
Lee
Hi @Lee_Mac I just wanted to share a funny story.
After running this lisp pretty often for the last year or so, today is the first time I hit a snag. The converted object disappeared! I couldn't find it with zoom extents, and the previous selection set yielded no objects. Where could it be going? Frozen layer, UCS...?
Nope. Just me. I had forgotten to check my current MLeader Style. The current one was using a block as the leader object, not mtext. So I guess the mtext converted to a mleader with no leader and no mtext. That's the weirdest way of erasing something I can think of! 
Mark Green
Working on Civil 3D in Canada
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
