フェイタルエラーのUnhandled e0434352h Exception at 7c812afbhがでて強制終了します。
net framework 3.5を再インストールしたりしましたが、効果無しです。
誰か助けてください
製品ってAutoCAD Civil 3D 2012?
単純にググるとこんなのが出てくるけど。
このページの左の方の「Translate this page」でJapaneseを選べば日本語表示にもなるね。
ちょっと意味が分からない部分もあるけど。
こんばんは
この acad.exe.config ファイルでは .NET2.0を使う、という指定がコメントアウトされているので
インストールされている最新バージョンが自動的に使われるようになっている
で、エラーが発生しているので、
コメントアウトされてる中から、常に .NET2.0を使います、って記述を外に出して
明示的にはバージョン指定するという内容ですね
AutoCAD 2007 か2008 のときにやりました
書き換えは簡単ですしバックアップも念のため取っておけば、やってみる価値あるかもしれないですね
ちなみに .NET 3.5 の SP1 や 4.0 ってインストールされています?
XCIX
BIM Manager
下記の情報も参考になるかと!
.netのクリーンインストール方法が記載
参考= .netサイトにあるクリーンインストール
blogs.msdn.com/b/jpvsblog/archive/2012/05/16/net-framework.aspx
後 acad2012の.net frameworkは 4.0です。 利用acadと.netのverは確認しておくと良い。
注意= 古いacad verを後からインストールするとトラブルが発生します。
下記サイトは google toolbar等の翻訳ボタンでページ翻訳して下さい。(ある程度理解可能)
翻訳ができない時は google chromeブラウザで閲覧すると自動翻訳します。(java script禁止時は許可で翻訳)
.NET Framework Error on Start up of AutoCAD 2011 or 2012
.NET Framework Cleanup Tool for Unhandled Exception Errors
すいません
少し勘違いしていました
私がやったのは win95 さんの張ってくれたリンクのさらにリンクのほうの操作です
バージョンによって .NET のバージョンと、config ファイルの記述が違います
LT2012ならば以下のファイルですね
<C:\Program Files\Autodesk\AutoCAD LT 2012 - Japanese\acadlt.exe.config>
動作を実機で確認するので少し待ってください。
XCIX
BIM Manager
結論から先にいうと、ここ の操作はだめでした、あくまで手元の結果ですが
上記ページに添付の「Acad.exe.config」を LT2012 の acadlt.exe.config ファイルと置き換えましたが
起動時にエラーが発生してリボンや画層パネルなど、.NET を使う機能が軒並み使えませんでした
また、デフォルト acadlt.exe.config ファイルのバージョン指定の箇所だけを "v4.0" ⇒ "v4.0.30319" に
メモ帳で書きかえた場合は、問題なく起動しましたが、今回の件で効果があるか自信ないです
(Window7 x64 環境)
申し訳ないですけど、現状ではやはりクリーンナップツール等を使って .NET を完全に再インストールするしかないのかなと思いました
または、カズヤンさんのところのユーザ権限や OS が不明なのと、エラー内容が違いますが、
下記のファイルのアクセス権を確認、という情報があるので試してみてはどうでしょう
参考
http://forums.autodesk.com/t5/Installation-Licensing/Exception-in-acmgd-dll-ARX-Command-Unhandled-Ex...
http://forums.autodesk.com/t5/AutoCAD-2006/Exception-in-acmgd-dll-ARX-Command/td-p/1599600
64ビット
C:\Windows\Microsoft.NET\Framework64\v4.0.30319\Config\machine.config
32ビット
C:\Windows\Microsoft.NET\Framework\v4.0.30319\Config\machine.config
Users グループに対して「読み取りと実行」および「読み取り」の権限を与える、という操作です
私のところではすでにそのようなアクセス権が与えられていたので、同様で意味がないのかもしれませんが
時間はかからないので念のため確認してはどうでしょう
お役に立てずすいません
XCIX
BIM Manager
.NET Framework issues can be resolved using the .NET Framework Cleanup Tool. More information about this tool can be found at my discussion thread here:
http://forums.autodesk.com/t5/Installation-Licensing/NET-Framework-Cleanup-Tool-for-Unhandled-Except...
Good Luck!
>紹介してもらったソフトを使ってやってみたいと思います。
.net 関係はインストール済とあるが windows サービスはチャット起動していますか?
windows のverが不明なので 判断できませんが windows7 64bit環境ですと 4種類のサービスが起動しています。
2,0~3.5用の x86,x64用 (windows7 ではos標準インストール)
2サービス : サービス(ローカル)表示名 (サービス名)
Microsoft .NET Framework NGEN v2.0.50727_X64 (=clr_optimization_v2.0.50727_64)
Microsoft .NET Framework NGEN v2.0.50727_X86 (=clr_optimization_v2.0.50727_32)
4.0用 別途追加インスロール
2サービス : サービス(ローカル)表示名 (サービス名)
Microsoft .NET Framework NGEN v4.0.30319_X64 (=clr_optimization_v4.0.30319_64)
Microsoft .NET Framework NGEN v4.0.30319_X86 (=clr_optimization_v4.0.30319_32)
.NET Frameworkのバージョンを確認する方法
@ITサイトで.net freamework関係の情報が色々有ります。
バージョン自動検出用バッチ・ファイル(ZIPファイル)
この項目を確認しては?
www.atmarkit.co.jp/fwin2k/win2ktips/246checkvdnfw/checkvdnfw.html
今インストールしているNET Framew orkは
1.1
1.1 Japanses Language Pack
2.0 Service Pack 2
2.0 Service Pack 2 Japanses Language Pack
3.0 Service Pack 2
3.0 Service Pack 2 Japanses Language Pack
3.5 Service Pack 1
3.5 Service Pack 1 Japanses Language Pack
4.0 Client Profile
4.0 Client Profile Japanses Language Pack
4.0 Extended
4.0 Extended Japanses Language Pack
プログラムの追加と削除で見るとこれだけインストールされていました。
参考まで 前回説明したサービス起動確認を行いましたか?
サービス設定をいじくった記憶があれば 再確認下さい。
xpだと .netは 4.0ですから 下記のサービスを自動にする。(手動はアプリ起動で問題無いか確認)
スタートアップの種類は自動だと思う。 無効 => 自動に修正
Microsoft .NET Framework NGEN v2.0.50727_X86 (=clr_optimization_v2.0.50727_32)
>xpだと .netは 4.0
ミスです acad2012ですと .netは4.0 です。
xp環境の .net freamework 4.0は サービスが動いています。
1.1 , 2.0~3.5はサービスが不明 (曖昧= システムに疎いので失礼)
xpに.netを全てインストールした環境で サービス確認できたのが 4.0だけでした。
確認しましたが何がなんだか分からなかったです、すいません。
@echo off
REM ------------------------------------------------------------------------------
REM .NET Frameworkバージョン自動検出用バッチ・ファイル(2011年11月25日版)
REM
REM Windows TIPS: .NET Frameworkのバージョンを確認する方法
REM http://www.atmarkit.co.jp/fwin2k/win2ktips/246checkvdnfw/checkvdnfw.html
REM Copyright (C) 2000-2011 Digital Advantage Corp.
REM ------------------------------------------------------------------------------
setlocal
REM ----- 引数(リモート・コンピュータ名)の確認
if %1. == . (
set RemoteName=
echo ----- ローカル・コンピュータ(%COMPUTERNAME%) -----
) else (
set RemoteName=%1\
echo ----- %1 -----
)
REM ----- レジストリに参照できるか確認
reg query %RemoteName%HKLM\SOFTWARE\Microsoft 1>nul
if errorlevel 1 (
echo %0: レジストリを参照できません。エラーが発生しました。
endlocal
exit /b
)
REM ----- レジストリ・エントリの指定
set RegKey11=%RemoteName%HKLM\SOFTWARE\Microsoft\NET Framework Setup\NDP
REM ----- 各バージョンの確認
call :Detect10
call :Detect11_35 ".NET Framework 1.1" "%RegKey11%\v1.1.4322"
call :Detect11_35 ".NET Framework 2.0" "%RegKey11%\v2.0.50727"
call :Detect11_35 ".NET Framework 3.0" "%RegKey11%\v3.0"
call :Detect11_35 ".NET Framework 3.5" "%RegKey11%\v3.5"
call :Detect4 ".NET Framework 4" "%RegKey11%\v4"
REM ----- 終了処理
endlocal
exit /b
REM --------------------------------------
REM ----- .NET Framework 1.0の検出
:Detect10
set RegKey10_Inst=%RemoteName%HKLM\SOFTWARE\Microsoft\NET Framework Setup\Full\v1.0.3705\1041\Microsoft .NET Framework Full v1.0.3705 (1041)
set RegKey10_SP=%RemoteName%HKLM\SOFTWARE\Microsoft\Active Setup\Installed Components
REM ----- インストールの確認
reg query "%RegKey10_Inst%" /v "Install" 2>nul | find /I "Install" 2>nul | find /I "0x1" 1>nul 2>nul
if errorlevel 1 goto NoExist10
REM ----- Service Packレベルの確認
reg query "%RegKey10_SP%\{78705f0d-e8db-4b2d-8193-982bdda15ecd}" /v "Version" 2>nul | find /I "Version" 1> temp-RegOut.log 2>nul
reg query "%RegKey10_SP%\{FDC11A6F-17D1-48f9-9EA3-9051954BAA24}" /v "Version" 2>nul | find /I "Version" 1>> temp-RegOut.log 2>nul
REM ----- 初期版の確認
find /I "1,0,3705,0" temp-RegOut.log 1>nul 2>nul && echo .NET Framework 1.0 初期版がインストール済みです
REM ----- SP1/SP2/SP3の確認
for %%i in (1 2 3) do (find /I "1,0,3705,%%i" temp-RegOut.log 1>nul 2>nul && echo .NET Framework 1.0 Service Pack %%i がインストール済みです)
:NoExist10
if exist temp-RegOut.log del temp-RegOut.log
exit /b
REM -----
REM ----- .NET Framework 1.1/2.0/3.0/3.5 の検出
:Detect11_35
REM ----- インストールの確認
reg query "%~2" /v "Install" 2>nul | find /I "Install" 2>nul | find /I "0x1" 1>nul 2>nul
if errorlevel 1 goto NoExist11
reg query "%~2" /v "SP" 2>nul | find /I "SP" 1> temp-RegOut.log 2>nul
if errorlevel 1 goto NoExist11
REM ----- 初期版の確認
find /I "0x0" temp-RegOut.log 1>nul 2>nul && echo %~1 初期版 がインストール済みです
REM ----- SP1/SP2/SP3の確認
for %%i in (1 2 3) do (find /I "0x%%i" temp-RegOut.log 1>nul 2>nul && echo %~1 Service Pack %%i がインストール済みです)
REM ----- 日本語 Language Packの確認
set LangPath=
reg query "%~2\Setup\1041" /v "Install" 2>nul | find /I "Install" 2>nul | find /I "0x1" 1>nul 2>nul && set LangPath=%~2\Setup\1041
reg query "%~2\1041" /v "Install" 2>nul | find /I "Install" 2>nul | find /I "0x1" 1>nul 2>nul && set LangPath=%~2\1041
if "%LangPath%" == "" (
echo 日本語Language Packはインストールされていません
) else (
reg query "%LangPath%" /v "SP" 2>nul | find /I "SP" 1> temp-RegOut.log 2>nul
find /I "0x0" temp-RegOut.log 1>nul 2>nul && echo 日本語Language Pack(初期版)がインストール済みです
for %%i in (1 2 3) do (find /I "0x%%i" temp-RegOut.log 1>nul 2>nul && echo 日本語Language Pack(Service Pack %%i)がインストール済みです)
)
:NoExist11
if exist temp-RegOut.log del temp-RegOut.log
exit /b
REM -----
REM ----- .NET Framework 4 の検出
:Detect4
REM ----- インストールの確認
reg query "%~2\Full" /v "Install" 2>nul | find /I "Install" 2>nul | find /I "0x1" 1>nul 2>nul
if not errorlevel 1 (
echo %~1 (フル版)がインストール済みです
reg query "%~2\Full\1041" /v "Install" 2>nul | find /I "Install" 2>nul | find /I "0x1" 1>nul 2>nul
if not errorlevel 1 (
echo 日本語Language Packがインストール済みです
) else (
echo 日本語Language Packはインストールされていません
)
) else (
reg query "%~2\Client" /v "Install" 2>nul | find /I "Install" 2>nul | find /I "0x1" 1>nul 2>nul
if not errorlevel 1 (
echo %~1 (クライアント・プロファイル版)がインストール済みです
reg query "%~2\Client\1041" /v "Install" 2>nul | find /I "Install" 2>nul | find /I "0x1" 1>nul 2>nul
if not errorlevel 1 (
echo 日本語Language Packがインストール済みです
) else (
echo 日本語Language Packはインストールされていません
)
)
)
exit /b
REM -----
サービスの意味は windowsのサービスです。
スタートから
1.「ファイル名を指定して実行」を起動
2.名前の欄に、「services.msc」 (「」は不要)を入力し、「OK」
xpのディスクトップ上ですと(現在win7なので 記憶で)
スタート => コントロールパネル => コンピューターの管理 => サービス
お探しの情報が見つからないときは、コミュニティで質問しましょう。困っている人がいたら、情報を教えてあげましょう。