Change Content Center part to a normal ipt

[Anonymous]

Hi,

I have a part that was made from content center and modified further.  I would like Inventor to no longer recognize this part as a content center part.  It has been renamed and migrated to 2013 format, but still when inserting into an assembly the assembly recognizes it as a content center part in the browser.

Also, the browser title for the part will not update with the filename.

[cbenner]

What is the part?  Can you post the file?  There are work features added to a part when it is published to the CC.  It may be as simple as removing these work features.  But what those are depnds on what the part is.

[LT.Rusty]

Open from content center --> save as.

Should be as simple as that.  I've got a bunch of stuff that I've done that with, and it doesn't show as a CC part anymore.

Changing the browser name though, I think you have to do that manually once the file is open.

[Cadmanto · Accepted solution]

See if this link helps you.

http://forums.autodesk.com/t5/Autodesk-Inventor/Fitting-type-removal/m-p/3066678/highlight/true#M405...

If this solved your issue please mark this posting "Accept as Solution".

Or if you like something that was said and it was helpful, Kudos are appreciated. Thanks!!!! 

     

[Carthik_Babu]

hi,

kindly read this blog, it will solve the issue.

http://beinginventive.typepad.com/being-inventive/2012/07/place-a-tube-pipe-fitting-in-an-assembly-a...

I got thisbelow macro from the above site(bit modified for Autodesk Inventor 2011). I saved this as external macro and applied the macro to the part file which has been placed from content center as "Custom". The Macro solved the issue.....

Sub Main()
strip_CC()
End Sub

Sub strip_CC()
    Dim oDoc As PartDocument
    oDoc = ThisApplication.ActiveDocument
    
    'Check to see if it is not a true content center part . otherwise bail out
    If oDoc.ComponentDefinition.IsContentMember = False Then
        ' Enable all commands and set the subtype to a standard part.
        oDoc.DisabledCommandTypes = 0
        oDoc.SubType = "{4D29B490-49B2-11D0-93C3-7E0706000000}"
    
        ' Optionally clean up other Content Center related properties.
        On Error Resume Next
        oDoc.PropertySets.Item("Content Library Component Properties").Delete
        Dim DTPropSet As PropertySet
        DTPropSet = oDoc.PropertySets.Item("Design Tracking Properties")
        DTPropSet.Item("Catalog Web Link").Value = ""
        oDoc.Save
    End If
End Sub

[Carthik_Babu]

Hi,

Kindly find the code for converting the selected "custom content center Part file" in an assembly to Normal File. Hope it will be useful for someone who search for the same.

Sub Main()
Dim oOcc As ComponentOccurrence 
oOcc = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kAssemblyOccurrenceFilter, "Pick occurrence") 
    
strip_CC(oOcc)
End Sub

Sub strip_CC(ByVal oOcc1 As ComponentOccurrence)
    'Dim oDoc As PartDocument
    'oDoc = ThisApplication.ActiveDocument
    
    Dim oOccDef As PartComponentDefinition 
    oOccDef = oOcc1.Definition 
    
    ' Just open it in the background
    asm = ThisApplication.Documents.Open(oOccDef.Document.FullFileName, False)
    
    'Check to see if it is not a true content center part . otherwise bail out
    If oOccDef.Document.ComponentDefinition.IsContentMember = False Then
        ' Enable all commands and set the subtype to a standard part.
        oOccDef.Document.DisabledCommandTypes = 0
        oOccDef.Document.SubType = "{4D29B490-49B2-11D0-93C3-7E0706000000}"
    MsgBox(oOccDef.Document.FullFileName)
    
        ' Optionally clean up other Content Center related properties.
        On Error Resume Next
        oOccDef.Document.PropertySets.Item("Content Library Component Properties").Delete
        Dim DTPropSet As PropertySet
        DTPropSet = oOccDef.Document.PropertySets.Item("Design Tracking Properties")
        DTPropSet.Item("Catalog Web Link").Value = ""
        oOccDef.Document.Save
    End If
End Sub

[tegstette]

Hi

This rule Works great from an Assembly by picking the part I want to make normal.

But is it possible to rewrite the rule so it can be run directly on the ipt?

I would be very glad if you or someone else could help me out very soon

[tegstette]

I figured it out

I used the code above and modified a little to my need.

[mcgyvr]

@tegstette

Do you mind posting your updated code that worked for you so others can benefit from it?

Thanks

[Curtis_Waguespack]

Hi mcgyvr,

I use a version of this with iLogic.

I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com

Run in the part file:

Try
	ThisApplication.ActiveDocument.PropertySets.Item("Content Library Component Properties").Delete
	MessageBox.Show("KA-POW!" & vbLf & "Content Center Properties smashed!", "iLogic")
Catch
	MessageBox.Show("huh?" & vbLf & _
	"Something didn't work..." &vbLf & _
	"...file is read only maybe?" &vbLf & _
	"...file has no Content Center Properties, maybe?" &vbLf & _
	"...other?", "iLogic")
End Try

[jrbrabbs]

Very nice!

[lackas5C4Z4]

@Curtis_Waguespack, Do you know if it is possible to restore the symbol to the default for an IPT file?

[Curtis_Waguespack · Accepted solution]

Hi lackas5C4Z4,

Give this a try. I didn't have time to test it much, post back if you run into problems.

Note you might to save or do a rebuild all on the assembly to see the icon for the component change, if the part was already placed in an assembly and that assembly is open.

I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com

oError = 0


Try
	ThisApplication.ActiveDocument.PropertySets.Item("Content Library Component Properties").Delete
	oErrorMessage1 = ""
Catch
	oError = oError + 1	
	oErrorMessage1 = "PropertySet not found: Content Library Component Properties"
End Try

Try
	ThisApplication.ActiveDocument.PropertySets.Item("ContentCenter").Delete
	oErrorMessage2 = ""
Catch
	oError = oError + 1
	oErrorMessage2 = "PropertySet not found: ContentCenter"
End Try

If oError = 2 Then
	MessageBox.Show("huh?" & vbLf & _
	"Something didn't work..." &vbLf & _
	"...file is read only maybe?" &vbLf & _
	"...file has no Content Center Properties, maybe?" &vbLf & _
	"...other?", "iLogic")
ElseIf oError = 1 Then
	MessageBox.Show(oErrorMessage1 & vbLf & _
	oErrorMessage2, "iLogic")		
Else
	MessageBox.Show("KA-POW!" & vbLf & "Content Center Properties smashed!", "iLogic")
End If

[lackas5C4Z4]

This worked beautifully. Didn't even have to rebuild the assembly. Thank you very much!

Note: it did throw an error on the parts where I used the previous script but still got the job done.