Community
Hi,
You can use something like this sub routine which converts any number, even in lists whatever the nesting level.
(defun trueZero (x)
(cond
((listp x) (mapcar 'trueZero x))
((and (numberp x) (< x 0.00001)) 0)
(x)
)
)
(trueZero 1e-12) => 0
(trueZero '(21 28 1e-12)) => (21 28 0)
(trueZero '((21 28 1e-12) (32 15 1e-12))) => ((21 28 0) (32 15 0))
@hgasty1001 wrote:
....
The problem is you are trying to compare a list (y) to an atom y. Try changing this: (if (< (cdr vtpt) 0.0001) to (if (< (cadr vtpt) 0.0001) .
....
I agree, but would also suggest that you add an element:
(if (< (abs (cadr vtpt)) 0.0001)
and similarly for the X component. After all, I assume that if the value is, say, -3, you don't want it changed to 0.
You could also handle the possibility of positive or negative values very close to zero this way:
(if (equal (cadr vtpt) 0 1e-4)
Kent Cooper, AIA 
Same caveat as in my previous message....
(truezero '(-34 12 87))
returns
(0 12 87)
It should be something like:
(defun trueZero (x)
(cond
((listp x) (mapcar 'trueZero x))
((and (numberp x) (< (abs x) 0.00001)) 0)
(x)
)
)
Another approach:
(defun fixZero (ptlist)
(mapcar
'(lambda (coord) (if (equal coord 0 1e-8) 0 coord)) ;;; or whatever level of precision you prefer
ptlist
); mapcar
); defun
e.g.:
(fixZero '(-1.1234e-10 9e-11 -34))
returns
(0 0 -34)
Kent Cooper, AIA
Oopss !... I posted too quick.
Try this:
(defun trueZero (x)
(cond
((listp x) (mapcar 'trueZero x))
((and (numberp x) (equal x 0 0.00001)) 0)
(x)
)
)
(defun test (/ out vertexList)
(if (setq out (ssget "x" '((0 . "LWPOLYLINE") (8 . "Outside*"))))
(foreach p (entget (ssname out 0))
(if (= 10 (car p))
(setq vertexList (cons (trueZero (cdr p)) vertexList))
)
)
)
(reverse vertexList)
)
(defun test (/ out vertexBulgeList)
(if (setq out (ssget "x" '((0 . "LWPOLYLINE") (8 . "Outside*"))))
(foreach p (entget (ssname out 0))
(if (= 10 (car p))
(setq vertexBulgeList (cons (trueZero (cdr p)) vertexBulgeList))
)
(if (= 42 (car p))
(setq vertexBulgeList
(cons (list (car vertexBulgeList) (cdr p))
(cdr vertexBulgeList)
)
)
)
)
)
(reverse vertexBulgeList)
)
You could also write it as:
(defun test ( / enx itm lst sel )
(if (setq sel (ssget "_x" '((0 . "LWPOLYLINE") (8 . "Outside*"))))
(progn
(setq enx (entget (ssname sel 0)))
(while (setq itm (assoc 10 enx))
(setq lst (cons (list (truezero (cdr itm)) (cdr (assoc 42 enx))) lst)
enx (cdr (member itm enx))
)
)
(reverse lst)
)
)
)
Nice 'truezero' function gile 
Hi,
Did you try the routines lee and I posted ?
Both return a list where each item is a sub-list containing the point and the bulge;
(((x1 y1) b1) ((x2 y2) b2) ...)
If you really need to flatten each sublist item, just use (append ...) instead of (list ..) when building each item in the loop.
(defun test (/ out vertexBulgeList)
(if (setq out (ssget "x" '((0 . "LWPOLYLINE") (8 . "Outside*"))))
(foreach p (entget (ssname out 0))
(if (= 10 (car p))
(setq vertexBulgeList (cons (trueZero (cdr p)) vertexBulgeList))
)
(if (= 42 (car p))
(setq vertexBulgeList
(cons (append (car vertexBulgeList) (list (cdr p)))
(cdr vertexBulgeList)
)
)
)
)
)
(reverse vertexBulgeList)
)
Or with Lee's
(defun test ( / enx itm lst sel )
(if (setq sel (ssget "_x" '((0 . "LWPOLYLINE") (8 . "Outside*"))))
(progn
(setq enx (entget (ssname sel 0)))
(while (setq itm (assoc 10 enx))
(setq lst (cons (append (truezero (cdr itm)) (list (cdr (assoc 42 enx)))) lst)
enx (cdr (member itm enx))
)
)
(reverse lst)
)
)
)
Anyway, even if you prefer build two separated lists and concat their item after, you do not need to select the polyline twice neither lopp through its dXF data list twice.
(defun test (/ out vertexList bulgeList)
(if (setq out (ssget "x" '((0 . "LWPOLYLINE") (8 . "Outside*"))))
(foreach p (entget (ssname out 0))
(if (= 10 (car p))
(setq vertexList (cons (trueZero (cdr p)) vertexList))
)
(if (= 42 (car p))
(setq bulgeList (cons (cdr p) bulgeList))
)
)
)
(reverse
(mapcar
'(lambda (p b) (append p (list b)))
vertexList
bulgeList
)
)
)
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
