Convert IDW with multiple sheets to multiple PDF's (Inventor 2013)

[berry.lejeune]

Hey everybody,

here is the problem we are facing.

From all our parts of an assembly we made 1 IDW with multiple sheets. Now we want to convert this IDW to PDF's and in such a way that we have one PDF for each sheet,  and each PDF files needs the same name as the sheet.

Thanks,

Berry

[Anonymous]

http://www.bullzip.com/products/pdf/info.php

Print one page at a time and name them whatever.

Or try this as well

http://www.kvisoft.com/pdf-splitter/

[berry.lejeune]

The problem is we are having IDW's with about 50 sheets each.

Berry

[Anonymous]

Yah, thought of that so edited my last post to include a splitter, it works quite well.

[Curtis_Waguespack · Accepted solution]

Hi berry.lejeune,

You can use an iLogic rule to do this:

http://inventortrenches.blogspot.com/2011/07/ilogic-to-save-pdf-files-to-new.html

Here is the code snippet from the 2nd variation found at that link. You can configure the output folder location and the file name as needed. Post back with an example of each and I can modify the code for you.

If you've never created an iLogic rule you can follow this link to see how to create an external iLogic rule. Once created you can paste in the code below for testing.

http://autodeskmfg.typepad.com/blog/2012/01/working-with-external-ilogic-rules.html

I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com

 oPath = ThisDoc.Path
oFileName = ThisDoc.FileName(False) 'without extension
oPDFAddIn = ThisApplication.ApplicationAddIns.ItemById _
("{0AC6FD96-2F4D-42CE-8BE0-8AEA580399E4}")
oDocument = ThisApplication.ActiveDocument
oContext = ThisApplication.TransientObjects.CreateTranslationContext
oContext.Type = IOMechanismEnum.kFileBrowseIOMechanism
oOptions = ThisApplication.TransientObjects.CreateNameValueMap
oDataMedium = ThisApplication.TransientObjects.CreateDataMedium

'Define the drawing
Dim oDrawing As DrawingDocument
oDrawing = ThisDoc.Document

Dim oSheet As Sheet
Dim lPos As Long
Dim rPos As Long
Dim sLen As Long
Dim sSheetName As String
Dim iSheetNumber As Integer

'step through each drawing sheet
For Each oSheet In oDrawing.Sheets

'find the seperator in the sheet name:number
lPos = InStr(oSheet.Name, ":")
'find the number of characters in the sheet name
sLen = Len(oSheet.Name)
'find the sheet name
sSheetName = Left(oSheet.Name, lPos -1)
'find the sheet number
sSheetNumber = Right(oSheet.Name, sLen -lPos)

'set PDF Options
If oPDFAddIn.HasSaveCopyAsOptions(oDataMedium, oContext, oOptions) Then
oOptions.Value("All_Color_AS_Black") = 1
oOptions.Value("Remove_Line_Weights") = 1
oOptions.Value("Vector_Resolution") = 400
oOptions.Value("Sheet_Range") = Inventor.PrintRangeEnum.kPrintSheetRange
oOptions.Value("Custom_Begin_Sheet") = sSheetNumber
oOptions.Value("Custom_End_Sheet") = sSheetNumber
End If

'get PDF target folder path
oFolder = Left(oPath, InStrRev(oPath, "\")) & "PDF"

'Check for the PDF folder and create it if it does not exist
If Not System.IO.Directory.Exists(oFolder) Then
    System.IO.Directory.CreateDirectory(oFolder)
End If

'Set the PDF target file name
oDataMedium.FileName = oFolder & "\" & oFileName & " " & sSheetName & " " & sSheetNumber  & ".pdf"

'Publish document
oPDFAddIn.SaveCopyAs(oDocument, oContext, oOptions, oDataMedium)

Next

[Anonymous]

well, just try kvisoft PDF splitter or try the XFlip PDF page flip software at http://www.xflip.com/, good luck!