Hatch dialog box

[Alexey_Terno]

Is it possible to show hatch dialog box using .NET?

I have found one old issue (link) but it does not work with AutoCAD 2014.

[Ajilal.Vijayan · Accepted solution]

Hi,

Please try with this code

There is a commnet from MathewWebber in the same link where you find the code.

Imports Autodesk.AutoCAD.ApplicationServices
Imports Autodesk.AutoCAD.Runtime
Imports Autodesk.AutoCAD.EditorInput
Imports System.Runtime.InteropServices
Imports System

Namespace HatchDialogTest

    Public Class Commands

        Private Declare Auto Function acedHatchPalletteDialog _
        Lib "acad.exe" _
        Alias "?acedHatchPalletteDialog@@YA_NPEB_W_NAEAPEA_W@Z" _
        (ByVal currentPattern As String, _
        ByVal showcustom As Boolean, _
        ByRef newpattern As IntPtr) As Boolean

        <CommandMethod("SHD")> _
        Public Sub ShowHatchDialog()

            Dim sHatchType As String = "ANGLE"
            Dim ptr As IntPtr
            Dim bRet As Boolean = _
              acedHatchPalletteDialog(sHatchType, _
                True, ptr)
            If bRet Then
                Dim sNewHatchType As String = _
                  Marshal.PtrToStringAuto(ptr)
                If sNewHatchType.ToString.Length > 0 Then
                    Dim ed As Editor
                    ed = _
                      Application.DocumentManager.MdiActiveDocument.Editor
                    ed.WriteMessage( _
                      vbLf + "Hatch type selected: " + sNewHatchType)
                End If
            End If

        End Sub

    End Class

End Namespace

[Alexey_Terno]

Yes - it's works!!!
Thanks a lot!