last saved version button

[ewcler]

I often share dwg files with other departments, customers, and vendors.  And from time to time, I have had issues with the autocad version that was used to create/modify a file is of a later version than someone downstream can handle.  We deal with several non-autocad uses of dwg information (like mastercam, and trumpf laser cutting software etc...)

Is there a way to see what version of autocad created or modified a particular document other than opening a *.dwg file with notepad?  I was thinking that there might be a simple lisp routine that might get the job done.  Any thoughts would be appreciated.

[Kent1Cooper]

---

@ewcler wrote:

....Is there a way to see what version of autocad created or modified a particular document...?  I was thinking that there might be a simple lisp routine that might get the job done.  Any thoughts would be appreciated.

---

I'm not sure you can get at the information once in the drawing, to extract it with Lisp or something rather than look at it on-screen, or find it without opening the drawing.  But if you just want to "see" it, when I open drawings, the very first thing at the top of the Text Screen is always:

Opening an AutoCAD XXXX format file.

[Lee_Mac]

Here is my function:

(defun c:getversion ( / f v )
    (if
        (and
            (setq f (open (strcat (getvar 'dwgprefix) (getvar 'dwgname)) "r"))
            (setq v
                (cdr
                    (assoc (strcase (substr (read-line f) 1 6))
                       '(
                            ("AC1024" . "2010-2012")
                            ("AC1021" . "2007-2009")
                            ("AC1018" . "2004-2006")
                            ("AC1015" . "2000-2002")
                            ("AC1014" . "Release 14")
                            ("AC1012" . "Release 13")
                            ("AC1009" . "Release 11/12")
                            ("AC1006" . "Release 10")
                            ("AC1004" . "Release 9")
                            ("AC1003" . "Release 2.60")
                            ("AC1002" . "Release 2.50")
                            ("AC1001" . "Release 2.22")
                            ("AC2.22" . "Release 2.22")
                            ("AC2.21" . "Release 2.21")
                            ("AC2.10" . "Release 2.10")
                            ("AC1.50" . "Release 2.05")
                            ("AC1.40" . "Release 1.40")
                            ("AC1.2"  . "Release 1.2")
                            ("MC0.0"  . "Release 1.0")
                        )
                    )
                )
            )
        )
        (princ (strcat "\nThis is an AutoCAD " v " format file."))
        (princ "\nThe format of this file could not be determined.")
    )
    (if f (close f))
    (princ)
)

Release codes taken from here.

[ewcler]

I tried that and found it to work just as you said.  However, it requires me to open each file individially.  I guess I am looking for something that can be applied in a more robust manner.  Ideally, added to the plot stamp, or title block etc...

[ewcler]

Lee, 

I think this is the kind of thing I was looking for.  I'll try it out this afternoon.

[M_Hensley]

If you install Autodesk's free program DWGTrueView it has a batch convert command. You can select many files to convert and it lists the current version beside each filename. You can look at what version each file is, remove the ones that are already the correct version, then batch convert the ones that are not.

[Lee_Mac]

---

@ewcler wrote:

Lee, 

I think this is the kind of thing I was looking for.  I'll try it out this afternoon.

---

Excellent, let me know how you get on