Opening old DWG files in US Survey Foot

[balvernaz]

When I open drawing that we created using 2008 LDD on Civil 3D 2012, the drawings are opening as International Foot. I would like them to open as US Survey Foot. I understand that the current way to change this is got to the Drawings Settings and change it via the drop dropdown box. Due to the high number of drawings that my company has. This would be too cumbersome and hard for the employees to remember to do.  Does anybody know a way that would allow me to open every drawing using US Survey Foot instead of International Foot by default (either by lisp routines, macros, etc). Your help would be greatly appreciated.

[Jeff_M · Accepted solution]

You can add this to your acaddoc.lsp (create it if it doesn't exist with notepad and place it in the Acad support path). Once it's loaded you can either call it by the command name "SETUSFOOT" or add (c:setusfoot) immediately following the code in the acaddoc.lsp.

Limited testing done, but seems to do what you need.

(defun c:setusfoot (/ *acad* c3d c3ddoc code convflag doc dwgsettings prod
		      prodstr settings unitzone zone
		   )
  (vl-load-com)
  (setq prod (vlax-product-key))
  (setq	prodStr	(strcat	"AeccXUiLand.AeccApplication"
			(cond ((vl-string-search "\\R17.0\\" prod)
			       ".4.0"
			      )
			      ;;2007
			      ((vl-string-search "\\R17.1\\" prod)
			       ".5.0"
			      )
			      ;;2008
			      ((vl-string-search "\\R17.2\\" prod)
			       ".6.0"
			      )
			      ;;2009
			      ((vl-string-search "\\R18.0\\" prod)
			       ".7.0"
			      )
			      ;;2010
			      ((vl-string-search "\\R18.1\\" prod)
			       ".8.0"
			      )
			      ;;2011
			      ((vl-string-search "\\R18.2\\" prod)
			       ".9.0"
			      )
			      ;;2012
			      ((vl-string-search "\\R19.0\\" prod)
			       ".10.0"
			      )
			      ;;2013
			      ((vl-string-search "\\R19.1\\" prod)
			       ".10.3"
			      )
			      ;;2014
			      (t "")
			)
		)
  )
  (if (and (setq *acad* (vlax-get-acad-object))
	   (setq doc (vla-get-activedocument *acad*))
	   (setq C3D (vla-getinterfaceobject *acad* prodStr))
	   (setq C3Ddoc (vla-get-activedocument C3D))
	   (setq settings (vlax-get c3ddoc 'settings))
	   (setq dwgsettings (vlax-get settings 'drawingsettings))
	   (setq unitzone (vlax-get dwgsettings 'unitzonesettings))
	   (setq convflag (vlax-get unitzone 'foottometerconversionflag))
      )
    (progn
      (if (= convflag 1)
	(progn
	  (vlax-put unitzone 'foottometerconversionflag 2)
	  (princ "\n*****Drawing conversion changed from International Foot to US Survey foot!!*****")
	  )
	)
      (vlax-release-object C3D)
    )
  )
  (princ)
)