Dang Groups

[gccdaemon]

Our survey department uses Non-AutoDesk software to produce our surveys. During the conversion process, all the points come in as grouped items consisting of blocks & points. Now normally you could explode selected groups, but with 10,000 points it tends to become time consuming. Here is the big problem, all the groups come in as unnamed groups. the -GROUP command will not list these, but the GROUP command does when you check "Include Unnamed". With 10,000 points, it takes about 4 minutes to explode one of these groups. Here is my question, Anyone out there had a .lsp that will explode all groups in the drawing? I have some .lsp that delete all unused groups but it will not clear these. PLEASE HELP!

[Neilw_05]

I've encountered the situation you bring up, namely how to explode or delete numerous groups in ACAD. It only allows you to select them one at a time. Unfortunately I don't have a direct solution, but it may help to know that you can disable group selection globally in ACAD options. While that won't get rid of the groups, it will at least allow you to manipuate the elements individually. Perhaps you could disable group selection and then extract the points to C3D points or some other form that is more useable. I know it can be done using Map.

By the way I suspect the non-acad software you mention is Geopak which uses graphics groups extensively, including for survey points. Microstation can "drop" (explode) groups by selection set so it is not a problem in that environment. If you have a seat of Microstation or can find someone that does, they can remove the groups easily. I could do that for you if you like but I can only load ACAD 2009 format files in my version Microstation.

[Jeff_M]

---

@gccdaemon wrote:

I have some .lsp that delete all unused groups but it will not clear these.

---

What do you mean by this? I have a real small lisp that just deletes the unnamed groups then all objects formerly within the groups are individually selectable and there are no groups left in the list of groups...

Feel free to try it. If this doesn't do what you want, can you post a drawing with the groups?

(defun c:rmvgrps (/ doc grps count)
  (vl-load-com)
  (setq doc (vla-get-activedocument (vlax-get-acad-object))
	grps (vla-get-groups doc)
	count 0
	)
  (vla-startundomark doc)
  (vlax-for grp grps
    (if (wcmatch (vla-get-name grp) "`**");;only use anonymous groups
      (progn
	(vla-delete grp)
	(setq count (1+ count))
	)
      )
    )
  (vla-endundomark doc)
  (princ (strcat "....removed " (itoa count) " groups from this drawing."))
  (princ)
  )

[gccdaemon]

That lisp seems to do some good and cleared a couple hundred out, however I have now noticed there are still Unnamed groups that now have a "0x" prefix. As for using microstation, we do not have a copy nor do i see a use for getting a liscense for group removal...lol. Does anyone have a lisp for exploding multiple selectable groups?

[Jeff_M · Accepted solution]

Here are 2 more slightly altered lisps. The first will remove all Selectable Groups, second just removes all groups.

(defun c:rmvselgrps (/ doc grps count)
  (vl-load-com)
  (setq doc (vla-get-activedocument (vlax-get-acad-object))
	grps (vla-get-groups doc)
	count 0
	)
  (vla-startundomark doc)
  (vlax-for grp grps
    (setq egrp (vlax-vla-object->ename grp)
	  elist (entget egrp)
	  )
    (if (= (cdr (assoc 71 elist)) 1) ;;only use selectable groups
      (progn
	(vla-delete grp)
	(setq count (1+ count))
	)
      )
    )
  (vla-endundomark doc)
  (princ (strcat "....removed " (itoa count) " groups from this drawing."))
  (princ)
  )


(defun c:rmvallgrps (/ doc grps count)
  (vl-load-com)
  (setq doc (vla-get-activedocument (vlax-get-acad-object))
	grps (vla-get-groups doc)
	count 0
	)
  (vla-startundomark doc)
  (vlax-for grp grps
	(vla-delete grp)
	(setq count (1+ count))
    )
  (vla-endundomark doc)
  (princ (strcat "....removed " (itoa count) " groups from this drawing."))
  (princ)
  )

[dschuler]

Andrew,

I used to struggle with compatibility issues between engineering and survey.  I hate to get my points as blocks.  The best solution for me is to just get the survey dept. to send me the points file or a .xml file if possible.  Once I import that into C3D I have all the control I need over all that point data.  I believe in keeping it simple.

[gccdaemon]

We currently ask for the TIN and point files in addition to the full survey. We're forcing our Survey Dept. to start using C3D because of the incompatabilities in addition to using the Engineering dept. standards. I couldn't tell you how many hours i spent translating layers, fixing line weights, changing linetypes, etc. The only reason we don't do the survey ourselves is because of company politics...lol.

[dschuler]

Been there done that Andrew...it can be quite a challenge getting survey to consistantly give you what you need.

If you are gettting your points in a text file format than when you import them directly into C3D you should be removing the grouping that you do not like.  Unless I'm missing something.

David