Community
Hi John,
Are you able to upload a sample drawing containing an example of such an overlapping dimension?
Thanks John -
The following is only a quick draft (and may be slow!), but should hopefully perform as required:
;; Dimension Overlap - Lee Mac
;; Detects overlapping linear dimensions and moves the dimension to a separate layer
(defun c:dimoverlap ( / dm1 dm2 enx g10 g13 g14 idx int lst sel tmp vec )
(if
(setq sel
(ssget "_X"
(list
'(0 . "DIMENSION")
'(-4 . "<OR")
'(70 . 000)
'(70 . 032)
'(70 . 064)
'(70 . 096)
'(70 . 128)
'(70 . 160)
'(70 . 192)
'(70 . 224)
'(-4 . "OR>")
(if (= 1 (getvar 'cvport))
(cons 410 (getvar 'ctab))
'(410 . "Model")
)
)
)
)
(progn
(repeat (setq idx (sslength sel))
(setq enx (entget (ssname sel (setq idx (1- idx))))
g10 (cdr (assoc 10 enx))
g13 (cdr (assoc 13 enx))
g14 (cdr (assoc 14 enx))
vec (mapcar '- g10 g14)
int (inters
g10 (mapcar '+ g10 (list (- (cadr vec)) (car vec) 0.0))
g13 (mapcar '+ g13 vec)
nil
)
lst (cons (list g10 int enx) lst)
)
)
(while (setq dm1 (car lst))
(setq lst (cdr lst)
tmp lst
)
(while
(not
(or (null (setq dm2 (car tmp)))
(
(lambda ( / x y )
(if
(vl-some
(function
(lambda ( a b c d / e f )
(if (setq f (equal a c 1e-3))
(progn
(setq e (distance b d))
(or (setq x (< e (distance a b)))
(setq y (< e (distance c d)))
)
)
)
f
)
)
(list (car dm1) (car dm1) (cadr dm1) (cadr dm1))
(list (cadr dm1) (cadr dm1) (car dm1) (car dm1))
(list (car dm2) (cadr dm2) (car dm2) (cadr dm2))
(list (cadr dm2) (car dm2) (cadr dm2) (car dm2))
)
(if (or x y)
(
(lambda ( e )
(entmod
(subst
'(8 . "DIMOVERLAP")
(assoc 8 (caddr e))
(caddr e)
)
)
t
)
(if x dm1 dm2)
)
)
)
)
)
)
)
(setq tmp (cdr tmp))
)
)
)
)
(princ)
)
The above processes only Linear Dimensions and assumes all dimensions reside in the WCS X-Y plane
- that's all I have time for I'm afraid.
Give it a try and let me know how you get on 
You're very welcome John, it was an interesting program to write
I'm unaware of any formal training available online or elsewhere (perhaps you might need to contact your local Autodesk representative?), but I would personally recommend learning the very basics of AutoLISP (such as the syntax and basic functions) from free online tutorials, and then progress with your learning through many hours of practice and through feedback and information received from the forums.
As a side-note, be sure to mark my post as the solution (if you are satisfied) so that the thread is marked as resolved.
I haven't had much time to look back over this, but try the following code:
;; Dimension Overlap - Lee Mac
;; Detects overlapping linear dimensions and moves the dimension to a separate layer
(defun c:dimoverlap ( / *error* cn1 cn2 )
(defun *error* ( msg )
(LM:endundo (LM:acdoc))
(if (not (wcmatch (strcase msg t) "*break,*cancel*,*exit*"))
(princ (strcat "\nError: " msg))
)
(princ)
)
(setq cn1 0
cn2 0
)
(LM:startundo (LM:acdoc))
(vlax-for blk (vla-get-blocks (LM:acdoc))
(if (= :vlax-false (vla-get-isxref blk))
(if (= :vlax-true (vla-get-islayout blk))
(setq cn1 (+ cn1 (processblock blk)))
(setq cn2 (+ cn2 (processblock blk)))
)
)
)
(if (< 0 cn2)
(vla-regen (LM:acdoc) acallviewports)
)
(if (< 0 (+ cn1 cn2))
(princ
(strcat
"\n"
(itoa (+ cn1 cn2))
" overlapping dimension"
(if (= 1 cnt) "" "s")
" found."
(if (< 0 cn2)
(strcat
"\n"
(itoa cn2)
(if (= 1 cn2) " was in a block." " were in blocks.")
)
""
)
)
)
(princ "\nNo overlapping dimensions were found.")
)
(LM:endundo (LM:acdoc))
(princ)
)
(defun processblock ( blk / cnt dm1 dm2 enx g10 g13 g14 int lst tmp vec )
(vlax-for obj blk
(if (= "AcDbRotatedDimension" (vla-get-objectname obj))
(setq enx (entget (vlax-vla-object->ename obj))
g10 (cdr (assoc 10 enx))
g13 (cdr (assoc 13 enx))
g14 (cdr (assoc 14 enx))
vec (mapcar '- g10 g14)
int (inters
g10 (mapcar '+ g10 (list (- (cadr vec)) (car vec) 0.0))
g13 (mapcar '+ g13 vec)
nil
)
lst (cons (list g10 int enx) lst)
)
)
)
(setq cnt 0)
(while (setq dm1 (car lst))
(setq lst (cdr lst)
tmp lst
)
(while
(not
(or (null (setq dm2 (car tmp)))
(
(lambda ( / x y )
(if
(vl-some
(function
(lambda ( a b c d / e f )
(if (setq f (equal a c 1e-3))
(progn
(setq e (distance b d))
(or (setq x (< e (distance a b)))
(setq y (< e (distance c d)))
)
)
)
f
)
)
(list (car dm1) (car dm1) (cadr dm1) (cadr dm1))
(list (cadr dm1) (cadr dm1) (car dm1) (car dm1))
(list (car dm2) (cadr dm2) (car dm2) (cadr dm2))
(list (cadr dm2) (car dm2) (cadr dm2) (car dm2))
)
(if (or x y)
(
(lambda ( e )
(entmod
(subst
'(8 . "DIMOVERLAP")
(assoc 8 (caddr e))
(caddr e)
)
)
(setq cnt (1+ cnt))
)
(if x dm1 dm2)
)
)
)
)
)
)
)
(setq tmp (cdr tmp))
)
)
cnt
)
;; Start Undo - Lee Mac
;; Opens an Undo Group.
(defun LM:startundo ( doc )
(LM:endundo doc)
(vla-startundomark doc)
)
;; End Undo - Lee Mac
;; Closes an Undo Group.
(defun LM:endundo ( doc )
(while (= 8 (logand 8 (getvar 'undoctl)))
(vla-endundomark doc)
)
)
;; Active Document - Lee Mac
;; Returns the VLA Active Document Object
(defun LM:acdoc nil
(eval (list 'defun 'LM:acdoc 'nil (vla-get-activedocument (vlax-get-acad-object))))
(LM:acdoc)
)
(vl-load-com) (princ)
Thanks John
My apologies, I had received your earlier message, but hadn't had a chance to respond 
@Johnw wrote:Good morning Lee, I left you my email address in the private message I sent you. When you have a moment can you look the message and email me your response to the questions I put forth? Thanks, John
Hi John,
I thought I replied to your message yesterday, but perhaps the message didn't reach you - no problem though, I shall forward my response to the email address you provided.
Cheers,
Lee
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
