Auto offset for selected items

[lai]

I wish to have a lisp than enable to do automatic offset base on some selection of lines ,circles or polylines object as shown in attachment. Does anyone have idea on it?

[hmsilva]

lai wrote:
I wish to have a lisp than enable to do automatic offset base on some selection of lines ,circles or polylines object as shown in attachment. Does anyone have idea on it?

perhaps something like

(defun c:test (/ dist ent curve pt1 pt2 pt3 pt4)
  (vl-load-com)
  (setq dist (getdist (strcat"\nEnter Distance to Offset: <" (rtos (getvar "offsetdist") 2 2 ) ">:")))
  (if (not dist) (setq dist (getvar "offsetdist"))); end if
  (setq ent (entsel "\nSelect Object to Offset:"))
  (setq curve (vlax-ename->vla-object (car ent)))
  (setq pt1 (vlax-curve-getClosestPointTo curve (cadr ent)))
  (setq pt2 (vlax-curve-getPointAtDist curve 0.01))
  (setq pt3 (polar pt1 (+ (angle pt1 pt2) (* pi 0.5)) 1))
  (setq pt4 (polar pt1 (- (angle pt1 pt2) (* pi 0.5)) 1))
  (command "_.offset" dist (car ent) (osnap pt3 "_non") "")
  (command "_.offset" dist (car ent) (osnap pt4 "_non") "")
  (princ)
  )

Hope that helps

Henrique

[pbejse · Accepted solution]

---

@lai wrote:

I wish to have a lisp than enable to do automatic offset base on some selection of lines ,circles or polylines object as shown in attachment. Does anyone have idea on it?

---

(defun c:osd ( /  ss e )
(setq ofd (cond
((getdist (strcat "\nEnter Offset distance"
 (if ofd (strcat " <" (rtos ofd) ">: ") ": ")
            )))(ofd))
)
(if (setq ss (ssget ":L"))
  (repeat (sslength ss)
          	(setq e (vlax-ename->vla-object (ssname ss 0)))
    		(if (vlax-method-applicable-p e 'Offset)
                    (mapcar '(lambda (o)
				(vl-catch-all-error-p
				  (vl-catch-all-apply
				    'vla-offset (list e o))))(list ofd (- ofd)))
                  )
    	(ssdel (ssname ss 0) ss)))
(princ)
)

HTH

[hmsilva]

pbejse,
very nice approach!

Cheers
Henrique

[Kent1Cooper]

---

@lai wrote:

I wish to have a lisp than enable to do automatic offset base on some selection of lines ,circles or polylines object as shown in attachment. Does anyone have idea on it?

---

Here's my version from a couple of years ago.  It remembers the offset distance used in it, separately from regular Offset's setting, and offers it as a default on subsequent use.  But if there hasn't been a value used in it yet, it offers regular Offset's setting as a default [provided it's not Through, which would be inapplicable].

If you put Offset Both Sides or something similar in the Search window, you'll find a variety of threads on the subject [including one with an earlier version of the attached].

If you want to select all objects to Offset both ways at once, instead of one at a time, it could certainly be adjusted to do that.

[pbejse]

---

@hmsilva wrote:

pbejse,
very nice approach!

Cheers
Henrique

---

Thank you Henrique, its from an old routine of mine. Glad you like it.

Cheers

[lai]

Dear Henrique,

Thanks for your help..after test, i feel that it lack of some feature..

More prefer to pbejse lisp..Works more better.

[pbejse]

Glad it helps

Cheers 

[hmsilva]

lai wrote

: ...

More prefer to pbejse lisp..Works more better.

I fully agree with you, pbejse's code is a great code.

Cheers

Henrique

[lai]

Hi pbejse,

I not sure if the lisp can be modify to do it to be as shown in attachment.

[pbejse · Accepted solution]

---

@lai wrote:

Hi pbejse,

I not sure if the lisp can be modify to do it to be as shown in attachment.

---

But of course

(defun c:osdc ( /  ss e )
(setq ofd (cond
((getdist (strcat "\nEnter Offset distance"
 (if ofd (strcat " <" (rtos ofd) ">: ") ": ")
            )))(ofd))
)
(if (setq ss (ssget ":L"))
  (repeat (sslength ss)
          	(setq e (vlax-ename->vla-object (ssname ss 0)))
    		(if (vlax-method-applicable-p e 'Offset)
            (progn
			(mapcar '(lambda (o)
				(vl-catch-all-error-p
					(vl-catch-all-apply
						'vla-offset (list e o))))(list ofd (- ofd)))
              (mapcar '(lambda (p)
              	(entmakex (list (cons 0 "CIRCLE")
                  		(cons 10 p)
                  		(cons 40 ofd))))
                    (list (vlax-curve-getstartpoint e)
				(vlax-curve-getendpoint e)))  
              				)
                  )
    	(ssdel (ssname ss 0) ss)))
(princ)
)

command: Osdc

Select objects:

HTH