Centerline along length of 3d soild shape

[Stuboy]

Has anyone seen a lisp to draw a line along the length of a 3d solid? I have some UB (I sections) columns and beams modeled and would like to select all solids and for it draw a centerline end to end, any hep would be greatly appreciated

Stu

[mid-awe]

None that I've seen, but last I worked with LISP in 3D there was no method for sub-entity selections (which usually require holding the control key while clicking the face/edge/vertex).

*check out this old thread which never a solution was found.

http://forums.autodesk.com/t5/Visual-LISP-AutoLISP-and-General/ssget-edges/td-p/1893730/page/2#M2335...

[hmsilva]

Hi Stu,

not the answer that you are waiting, but maybe this thread helps...

Attache a sample dwg, with a few objects.

HTH

Henrique

[Kent1Cooper]

---

@Stuboy wrote:

Has anyone seen a lisp to draw a line along the length of a 3d solid? I have some UB (I sections) columns and beams modeled and would like to select all solids and for it draw a centerline end to end, any hep would be greatly appreciated

....

---

Are they all orthogonally oriented, and with ends cut perpendicular to their lengths?  If, so, I can imagine a way to calculate where the ends are, assuming they're the smallest opposite faces of the bounding boxes, and draw Lines between the middles of those.

[Stuboy]

Hi guys thanks for your help,

The ends are cut perpindicular to its length so what you perceive is true kent, Most entities are orthogonal well the columns and beams but there is also some wall bracing as you can imagine, but worst case i can draw the centerlines for those in. there is a centroid.lsp out there that puts a 'point' in at the COG, which could be used maybe using the bounding box at the ends and lenthen a line from that 'point', but your way is probably easier kent, you always seem to have an easier may, haha. would be good to select multiple entities at once though. attached a dwg, I have stripped most of the steel out to reduce size but it will give you an idea of what i am talking about.

again thanks all

stu 

[hmsilva · Accepted solution]

Stu,

did you checked the link at my previous post?

There, I pointed a way to achieve your objective...

Maybe this code lead you to the right solution.

As a "demo", a quick one, minimally tested:

(defun c:CtrLine (/ CTRD HND ITM NUM POS POS1 SS TMP TYP VECT VLAOBJ)
  (prompt "\nSelect 3D Solids to draw Centerlines: ")
  (if (setq ss (ssget '((0 . "3DSOLID"))))
    (progn
      (setq itm	0
	    num	(sslength ss)
      );; setq
      (while (< itm num)
	(setq hnd    (ssname ss itm)
	      vlaobj (vlax-ename->vla-object hnd)
	      ctrd   (vlax-get vlaobj 'Centroid)
	      typ    (vlax-get vlaobj 'SolidType)
	);; setq
	(cond ((eq typ "Cylinder")
	       (setq pos  (vlax-get vlaobj 'Position)
		     tmp  (mapcar '- pos ctrd)
		     pos1 (mapcar '- ctrd tmp)
	       );; setq
	       (entmake
		 (list
		   '(0 . "LINE")
		   '(8 . "CtrLine")
		   (cons 10 pos)
		   (cons 11 pos1)
		 )
	       );; entmake
	      )
	      ((eq typ "Extrusion")
	       (setq vect (cdr (assoc 10 (entget (cdr (assoc 360 (member '(100 . "AcDbEvalGraph")
			  (entget (cdr (assoc 360 (member '(100 . "AcDbShHistory")
			  (entget (cdr (assoc 350 (member '(100 . "AcDb3dSolid")
			  (entget hnd)))))))))))))))
		     );; setq
	       (setq tmp  (mapcar '/ vect '(2. 2. 2.))
		     pos  (mapcar '+ ctrd tmp)
		     pos1 (mapcar '- ctrd tmp)
	       )
	       (entmake
		 (list
		   '(0 . "LINE")
		   '(8 . "CtrLine")
		   (cons 10 pos)
		   (cons 11 pos1)
		 )
	       );; entmake
	      )
	);; cond
	(setq itm (1+ itm))
      );; while
    );; progn
  );; if
  (princ)
);; CtrLine

Hope that helps
Henrique

[Stuboy]

Your the man henrique, that works a treat I can add additionally what I need to it, thanks again all for your help, greatly appreciated gents..

Stu

[hmsilva]

---

@Stuboy wrote:
Your the man henrique, that works a treat I can add additionally what I need to it, thanks again all for your help, greatly appreciated gents..

Stu

---

You're welcome, Stu.

But please pay attention that if the 3DSolid is an edited one, with Union, Subtract, Intersect..., the 3DSolid entity don't have a "SolidType" property, and will give an error, this error can be avoided by using something like this, and no ceterline will be created for that edited 3DSolid...

(defun c:CtrLine (/ CTRD HND ITM NUM POS POS1 SS TMP TYP VECT VLAOBJ)
  (prompt "\nSelect 3D Solids to draw Centerlines: ")
  (if (setq ss (ssget '((0 . "3DSOLID"))))
    (progn
      (setq itm	0
	    num	(sslength ss)
      );; setq
      (while (< itm num)
	(setq hnd    (ssname ss itm)
	      vlaobj (vlax-ename->vla-object hnd)
	      ctrd   (vlax-get vlaobj 'Centroid));; setq
	(if (vl-catch-all-error-p
		   (vl-catch-all-apply (function (lambda ()
			(vlax-get vlaobj 'SolidType)))))
	  (setq typ "")
	  (setq typ (vlax-get vlaobj 'SolidType))
	  );; if
	(cond ((eq typ "Cylinder")
	       (setq pos  (vlax-get vlaobj 'Position)
		     tmp  (mapcar '- pos ctrd)
		     pos1 (mapcar '- ctrd tmp)
	       );; setq
	       (entmake
		 (list
		   '(0 . "LINE")
		   '(8 . "CtrLine")
		   (cons 10 pos)
		   (cons 11 pos1)
		 )
	       );; entmake
	      )
	      ((eq typ "Extrusion")
	       (setq vect (cdr (assoc 10 (entget (cdr (assoc 360 (member '(100 . "AcDbEvalGraph")
			  (entget (cdr (assoc 360 (member '(100 . "AcDbShHistory")
			  (entget (cdr (assoc 350 (member '(100 . "AcDb3dSolid")
			  (entget hnd)))))))))))))))
		     );; setq
	       (setq tmp  (mapcar '/ vect '(2. 2. 2.))
		     pos  (mapcar '+ ctrd tmp)
		     pos1 (mapcar '- ctrd tmp)
	       )
	       (entmake
		 (list
		   '(0 . "LINE")
		   '(8 . "CtrLine")
		   (cons 10 pos)
		   (cons 11 pos1)
		 )
	       );; entmake
	      )
	);; cond
	(setq itm (1+ itm))
      );; while
    );; progn
  );; if
  (princ)
);; CtrLine

Glad I could help

Henrique

[thomas.johansenPGXWY]

Hello,  

I tried using this script today 9.5 years later, and it doesnt seems to work with C3d 2020?  

Any tips? 😄   

Thanks 

[Abhay.KaranjikarQRNDZ]

can this script create multiple vertices polyline along 3d solid pipe if have multiple bends?

[hosneyalaa]

@Abhay.KaranjikarQRNDZ 

Can you attached example drawing 

[Abhay.KaranjikarQRNDZ]

Please find the attached sample 3D Solids received from client

[Abhay.KaranjikarQRNDZ]

Please find attached Cad file and snap of 3D Solid Pipe

[hosneyalaa]

@Abhay.KaranjikarQRNDZ 

hi

see this

https://forums.autodesk.com/t5/net/getting-subentity-vertex-points-of-swept-solid/td-p/6659519