From text to layout to block

Anonymous · ‎11-25-2014

Hi,

I m looking for a lisp where you can pick or draw a selection box around a text (single line) , connects that text value to a keyword, and then create a layout with that keyword as layoutname. some basic lisp tryouts would be great. Also some lisp to insert a block in that layout + input from the attributes in that block would be great. the block can be placed with basepoint. if you got pieces i can try and learn how to merge them.

Thanks!

paullimapa · ‎11-25-2014

Doing a google for "lisp to draw box around text" you'll find this link to draw a box around selected Text object:

http://forums.augi.com/showthread.php?51455-LISP-to-place-a-box-around-text

Use following code to get text string:

(setq en(car(entsel"\nSelect Text:")))

(setq ed(entget en))

(setq txt(cdr(assoc 1 ed)))

Then doing a google search "lisp to rename current layout name" you'll find a number of links on changing the layout tab name:

https://autocadtips.wordpress.com/2012/02/16/autolisp-select-text-rename-layout-tab/

Paul Li
IT Specialist
@The Office
Apps & Publications | Video Demos

Anonymous · ‎11-26-2014

hey, with box, i meant crossing, now im trying with a new crossing, but i m wondering what do i need to put in if the coordinates of the crossing are nog changeable.

that's what i got, but i got a error too few arguments

(vl-load-com)

(DEFUN C:NLay (/)
  (prompt "\nSelect Objects by Window")
  (setq p1
	 (getpoint "\nFirst Corner: "))
  (setq p2
	 (getpoint p1 "\nSecond Corner: "))
  (setq v1
	 (ssget "C" p1 p2 '((0 . "TEXT" ))))
  (setq layout
	 (cdr
	   (assoc 1 (entget (ssname v1 0)))))
  (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
  (setq oLayouts (vla-get-layouts acDoc))

  (if (vl-position (setq layoutName layout))
    (setq oLayout (vla-item oLayouts layoutName))
    (setq oLayout (vla-add oLayouts layoutName)))

  (vla-put-stylesheet oLayout "ABICON BEK STB.ctb")
  (cond ((findfile (strcat (getenv "PrinterConfigDir") "\\DWG To PDF.pc3"))
	  (vla-put-configname oLayout "DWG To PDF.pc3"))
	 (vla-put-configname oLayout )
	 (vla-put-canonicalmedianame oLayout "ISO_full_bleed_A3_(420.00_X_297.00_MM)")

	 (if (/= layoutName (getvar 'ctab))
	  (setvar 'ctab layoutName))

	 (princ))
  )

hmsilva · ‎11-26-2014

Something like this, perhaps

(DEFUN C:NLay (/ ACDOC LAYOUT OLAYOUT OLAYOUTS P1 P2 V1)
  (prompt "\nSelect Objects by Window")
  (if (and (setq p1 (getpoint "\nFirst Corner: "))
           (setq p2 (getcorner p1 "\nSecond Corner: "))
      )
    (progn
      (command "_.zoom" p1 p2)
      (setq v1 (ssget "C" p1 p2 '((0 . "TEXT"))))
      (command "_.zoom" "_P")
      (if v1
        (progn
          (setq layout (cdr (assoc 1 (entget (ssname v1 0)))))
          (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
          (setq oLayouts (vla-get-layouts acDoc))

          (if (vl-position layout (layoutlist))
            (setq oLayout (vla-item oLayouts layout))
            (setq oLayout (vla-add oLayouts layout))
          )

          (vla-put-stylesheet oLayout "ABICON BEK STB.ctb")
          (cond ((findfile (strcat (getenv "PrinterConfigDir") "\\DWG To PDF.pc3"))
                 (vla-put-configname oLayout "DWG To PDF.pc3")
                 (vla-put-canonicalmedianame
                   oLayout
                   "ISO_full_bleed_A3_(420.00_X_297.00_MM)"
                 )

                 (if
                   (/= layout (getvar 'ctab))
                    (setvar 'ctab layout)
                 )
                )
          )
        )
      )
    )
  )
  (princ)
)

EDIT: as the selection points will be hardcoded, I did add a zoom to the text object, because the ssget function with a selection mode (crossing) requires that the selected object be visible...

Hope that helps

Henrique

Anonymous · ‎11-26-2014

oke that's nice, you nailed, let's expand it a bit now,

try to look for some things today but i m actually not so good at it.

The next problems is:

1 - my block isn't placed. i think it has to do with the attributes, but it is only a hunch, i followed it onto this site

http://forums.augi.com/showthread.php?106834-Insert-block-with-attributes-using-vlisp

but i don't understand that thread

Attribuut "STUKS" will have or should be programmed with a crossing with a extraction of how many textobjects are in that crossing.

Attribuut 'VOLUME" should be extraced from a text in modelspace

rest is referend to dwgprops or other attributes.

attributes are :

Enter attribute values
PROJECTNAAM? <ABICON>:
BOUWPLAATS? <TIELT>:
AFK.E.1.1 <AFK.Model>:
STUKS? <1>:
VOLUME? <0>:
GEWICHT? <0>:
BEK_TEKENAAR? <DB>:
BEK_AANMAAKDATUM? <---->:
BEK_PROJECT/ELEMENT/B? <0000/Model/B>:
WAP_TEKENAAR? <DB>:
WAP_AANMAAKDATUM? <---->:
WAP_PROJECT/ELEMENT/B? <0000/Model/W>:
BEK_A_INDEX? <---->:
BEK_A_DATUM? <---->:
BEK_B_INDEX? <---->:
BEK_B_DATUM? <---->:
BEK_C_INDEX? <---->:
BEK_C_DATUM? <---->:
BEK_D_INDEX? <---->:
BEK_D_DATUM? <---->:
WAP_A_INDEX? <---->:
WAP_A_DATUM? <---->:
WAP_B_INDEX? <---->:
WAP_B_DATUM? <---->:
WAP_C_INDEX? <---->:
WAP_C_DATUM? <---->:
WAP_D_INDEX? <---->:
WAP_D_DATUM? <---->:
C30/37 <C30/37>:
GB <GB>:
EE2 <EE2>:
S4 <S4>:
16MM <16 mm>:
BETONDEKKING <30 mm>:
VELLINGKANTWAND*X* <VELLINGKANT 1 cm>:
FASE? < >:
FILENAME <R:\Autodesk Standards\Template\STARTBLAD PREFAB VER.3.1.dwt>:
BEK_E_INDEX? <---->:
BEK_E_DATUM? <---->:
WAP_E_INDEX? <---->:
WAP_E_DATUM? <---->:
BIJKOMENDE_INFO:
NIVEAU? <0>:
VOLUME? <0>:
GEWICHT? <0>:
BIJKOMENDE_INFO:
VELLINGKANTWAND*X*FR <CHANFREIN 1 cm>:
Verify attribute values
BIJKOMENDE_INFO:
BIJKOMENDE_INFO:

2 - next line need to be changed in only for the active layout.

(foreach x (layoutlist )

3. block needs to be on layer "4011.Titelhoek"

4. when making that pagesetup, im zoomed in in Paperspace, can i ,after exiting the command, launch a zoom extends on that active layout?

what i now got is:

(defun putPagesetup (document layout setup)
(if (vl-catch-all-error-p (vl-catch-all-apply
(function (lambda () (vla-copyfrom
(vla-item (vla-get-layouts document) layout)
(vla-item (vla-get-plotconfigurations document) setup)
)))))
nil
t
)
)

(vl-load-com)

(DEFUN C:NLay (/ ACDOC LAYOUT OLAYOUT OLAYOUTS P1 P2 V1 titelhoek putpagesetyp)
  (prompt "\nSelect Objects by Window")
  (if (and (setq p1 (getpoint "\nFirst Corner: "))
           (setq p2 (getcorner p1 "\nSecond Corner: "))
      )
    (progn
      (command "_.zoom" p1 p2)
      (setq v1 (ssget "C" p1 p2 '((0 . "TEXT"))))
      (command "_.zoom" "_P")
      (if v1
	(progn
          (setq layout (cdr (assoc 1 (entget (ssname v1 0)))))
          (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
          (setq oLayouts (vla-get-layouts acDoc))

          (if (vl-position layout (layoutlist))
            (setq oLayout (vla-item oLayouts layout))
            (setq oLayout (vla-add oLayouts layout))
          )
          
	  (setq PCFGS (vla-get-plotconfigurations acDoc))
          (foreach x (layoutlist )
	  (putpagesetup acDoc x "A3 PDF KLEUR"))

	  (setq titelhoek (vla-insertblock (vla-get-paperspace acDoc)

			    (vlax-3d-point '(0.0 0.0 0.0))
			    "4011TITELHOEK_BEK_WAP"
			    1 1 1 0
			    )
		       

		)
	  
	  )
	  
	  (if
                   (/= layout (getvar 'ctab))
                    (setvar 'ctab layout)

                )
          )
      )
    )
  (princ)
  )

thanks for support!

can i only choose one solution each topic or can i pick different solutions?

hmsilva · ‎11-26-2014

@Anonymous wrote:

oke that's nice, you nailed, let's expand it a bit now,

try to look for some things today but i m actually not so good at it.

The next problems is:

1 - my block isn't placed. i think it has to do with the attributes, but it is only a hunch, i followed it onto this site

http://forums.augi.com/showthread.php?106834-Insert-block-with-attributes-using-vlisp

but i don't understand that thread

Attribuut "STUKS" will have or should be programmed with a crossing with a extraction of how many textobjects are in that crossing.

Attribuut 'VOLUME" should be extraced from a text in modelspace

rest is referend to dwgprops or other attributes.

Hi Subje,

the AlanJT's codes are to vla-insert a block and fill the attributes values from a supplied list with those values.

I do not understand how it is calculated the attribute "STUKS".

The 'VOLUME" is selected by th user?

@Anonymous wrote:

3. block needs to be on layer "4011.Titelhoek"

Do the layer "4011.Titelhoek" exists?

@Anonymous wrote:

thanks for support!

can i only choose one solution each topic or can i pick different solutions?

You're welcome.

You can choose multiple solutions, but it would be preferable to acept the solutions only if for you the thread is closed, if not don't mark as solved, to allow others to assist.

(defun putPagesetup (document layout setup)
  (if (vl-catch-all-error-p
        (vl-catch-all-apply
          (function (lambda ()
                      (vla-copyfrom
                        (vla-item (vla-get-layouts document) layout)
                        (vla-item (vla-get-plotconfigurations document) setup)
                      )
                    )
          )
        )
      )
    nil
    t
  )
)

(vl-load-com)

(DEFUN C:NLay (/ ACDOC LAYOUT OLAYOUT OLAYOUTS P1 P2 V1 titelhoek putpagesetyp)
  (prompt "\nSelect Objects by Window")
  (if (and (setq p1 (getpoint "\nFirst Corner: "))
           (setq p2 (getcorner p1 "\nSecond Corner: "))
      )
    (progn
      (command "_.zoom" p1 p2)
      (setq v1 (ssget "C" p1 p2 '((0 . "TEXT"))))
      (command "_.zoom" "_P")
      (if v1
        (progn
          (setq layout (cdr (assoc 1 (entget (ssname v1 0)))))
          (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
          (setq oLayouts (vla-get-layouts acDoc))

          (if (vl-position layout (layoutlist))
            (setq oLayout (vla-item oLayouts layout))
            (setq oLayout (vla-add oLayouts layout))
          )

          (setq PCFGS (vla-get-plotconfigurations acDoc))
          ;(foreach x (layoutlist )
          (putpagesetup acDoc layout "A3 PDF KLEUR")
          (if
            (/= layout (getvar 'ctab))
             (setvar 'ctab layout);; set the currect layout to innsert the block
          )
          (if (setq titelhoek (vla-insertblock
                                (vla-get-paperspace acDoc)
                                (vlax-3d-point '(0.0 0.0 0.0))
                                "4011TITELHOEK_BEK_WAP.dwg";; if not in the dwg, but in a SFS Path need the .dwg
                                1
                                1
                                1
                                0
                              )
                    
              )
        )
        (vla-ZoomExtents (vlax-get-acad-object))
      )
    )
  )
  (princ)
)

Henrique

Anonymous · ‎11-27-2014

hey,

i had to change some functions cause it didn't do anything with me. block wasn't show.

Now i get the block etc.

Some more things to develop:

- imagine that the selected text has a value of "Test.TEXT.1.1"

In my drawing prop there's a attribute (AFK ELEMENT) that already defined as "test". so basically, i want to pull that "Test"+ "." out of the defined attribuut "current layout" with the help of that attribute before he makes that layout. is that possible? text in modelspace needs to be unchanged.

maybe this will do a trick?

(setq Afkelement (vlax-get-Property doc 'AFK ELEMENT)) but the vla's to subtract i don't know.

- i will come back for the layer for the block, gonna explore it en try to master it :D. he is a standard layer in my template.

- "Stuks" will be again a crossing who's selects some textobjects en then counts how many text object there are. That count need to be placed in modelspace as text on specified coordinates.

- Volume will be a text made with anouther lisp, in the far future, but the meaning is to extract that text and put it in the box, the only thing that can be used are the coordinates from that text. so again with a selection i suppose?

- after the zoom extends, i m still in paperspace, can i be directly back to modelspace

- later on, in the far future, when we are old and milked from the goverment, i would like to get a pop up where you can select wich lookup for the block, but not for now 😉

that's the last edition:

(vl-load-com)


(defun putPagesetup (doc layout setup)
  (if (vl-catch-all-error-p
        (vl-catch-all-apply
          (function (lambda ()
                      (vla-copyfrom
                        (vla-item (vla-get-layouts doc) layout)
                        (vla-item (vla-get-plotconfigurations doc) setup)
                      )
                    )
          )
        )
      )
    nil
    t
  )
)


(DEFUN C:NLay (/ DOC CURRENTLAYOUT OLAYOUT OLAYOUTS P1 P2 V1 TITELHOEK POINTBLCK PS)
  (prompt "\nSelect Objects by Window")
  (if (and (setq p1 (getpoint "\nFirst Corner: "))
           (setq p2 (getcorner p1 "\nSecond Corner: "))
      )
    (progn
      (command "_.zoom" p1 p2)
      (setq v1 (ssget "C" p1 p2 '((0 . "TEXT"))))
      (command "_.zoom" "_P")
      (if v1
        (progn
          (setq Currentlayout (cdr (assoc 1 (entget (ssname v1 0)))))
          (setq doc (vla-get-activedocument (vlax-get-acad-object)))
          (setq oLayouts (vla-get-layouts doc))

          (if (vl-position Currentlayout (layoutlist))
            (setq oLayout (vla-item oLayouts Currentlayout))
            (setq oLayout (vla-add oLayouts Currentlayout))
          )

	  (setq PCFGS (vla-get-plotconfigurations doc))
	  (putPagesetup doc Currentlayout "A3 PDF KLEUR")

	  (if
            (/= layout (getvar 'ctab))
             (setvar 'ctab Currentlayout);; set the currect layout to insert the block
          )
	  
          (vla-ZoomExtents (vlax-get-acad-object))


	  (vlax-invoke
	    (vlax-get
	      (vla-item
		(vla-get-layouts
		  (vla-get-activedocument
		    (vlax-get-acad-object)))
                                               Currentlayout)
                                         'block)
                                   'InsertBlock
                                   '(0.0 0.0 0.0)
                                   "4011TITELHOEK_BEK_WAP"
                                   1
                                   1
                                   1
                                   0)
	  ;insert block

	    )
	  
	  
	)
      );if extract text
    );if crossing
  (princ)
);defun

hmsilva · ‎11-27-2014

Hi Subje,

to get the AFK ELEMENT:

(setq doc (vla-get-activedocument (vlax-get-acad-object)))
;; to get the "AFK ELEMENT" value...
;; get the summaryInfo object
(setq summaryInfo (vla-get-SummaryInfo doc))
;; get the "AFK ELEMENT" value and set the
;; Afkelement variable with it
(vla-GetCustomByKey suminfo "AFK ELEMENT" 'Afkelement)
;; find the position (base 0) for "." in the string
;; in the Afkelement variable and save it in n variable
(setq n (vl-string-position (ascii ".") Afkelement))
;; create a substring using the n position
;; substr is base 1, we'll need to add 1 to
;; the posicion and as we need to strat our
;; substring in the next character, we'll
;; need to add another 1 to n.
(setq Afkelement (substr Afkelement (+ 2 n)))

To the Stuks:

 (command "_.zoom" px py)
 (setq v2 (ssget "_C" px px '((0 . "TEXT"))))
 (command "_.zoom" "_P")
 (if v2
   (entmake
     (list
       (cons 0 "TEXT")
       (cons 100 "AcDbText")
       (cons 8 "YourLayerName")
       (cons 10 TheInsertionPoint)
       (cons 1 (itoa (sslength v2)));; number of objects in v2
       (cons 100 "AcDbText")
     )
   )
 )

Your NLay code with some mods:

(DEFUN C:NLay (/ ACADO DOC CURRENTLAYOUT OLAYOUT OLAYOUTS P1 P2 V1 TITELHOEK POINTBLCK PS)
  (prompt "\nSelect Objects by Window")
  (if (and (setq p1 (getpoint "\nFirst Corner: "))
           (setq p2 (getcorner p1 "\nSecond Corner: "))
      )
    (progn
      (command "_.zoom" p1 p2)
      (setq v1 (ssget "C" p1 p2 '((0 . "TEXT"))))
      (command "_.zoom" "_P")
      (if v1
        (progn
          (setq Currentlayout (cdr (assoc 1 (entget (ssname v1 0)))))
          (setq acado (vlax-get-acad-object))
          (setq doc (vla-get-activedocument acado))
          (setq oLayouts (vla-get-layouts doc))

          (if (vl-position Currentlayout (layoutlist))
            (setq oLayout (vla-item oLayouts Currentlayout))
            (setq oLayout (vla-add oLayouts Currentlayout))
          )

	  (setq PCFGS (vla-get-plotconfigurations doc))
	  ;(putPagesetup doc Currentlayout "A3 PDF KLEUR")

	  (if
            (/= layout (getvar 'ctab))
             (setvar 'ctab Currentlayout);; set the currect layout to insert the block
          )
	  
          (vla-ZoomExtents acado)

	 (setq blk (vlax-invoke
	    (vlax-get
	      (vla-item
		(vla-get-layouts
		  (vla-get-activedocument
		    (vlax-get-acad-object)))
                                               Currentlayout)
                                         'block)
                                   'InsertBlock
                                   '(0.0 0.0 0.0)
                                   "4011TITELHOEK_BEK_WAP"
                                   1
                                   1
                                   1
                                   0));insert block
          (vla-put-Layer blk "4011.Titelhoek");; change the Layer
          (setvar 'ctab "Model");; put model active
          (vla-ZoomExtents acado);; zoom extents in model

	    );; progn
	  
	  
	);if extract text
      );; progn
    );if crossing
  (princ)
);defun

Henrique

Anonymous · ‎11-27-2014

arh, can't do that layer thingie,

trying now, but nothings seems to work.

(progn
(setq layer (getstring "4011.Titelhoek"))
(command "_change" "cr" -1 -1 1 1 "P" "LA" layer ""))
)

i give up for today, but any good examples for my situation would be great

hmsilva · ‎11-27-2014

@Anonymous wrote:

arh, can't do that layer thingie,

trying now, but nothings seems to work.

(progn
(setq layer (getstring "4011.Titelhoek"))
(command "_change" "cr" -1 -1 1 1 "P" "LA" layer ""))
)

i give up for today, but any good examples for my situation would be great

Look in the last code...

(vla-put-Layer blk "4011.Titelhoek");; change the Layer

Henrique

Anonymous · ‎11-27-2014

Oke. very good

i examined the functions of th AFK element, and i realised that ,after understanding it, that we can do it without the customkey AFK element.

So i did some little changes and put it in the full lisp.

tommorow i will to try to find out where to put the function for "stuks" is it advisable to create another lisp for that and put a link in this lisp?

Look in the last code...

(vla-put-Layer blk "4011.Titelhoek");; change the Layer

Haha idd, found it at that time, mine was more primitief, 😄 command _layer as start, but it's more interesting to try i with your way.

Last working version:

(vl-load-com)

                                                      

(defun putPagesetup (doc layout setup)
  (if (vl-catch-all-error-p
        (vl-catch-all-apply
          (function (lambda ()
                      (vla-copyfrom
                        (vla-item (vla-get-layouts doc) layout)
                        (vla-item (vla-get-plotconfigurations doc) setup)
                      )
                    )
          )
        )
      )
    nil
    t
  )
)







(DEFUN C:NLay (/ ACADO DOC CURRENTLAYOUT OLAYOUT OLAYOUTS P1 P2 V1 TITELHOEK POINTBLCK PS N ELEMENTNAAM)
  (prompt "\nSelect Objects by Window")
  (if (and (setq p1 (getpoint "\nFirst Corner: "))
           (setq p2 (getcorner p1 "\nSecond Corner: "))
      )
    (progn
      (command "_.zoom" p1 p2)
      (setq v1 (ssget "C" p1 p2 '((0 . "TEXT"))))
      (command "_.zoom" "_P")
      (if v1
        (progn
          (setq Currentlayout (cdr (assoc 1 (entget (ssname v1 0)))))
	  (setq n (vl-string-position (ascii ".") Currentlayout))    ;;look for how many text there is before you reach first "." 
	  (setq Elementnaam (substr Currentlayout (+ 2 n)))   ;; subtract from left to right n*letter + 2*letters (because first letter is 0 and "." need to be counted to    
          (setq acado (vlax-get-acad-object))
          (setq doc (vla-get-activedocument acado))
          (setq oLayouts (vla-get-layouts doc))

          (if (vl-position Elementnaam (layoutlist))   ;Returns the index of the specified list item and put some layout in i think
            (setq oLayout (vla-item oLayouts Elementnaam))
            (setq oLayout (vla-add oLayouts Elementnaam))
          )

	  (setq PCFGS (vla-get-plotconfigurations doc))      
	  (putPagesetup doc Elementnaam "A3 PDF KLEUR")    ;; launch function putpagesetup see top

	  (if
            (/= layout (getvar 'ctab))
             (setvar 'ctab Elementnaam);; set the currect layout to insert the block
          )
	  
          (vla-ZoomExtents acado)

	 (setq blk (vlax-invoke
	    (vlax-get
	      (vla-item
		(vla-get-layouts
		  (vla-get-activedocument
		    (vlax-get-acad-object)))
                                               Elementnaam)
                                         'block)
                                   'InsertBlock
                                   '(0.0 0.0 0.0)
                                   "4011TITELHOEK_BEK_WAP"
                                   1
                                   1
                                   1
                                   0));insert block
          (vla-put-Layer blk "4011.Titelhoek");; change the Layer
          (setvar 'ctab "Model");; put model active
          (vla-ZoomExtents acado);; zoom extents in model

	    );; progn
	  
	  
	);if extract text
      );; progn
    );if crossing
  (princ)
);defun

hmsilva · ‎11-27-2014

@Anonymous wrote:

i examined the functions of th AFK element, and i realised that ,after understanding it, that we can do it without the customkey AFK element.

So i did some little changes and put it in the full lisp.

tommorow i will to try to find out where to put the function for "stuks" is it advisable to create another lisp for that and put a link in this lisp?

Hi Subje,

you'll need to write a pseudocode first.

Try to put in simple words all the steps the code needs to do in model space, and then in paper space.

This way is easier to code, and it will easier to find the place to put the function for "stuks", and if you are going to use it only once in the code, you don't need to create a sub-function.

Henrique

Anonymous · ‎01-06-2015

Gonna put this on hold for the moment, i m looking into another lisp this moment and got a lot work also. hope i get back to this in a week or two.
thanks for the reply silva.

hmsilva · ‎01-07-2015

You're welcome, Subje

Henrique

From text to layout to block

From text to layout to block

Forums Links

Post to forums