Community
I have a drawing with dimensions and number (number and text number). I want ouput (Can select or Automatic) to a file excel. Please, write a lisp do.
Thank you very much.
I want ouput to excel the same this picture.
@minhphuong.humg wrote:
I have a drawing with dimensions and number (number and text number). I want ouput (Can select or Automatic) to a file excel. Please, write a lisp do.
Thank you very much.
...
minhphuong.humg,
this quick and dirty code will create a .csv file, in the dwg directory with the same name, try it, is minimally tested...
(defun c:test (/ *error* a b c file line)
(defun *error* (msg)
(if file
(close file)
)
(vl-cmdf "regen")
(cond ((not msg))
((member msg '("Function cancelled" "quit / exit abort")))
((princ (strcat "\n** Error: " msg " ** ")))
);; cond
(princ)
);; *error*
(setq file (open (strcat (getvar "dwgprefix")
(vl-filename-base (getvar "dwgname"))
".csv"
)
"w"
)
)
(while
(and (not (prompt "\n<<< Select the number >>>"))
(setq a (ssget "_+.:E:S" '((0 . "TEXT"))))
(not (redraw (ssname a 0) 3))
(not (prompt "\n<<< Select the reference >>>"))
(setq b (ssget "_+.:E:S" '((0 . "TEXT"))))
(not (redraw (ssname b 0) 3))
(not (prompt "\n<<< Select the length >>>"))
(setq c (ssget "_+.:E:S" '((0 . "TEXT"))))
(not (redraw (ssname c 0) 3))
);; and
(setq line (strcat (cdr (assoc 1 (entget (ssname a 0))))
"\t"
(cdr (assoc 1 (entget (ssname b 0))))
"\t"
(cdr (assoc 1 (entget (ssname c 0))))
)
)
(write-line line file)
);; while
(close file)
(*error* nil)
(princ)
);; test
HTH
Henrique
@devitg wrote:
Hi Enrique at
(not (prompt "\n<<< Select the length >>>")) (setq c (ssget "_+.:E:S" '((0 . "TEXT"))))
The lenght is not a TEXT , it is a Aligned Dimension.
Gabriel,
thanks, you are correct, I was with an open dwg posted by Patcy at
when the same OP start this thread, so I thought that was the same dwg, my bad...
So here's the revised code:
(defun c:test (/ *error* a b c file line)
(defun *error* (msg)
(if file
(close file)
)
(vl-cmdf "regen")
(cond ((not msg))
((member msg '("Function cancelled" "quit / exit abort")))
((princ (strcat "\n** Error: " msg " ** ")))
);; cond
(princ)
);; *error*
(setq file (open (strcat (getvar "dwgprefix")
(vl-filename-base (getvar "dwgname"))
".csv"
)
"w"
)
)
(while
(and (not (prompt "\n<<< Select the number >>>"))
(setq a (ssget "_+.:E:S" '((0 . "TEXT"))))
(not (redraw (ssname a 0) 3))
(not (prompt "\n<<< Select the reference >>>"))
(setq b (ssget "_+.:E:S" '((0 . "TEXT"))))
(not (redraw (ssname b 0) 3))
(not (prompt "\n<<< Select the length >>>"))
(setq c (ssget "_+.:E:S" '((0 . "DIMENSION"))))
(not (redraw (ssname c 0) 3))
);; and
(setq line (strcat (cdr (assoc 1 (entget (ssname a 0))))
"\t"
(cdr (assoc 1 (entget (ssname b 0))))
"\t"
(rtos (cdr (assoc 42 (entget (ssname c 0)))) 2 0)
)
)
(write-line line file)
);; while
(close file)
(*error* nil)
(princ)
);; test
Henrique
I think the csv file should open on 'append' mode than 'write' mode.
Hence OP can continue selection and csv file gets updated.
(setq file (open (strcat (getvar "dwgprefix") (vl-filename-base (getvar "dwgname")) ".csv" ) "a" ) )
| 
| 
@Ajilal.Vijayan wrote:
I think the csv file should open on 'append' mode than 'write' mode.
Hence OP can continue selection and csv file gets updated.
(setq file (open (strcat (getvar "dwgprefix") (vl-filename-base (getvar "dwgname")) ".csv" ) "a" ) )
Agree!
It's a good idea using the "append" insted of "write", we can also give OP the chance to choose the output file name, and... but it is just a demo, let's wait the OP feedback.
Henrique
Thank my friends (hmsilva, devitg, ajilal.vijayan). Special, lisp's devitg very very good with the simplest case (my drawing upload). However, I must do work very hard. It's complexer than you think.
With drawings (attach) complex I must pick each object from autocad to excel. Very long with drawing complex.
My friends, please help me write lisp (can select dimension (pick), select other text (select window or pick)) to output as image attach. Mr. hmsilva, devitg, ajilal.vijayan please help me!
Really, thank my friends very much.
P/S: Can you give me solutions that work fast to have results like that?
The attached drawing looks 'complex'
As you wait for the lisp routine in here,
Can I suggest something that will make your work more easier in future ?
I think you should start creating Dynamic block with attributes for this kind of job.
So for an external output you can use DATAEXRACTION command.
@devitg wrote:
Forma parte de una defun básica
It is par of a basic DEFUN
(IF (= (CAR (MEMBER "acetutil.arx" (ARX))) "acetutil.arx") (PRINC (STRCAT "acetutil.arx" " esta cargado")) (PROGN (ARXLOAD "acetutil.arx" "no se cargo") (PRINC (STRCAT "acetutil.arx" "..se ha cargado")) ) )No tiene implicancias en el lisp
It have no implied action on the LISP
Gabriel,
only commented the command line echo... 
Henrique
minhphuong.humg,
it is a good practice, when asking for help, provide the maximum of information possible, to ensure that the person who try to helps us, is not wasting time...
First - we all, are using our free time to help other people who have more difficulties than we!
Second - you should consider the ajilal.vijayan advice as a good practice for future jobs like this, using Dynablocks, Attributes and the DATAEXRACTION command, the excel spreadsheet would be automatically created!
Third - let's see what we can get, working together, if you are interested...
Starting, at your "complex.dwg" and at the image you attached, there are some coffers with no name, this is a possible situation, or is just a failure?
Henrique
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
