Community
The following program is only a quick draft but should join all collinear lines found in a selection, whilst retaining all properties of the original lines:
;; Join Lines - Lee Mac
;; Joins collinear lines in a selection, retaining all original properties.
(defun c:joinlines ( / process e i l s x )
(defun process ( l / x r )
(if (setq x (car l))
(progn
(foreach y (cdr l)
(if (vl-every '(lambda ( a ) (apply 'LM:collinear-p (cons a (cdr x)))) (cdr y))
(setq x (cons (car x) (LM:furthestapart (append (cdr x) (cdr y)))))
(setq r (cons y r))
)
)
(entmake (append (car x) (mapcar 'cons '(10 11) (cdr x))))
(process r)
)
)
)
(if (setq s (ssget "_:L" '((0 . "LINE"))))
(process
(repeat (setq i (sslength s))
(setq e (ssname s (setq i (1- i)))
x (entget e)
e (entdel e)
l (cons (list x (cdr (assoc 10 x)) (cdr (assoc 11 x))) l)
)
)
)
)
(princ)
)
;; Furthest Apart - Lee Mac
;; Returns the two points furthest apart in a given list
(defun LM:furthestapart ( lst / di1 di2 pt1 rtn )
(setq di1 0.0)
(while (setq pt1 (car lst))
(foreach pt2 (setq lst (cdr lst))
(if (< di1 (setq di2 (distance pt1 pt2)))
(setq di1 di2
rtn (list pt1 pt2)
)
)
)
)
rtn
)
;; Collinear-p - Lee Mac
;; Returns T if p1,p2,p3 are collinear
(defun LM:Collinear-p ( p1 p2 p3 )
(
(lambda ( a b c )
(or
(equal (+ a b) c 1e-8)
(equal (+ b c) a 1e-8)
(equal (+ c a) b 1e-8)
)
)
(distance p1 p2) (distance p2 p3) (distance p1 p3)
)
)
(princ)
If two or more collinear lines hold differing properties, the resulting joined line will inherit the properties of an arbitrary line from the set of collinear lines.
The program should perform successfully in all UCS & views and with 3D collinear lines.
Right now i am satisified with this code
i just want something extra looks like similar but different which is making lisp draw line between two lines when making window selection
i put here in this post
@jsuryakanth wrote:
....I want to combine multiple grids each other in this case i want to join all boundary lines,polyline,3D polylines with the same layer. Is there any lisp tool is available please let me know.
....
Try this.
[EDIT: I haven't downloaded it and tried it, so I don't know whether it will do 3DPolylines. If it works with PEDIT and the Join option, in my version here that won't work with 3DPolylines, but something else could be done to connect them.]
Kent Cooper, AIA 
@Tom2023 wrote:
...
(set s2 (ssget ":L" ' ((0 . "INSERT"))))
(command "erase" s2 " ")
....
Does it work if you remove the extraneous spaces? I see two that should not be there, in the upper line between the apostrophe and the left parenthesis, and in the lower line between the double-quotes at the end.
Kent Cooper, AIA
@Tom2023 wrote:
Thank you for the reply Kent1Cooper. Unfortunately, I still have to do the Selection Window twice.
....
(if (setq s2 (ssget ":L"'((0 . "INSERT"))))
....(if (setq s (ssget "_:L" '((0 . "LINE"))))
....
Well, now that you show the whole thing, of course you need two selections if you have two (ssget) functions that don't include one of the modes that applies itself without User selection.
Try this approach that selects both kinds of things together, then goes through and eliminates any Blocks before processing the Lines [untested]. Leave everything before your ;;;;; MODIFIED line, and everything after the (process line, and replace what's between with this:
(if (setq s (ssget ":L" '((0 . "LINE,INSERT"))))
(repeat (setq n (sslength s)); then
(setq ent (ssname s (setq n (1- n))))
(if (member '(0 . "INSERT") (entget ent))
(progn ; then
(ssdel ent s); remove from selection set
(entdel ent); and from drawing
); progn
); if
); repeat
); if
(if s ; anything left? [will be LINEs]
(process
.....
Kent Cooper, AIA
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
