Community
Hi jletcher,
Would it work to create the derived part in advance (not using iLogic) and have the iLogic Yes/No message simply replace the left side with the right side, etc. ?
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
>>>
Hi jletcher,
I'll see what I can come up with, but as a rule I typically don't respond to posts that contain rants and hints of unconstrained frustration.
This is simply because I've tried to help frustrated people in the past and they end up becoming unpleasant toward the people trying to help. There is also a tendency for people to get distracted by their frustration, rather than concentrating on the question they're asking and providing clear details and examples, which of course makes it difficult and time consuming to help them.
So generally speaking I'll pass on posts that lack detail and contain rants and complaining, but I might have a need for something similar to the derived example in the near future, so I'll take some time to explore it.
I can't promise anything, but I'll post back if I have some luck.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
Hi jletcher,
Here is a quick example I came up with. It looks for a pre-selected part from within the assembly, and then creates a new derived file from that file and mirrors it. Then it places an instance of the derived part into the assembly and then finally it replaces the selected file with the new derived one too.
You'll likely discard all of the file selection code and just hardcode in the file you're configuring, etc.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
'set a reference to the assembly component definintion.
'this assumes an assembly document is open.
Dim oAsmCompDef As AssemblyComponentDefinition
oAsmCompDef = ThisApplication.ActiveDocument.ComponentDefinition
'get currently selected component
Dim oOccurrence as ComponentOccurrence
Try
oOccurrence = ThisDoc.Document.SelectSet.Item(1)
Catch
MessageBox.Show("Please select a component before running this rule.", "iLogic")
Return
End Try
Dim doc As Document
Dim CurFileName As String
Dim NewFileName As String
'set the selected item
oOccurrence = ThisApplication.ActiveDocument.SelectSet.Item(1)
'get the selected item document occurrence name
doc = oOccurrence.Definition.Document
'get the path and file name of the selected item
CurFileName = doc.FullFileName
oQuestion = MessageBox.Show("Do you want to derive " & doc.DisplayName & " ?", "iLogic",MessageBoxButtons.YesNo)
If oQuestion = vbNo Then
Return
Else
' Initialize the string that defines the directory where the files will be created.
Dim sFilePath As String
sFilePath = "C:\Temp\"
' Create a new part file to derive the selected part into
'note: kPartDocumentObject is the default template
Dim oPartDoc As PartDocument
oPartDoc = ThisApplication.Documents.Add(kPartDocumentObject, ThisApplication.FileManager.GetTemplateFile(kPartDocumentObject))
'Create a derived definition for the selected part
Dim oDerivedPartDef As DerivedPartUniformScaleDef
oDerivedPartDef = oPartDoc.ComponentDefinition.ReferenceComponents.DerivedPartComponents.CreateUniformScaleDef(CurFileName)
' set the scale to use.
oDerivedPartDef.ScaleFactor = 1
'define the mirror plane
'kDerivedPartMirrorPlaneXY = 27393
'kDerivedPartMirrorPlaneYZ = 27394
'kDerivedPartMirrorPlaneXZ = 27395
oDerivedPartDef.MirrorPlane = 27393
' Create the derived part.
oPartDoc.ComponentDefinition.ReferenceComponents.DerivedPartComponents.Add(oDerivedPartDef)
'get a file name for the derived part
NewFileName = InputBox("Enter a name for the derived part file: ", "iLogic", doc.DisplayName & "_derived")
' Save and close the derived part.
oPartDoc.SaveAs(sFilePath & NewFileName & ".ipt", False)
oPartDoc.Close
'set a reference to the transient geometry object.
Dim oTG As TransientGeometry
oTG = ThisApplication.TransientGeometry
' Create a placement matrix
Dim oMatrix As Matrix
oMatrix = oTG.CreateMatrix
'set the matrix coordinates
oMatrix.SetTranslation(oTG.CreateVector(3, 2, 1))
' Add a new occurrence of the derived part to the assembly
Dim oOcc As ComponentOccurrence
oOcc = oAsmCompDef.Occurrences.Add(sFilePath & NewFileName & ".ipt", oMatrix)
‘Replace the originally selected part with the derived part
'note: True = Replace All
oOccurrence.Replace (sFilePath & NewFileName & ".ipt", False)
End If
Hi jletcher,
Those details help a lot.
If I understand correctly, then I don't think a derived part is needed.
The approach I would take is to create a mirror feature to mirror the entire part wihin the part file (use the Mirror a Solid button with the Remove Original option). Then in your iLogic configurator you'll simply suppress or enable this mirror feature.
Or you could even have the code delete the mirror feature.
Or you could take the opposite approach and have the ilogic create mirror feature using the API tools, but that wouldn't be my preference.
Attached is a simple example file.
Edit:
It just occured to me that if these parts are to be generated by iLogic, but maintained by traditional modeling tools, then the derived link would be the better way to go. If that's the case I can have another look at deriving from the part file.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
Hi jletcher,
Okay here is an example that creates a mirrored, derived part of the original and saves it in the same directory as the original. The file name is generated without user input.
Edit: I fixed a slight bug.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
doc = ThisDoc.Document
path_and_name = ThisDoc.PathAndFileName(False) ' without extension
oQuestion = MessageBox.Show("Do you want to derive this file?", "iLogic",MessageBoxButtons.YesNo)
If oQuestion = vbNo Then
Return
Else
' Create a new part file to derive the selected part into
'note: kPartDocumentObject is the default template
Dim oPartDoc As PartDocument
oPartDoc = ThisApplication.Documents.Add(kPartDocumentObject, ThisApplication.FileManager.GetTemplateFile(kPartDocumentObject))
'Create a derived definition for the selected part
Dim oDerivedPartDef As DerivedPartUniformScaleDef
oDerivedPartDef = oPartDoc.ComponentDefinition.ReferenceComponents.DerivedPartComponents.CreateUniformScaleDef(ThisDoc.PathAndFileName(True) )
' set the scale to use
oDerivedPartDef.ScaleFactor = 1
'define the mirror plane
'kDerivedPartMirrorPlaneXY = 27393
'kDerivedPartMirrorPlaneYZ = 27394
'kDerivedPartMirrorPlaneXZ = 27395
oDerivedPartDef.MirrorPlane = 27394
' Create the derived part.
oPartDoc.ComponentDefinition.ReferenceComponents.DerivedPartComponents.Add(oDerivedPartDef)
' Save the new derived part.
oPartDoc.SaveAs(path_and_name & "_derived.ipt", False)
oPartDoc.Close
MessageBox.Show("New file created at:" & vblf & path_and_name & "_derived.ipt", "iLogic")
End If
The fish say thanks! 
Hi sergelachance,
Sorry, but I don't understand what you're asking. Can you explain what you have set up and what you're attempting to do?
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
Can't find what you're looking for? Ask the community or share your knowledge.
Post to forums
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")