How to get rid a NIL from a LIST.

[devitg]

(setq sysvar-list(list (if (getvar "osmode")
        "osmode")
      (if (getvar "3dosmode")
        "3dosmode")
      (if (getvar "cmdecho")
        "cmdecho")
      (if (getvar "orthomode")
        "orthomode")
      (if (getvar "clayer")
        "clayer")))

 For a given acad version , it will return 

("osmode" nil "cmdecho" "orthomode" "clayer")

 I need it to be as follow 

("osmode" "cmdecho" "orthomode" "clayer")

 Thanks in advance

[hmsilva]

(setq lst '("osmode" "3dosmode" "cmdecho" "cmdecho" "clayer"))
(foreach l lst
(if (getvar l)
(setq sysvar-list (cons l sysvar-list))
)
)

HTH
Henrique

[Lee_Mac]

(setq sysvar-list (vl-remove-if-not 'getvar '("osmode" "3dosmode" "cmdecho" "orthomode" "clayer")))

[devitg]

Thanks you both for the answer to my original post , it work as spected. But if I want to get rid of a a NIL at any list ? (setq list-w-nil (list 123 nil "qwerty" 678 ))

[Ajilal.Vijayan]

---

@devitg wrote:
But if I want to get rid of a a NIL at any list ? (setq list-w-nil (list 123 nil "qwerty" 678 ))

---

Then

(setq list-w-nil (vl-remove nil list-w-nil))

[Lee_Mac]

Or alternatively:

(vl-remove-if 'null <list>)

[hmsilva]

---

@devitg wrote:
Thanks you both for the answer to my original post , it work as spected. But if I want to get rid of a a NIL at any list ? (setq list-w-nil (list 123 nil "qwerty" 678 ))

---

You're welcome, devitg

Another

(setq list-w-nil (list 123 nil "qwerty" 678 ))
(foreach l list-w-nil
  (if l
    (setq list-w-no-nil (cons l list-w-no-nil))
  )
)

HTH

Henrique

[Lee_Mac]

And another few

(defun rem-nil1 ( l )
    (if l (if (car l) (cons (car l) (rem-nil1 (cdr l))) (rem-nil1 (cdr l))))
)

(defun rem-nil2 ( l )
    (apply 'append (mapcar '(lambda ( x ) (if x (list x))) l))
)

(defun rem-nil3 ( l )
    (apply 'append (subst nil '(nil) (mapcar 'list l)))
)

[hmsilva]

---

@Lee_Mac wrote:

And another few

---

As always, fast reasoning...

Nicely coded, Lee.

Henrique

[Lee_Mac]

hmsilva wrote:

Lee_Mac wrote:

And another few

As always, fast reasoning...

Nicely coded, Lee.

Henrique

Thanks Henrique!

[ehsan_bahrani]

hi

thank for your respond

how about removing nil Only from end of list?

for example this is my list:

(12 23 "aa"

15 87 Nil

43 19 "ba"

24 27 "ab"

Nil Nil Nil

Nil Nil Nil)

and i want to remove Nils from end of list. 

[hak_vz · Accepted solution]

---

@ehsan_bahrani wrote:

hi

thank for your respond how about removing nil Only from end of list?

for example this is my list:

'(12 23 "aa" 15 87 Nil 43 19 "ba" 24 27 "ab" Nil Nil Nil Nil Nil Nil)and i want to remove Nils from end of list. 

---

(setq a '(12 23 "aa" 15 87 Nil 43 19 "ba" 24 27 "ab" Nil Nil Nil Nil Nil Nil))
(setq a (reverse a))
(while (not (car a)) (setq a (cdr a)))
(setq a (reverse a))

;-->  (12 23 "aa" 15 87 nil 43 19 "ba" 24 27 "ab")